Identificar parte de un dato dentro de un campo
 

Hola a todos
A ver si me podéis dar una mano con esto.
Tengo una tabla en donde tengo un campo descripción.
En este campo hay por ejemplo varios productos por ejemplo:

LAMINA 187 X 305 BONE
LAMINA 187 X 305 BLANCO

Este campo lo capturo en un combobox en donde me salen todos los que cumplen con una condición (sql).

Lo que me gustaría es:
En el evento onchange del combobox poder identificar la ultima parte.
(BONE) o (BLANCO)

Se podrá.

Este es el codigo con el que lo capturo:

Código Delphi [-]
 QTemp.SQL.Text := 'SELECT Materiales.Descripcion FROM Materiales WHERE Materiales.Notas = "LAMINA"';
   QTemp.Active := True;
   While not QTemp.Eof do
   begin
      CBLamina.Items.Add(QTemp.Fields[0].Text);
      QTemp.Next;
   end;
   QTemp.Active := False;

Saludos

Hola amigo,

Creo que hoy estoy cerrado, no entiendo lo que quieres hacer :o

Salud OS

Hola
Pues ya somos dos.:D:D:D
Lo que quiero hacer es identificar parte del texto que contiene ese campo.

Si el campo tiene:
LAMINA 187 X 305 BONE

Tiene:
LAMINA
187
X
305
BONE

Quiero que al mostrar ese campo en el combobox me identifique la ultima parte del campo: BONE

Se podra?':confused:

Estoy cada vez mas espeso, no capto nada.
Saludos

Hola,

No sé si será muy elegante, ni siquiera si acierto con lo que creo que quieres, pero, vamos, a ver qué tal parece esto:

Código Delphi [-]
function GetLaminaType(rawData: string): string;
var
  i: integer;
begin
  i := Length(rawData);
  while (i >= 0) do begin
    if (rawData[i] = ' ') then
      break;
    result := rawData[i] + result;
    Dec(i);
  end;
end;

// Ejemplo de uso
procedure TForm1.Button1Click(Sender: TObject);
begin

  // Muestra BONE
  ShowMessage(GetLaminaType('LAMINA 187 X 305 BONE'));

  // Muestra BLANCO
  ShowMessage(GetLaminaType('LAMINA 187 X 305 BLANCO'));

end;

Pues de poder se debe de poder :D:D:D, una pregunta, todos tus registros siguen ese formato?

LAMINA[espacio]187[espacio]X[espacio]305[espacio]BONE

Si es así puedes usar esta función que me encontre creo en Trucomanía.

Código Delphi [-]
function GetToken(Cadena,Separador:string;Token:integer):string;
var
  Posicion:integer;
begin
   while Token > 1 do begin
     Delete(Cadena,1,Pos(Separador,Cadena));
     Dec(Token);
   end;
   Posicion:=Pos(Separador,Cadena);
   if Posicion=0 then result:=cadena
   else Result:=Copy(Cadena,1,Posicion-Length(Separador));
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowMessage(GetToken('LAMINA 187 X 305 BONE',' ',5));
  ShowMessage(GetToken('LAMINA 187 X 305 BLANCO',' ',5));
end;

Salud OS

Edito: Vaya amigo Dec, me ganaste y me parece que tu función GetLaminaType() esta optimizada .... :)

Hola,

Yo sigo a lo mío... :D Creo que mi anterior función podría (y aun debería) quedar así, mejor o peor:

Código Delphi [-]
function GetLaminaType(rawData: string): string;
var
  i: integer;
begin
  result := '';
  i := Length(rawData);
  while (i >= 1) do begin
    if (rawData[i] = ' ') then
      break;
    result := rawData[i] + result;
    Dec(i);
  end;
end;

Nótese que ahora el bucle aguantaría mientras la variable "i" valiera igual o más que 1. ¿Por qué así ahora? Porque, si no recuerdo mal, las cadenas en Delphi son "Arrays" de caracteres cuyo índice comienza en uno, no en cero. Tal anteriormente la función de marras podría haber dado algún problema... ¡tal vez incluso ahora pueda darlos! :D :D

PD. Probándolo de nuevo no parece haber problema con el "cero", pero, el "uno" me sigue pareciendo más oportuno. Además he añadido el "result" del principio, por principio. ;)

Yo propongo esta:

Código Delphi [-]
function DameElTipo(Dato: String): String;
var
  Espacio: Integer;

begin
  Espacio := Pos(' ', ReverseString(Dato));
  Result := Copy(Dato, Length(Dato) - Espacio + 2, Length(Dato));
end;

Bye

Hola,

Huy... no sé qué te diga... bueno, sí: que la tuya me parece curiosa. ;)

Y, respecto de la del compañero keyboy, chico, yo probé con el "Reverse" pero me hice un lío... :D :D :D

Por cierto, creo que la de keyboy se muestra favorita, ahora, eso sí, le falta algo:

Código Delphi [-]
uses
  StrUtils;

:D :D :D

:eek:, de que hablas amigo Dec :D:D:D

mmmm, Yo ni siquiera he podido ver como funciona ese ReverseString(), no existe en mi rudimentario Delphi4 :o, bueno, ya vere mañana en mi TurboDelphi :cool:

Salud OS

Jeje... me ganaron... yo ya estaba preparando una función... pero bueno... mejor no intento.

Total, cuando vengan por aquí Domingo y Javier veremos como queda la cosa.:D

Mientras tanto veo como ganarles en ASM.:p:D:rolleyes:

Saludos,

Hola,

Aquí Zarko Gajic implementa una función "ReverseString()", e informa de que existe desde Delphi 6. ;)

En realidad lo de ReverseString está muy jalado :) pues al final termina haciendo el recorrido inverso. Mucho mejor la de dec que creo se puede simplificar un poco:

Código Delphi [-]
function DameloYa(Dato: String): String;
var
  I: Integer;

begin
  for I := Length(Dato) downto 1 do
    if Dato[i] = ' ' then
      break;

  Result := Copy(Dato, I + 1, Length(Dato));
end;

Bye

Eso mismo pensé :)

Y bueno, como lo dije, ya he probado la función ReverseString() en mi TurboDelphi y puede ser que no sea tan "jalado" en ciertas circunstancias.

De cualquier forma esto me hace auto-enviarme a RTFM :D:D:D

Salud OS

Hola
Sois unos maestros, pero casualmente aveces no os dais cuenta de quien pregunta (el Novato).:D:D
Esto de las funciones me mata.:o
Alguien me lo traduce.:D
Recordad, tengo un combobox, de ahi parto, la información entra en el.
Como uso la función para llamar al dato que contiene el combobox.:confused:
Ya se, nunca aprenderé, pero de que lo intento, lo intento.:D
Saludos

Hola amigo "NOVATO" :D, lo que pasa es que no entiendo que es lo que quieres hacer, la parte de obtener el color ya está resuelta, ahora hay que resolver lo que tu mente quiere hacer :D:D:D

Será que nos expliques un poco mas a detalle que es lo que intentas? :)

Salud OS

Hola
Que poca paciencia me tienes, te esta volviendo viejo amigo:D:D.
Vamos otra vez.
Tengo un campo. (text)
Recojo el dato en un combobox.
Ahora con la función que hicisteis quiero saber la ultima parte de ese dato.
No lo capto, seguro es facil y vosotros lo veis, pero yo no.:D
Anda, que no te cuesta nada explicárselo al Novato.:D:D
Saludos

Amigo! Me extraña!

Creo el Alz te ha visitado:D
Bueno creo que a lo que te refieres es a esto:

Código Delphi [-]
VariableOPriedad := NombreDeLaFuncion(VariablesOPropiedadesOConstantes);

Por ejemplo:

Código Delphi [-]
UnColor := DameloYa(ComboBox1.Text);

:confused:
Saludos,

Código Delphi [-]
function DameloYa(Dato: String): String;
var
  I: Integer;

begin
  for I := Length(Dato) downto 1 do
    if Dato[i] = ' ' then
      break;
  Result := Copy(Dato, I + 1, Length(Dato));
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
   Edit1.Text := DameloYa(ComboBox1.Text);
end;

Salud OS

Hola
Veis, no dolió, ahora si lo capte, era solo de tomarme la pastilla del Altz y ya.:D:D
Algún día entenderé esto de las funciones.:D
Gracias, ya esta resulto, la próxima vez pregunto mejor.:)
Para que veáis como quedo, (Use la función de Dec.):

Código Delphi [-]
procedure TFOrdenProdAcrilico.CBLaminaChange(Sender: TObject);
var
color: string;
begin
 Color:= GetLaminaType(CBLamina.Text);
 showmessage(color);
   QTemp.Close;
   QTemp.SQL.Text := 'SELECT Materiales.Disponible FROM Materiales WHERE Materiales.Descripcion = :Disp';
   QTemp.Parameters[0].Value:= CBLamina.Text;
   QTemp.Active := True;
   Dispon.Text:= QTemp.Fields[0].Text;
end;

Saludos

Hola
Bueno, aqui sigo molestando, otro asunto:
Ya consegui que me mostrara el color con la funcion, esto esta bien.
Ahora lo que necesito es que una vez que consiga el color del combo, me carge en otro combo los datos de otros productos que tienen tambien esa condicion.
Para que os deis cuenta.
1- paso:
Cargo de combobox ( LAMINA 187 X 305 BONE )
Genero la funcion y me da el color.
Esto va bien.

2- paso:
Una vez cargado el dato del color quiero que se me genere una consulta
Y que me carge en otro combobox el dato que tenga tambien la condicion de Color.
El dato es este:
IBIZA TERMOFORMADO BONE

Lo que tengo:

Código Delphi [-]
procedure TFOrdenProdAcrilico.CBLaminaChange(Sender: TObject);
var
ColorL: string;
begin
   ColorL:= GetLaminaType(CBLamina.Text);
   EColor.Text:= ColorL;
   QTemp.Close;
   QTemp.SQL.Text := 'SELECT Materiales.Disponible FROM Materiales WHERE Materiales.Descripcion = :Disp';
   QTemp.Parameters[0].Value:= CBLamina.Text;
   QTemp.Active := True;
   Dispon.Text:= QTemp.Fields[0].Text;

// aqui es donde lo necesito

   QTemp.SQL.Text := 'SELECT Materiales.Descripcion FROM Materiales WHERE Materiales.Notas ="TERM" ORDER BY Materiales.Descripcion';
   QTemp.Active := True;
   While not QTemp.Eof do
   begin
      CBPieza.Items.Add(QTemp.Fields[0].Text);
      QTemp.Next;
   end;
   QTemp.Active := False;
end;

Ojala me entendáis.
Saludos

Hola amigo Caral, y porque no usas un LIKE

Código Delphi [-]
   QTemp.SQL.Text := '......... WHERE Campo LIKE '+QuotedStr('%'+ColorL);

Salud OS

Hola
El asunto es que es el mismo campo pero con diferentes datos.

Campo descripcion, Notas= LAMINA
1- Combobox1 = LAMINA 187 X 305 BONE

Campo descripcion, Notas= TERM
2- Combobox2 = IBIZA TERMOFORMADO BONE

La idea es que al conseguir el color (en un edit) que en ambos datos esta al final y es igual se capture la información en el segundo combobox pero solo los que sean de ese color.
Ya se que me lio.:D
Saludos

Hola
Gracias amigo, ya me funciona, estoy embotado por eso seguro me cuesta tanto entender.
Gracias a todo por vuestra ayuda, me ha servido de mucho.
Gracias de corazón.
Saludos

Hola
Retomando este tema.
La función devuelve el ultimo dato (usando cualquiera de las funciones).
Me preguntaba si seria posible que devolviera el dato que uno necesite, el primero o el segundo o el ultimo (como en este caso).
Lo He intentado pero al contar el dato de atrás para adelante me coloca todas las palabras según van.
Se podrá hacer la diferenciación? o se necesitara otra función.?
Gracias
Saludos

Mi buen amigo Carlos, ¿Por casualidad te refieres a esto?

Código Delphi [-]
TLaminaInfo = (liName, liDimension, liColor);

function GetLaminaInfo(LaminaText: string; Info: TLaminaInfo): string;
var PosIni, PosEnd: integer;
begin
  //preventiva
  PosIni := 0;
  PosEnd := 0;

  // Dependiendo de la info a pedir, calculamos posiciones
  // iniciales y finales
  case Info of
  liName: begin
            Posini := 1;
            PosEnd := Pos(' ',LaminaText);
          end;
  liDimension: begin
                 PosIni := Pos(' ',LaminaText) + 1;
                 PosEnd := Length(LaminaText) - Pos(' ',ReverseString(LaminaText)) + 2;
               end;
  liColor: begin
             PosIni := Length(LaminaText) - Pos(' ',ReverseString(LaminaText)) + 1;
             PosEnd := Length(LaminaText) + 1;
           end;
  end;

  // copiamos el texto que esté comprendido desde PosIni a PosEnd
  result := Copy(LaminaText,PosIni,PosEnd - PosIni);
end;

Saludos,

Hola
Gracias Marcelo por contestar.
Tengo algunas preguntas:
Esta parte es una variable publica??:

Código Delphi [-]
TLaminaInfo = (liName, liDimension, liColor);

Ahora para llamar a la funcion que tengo lo hago asi:
En este caso solo devuelve el ultimo valor.

Código Delphi [-]
procedure TForm1.ComboBox1Change(Sender: TObject);
var
ColorL: string;
begin
 ColorL:= DameElTipo(ComboBox1.Text);
 showmessage(ColorL);
end;

Como haria para llamar a tu funcion???.
Supongo que tengo que indicar el tipo (Posin) o (PosEnd), pero no se como hacerlo.
Saludos

Perdón amigo, me olvidé de indicar que TLaminaInfo es un tipo de dato:

Código Delphi [-]
type
TTLaminaInfo = (liName, liDimension, liColor);

Y un ejemplo de uso de dicha función es el siguiente:

Código Delphi [-]
Edit1.Text := GetLaminaInfo(ComboBox1.Text,liName);
// con liName se obtiene el nombre, Por ejemplo: 'LAMINA'

Edit1.Text := GetLaminaInfo(ComboBox1.Text,liDimension);
// con liDimension se obtiene la dimensión. Por ejemplo: '132 X 185'

Edit1.Text := GetLaminaInfo(ComboBox1.Text,liColor);
// con liColor se obtiene el color, Por ejemplo: BONE.

El primer parámetro de la función es el texto completo. Por ejemplo: LAMINA 135 X 185 BONE. El segundo, el tipo de información a extraer.

Ahora que lo pienso y viendo lo que deseas hacer se debería modificar el tipo para mejorar el ejemplo:

Código Delphi [-]
type
TLaminaInfo = (liName = 0, liDimension = 1, liColor = 2);

De este modo puedes hacer coincidir los indices del Combo o de algún otro control con el tipo de dato. Por ejemplo:

Código Delphi [-]
Edit1.Text := GetLaminaText(Edit2.Text,ComboBox1.ItemIndex);

Suponiendo que en Edit2.Text estés guardando el texto completo e ItemIndex del combo represente el tipo de información que pide.

Mi función es probable que pueda ser mejorada para tus propósitos. La verdad es que la hice en 5 minutos, y no he pensado mucho en las posibilidades que necesitas. Mi intención era mostrar más o menos lo que entendía de tus requisitos.

Si es esto lo que andas buscando dimelo, y si no lo es, también dímelo (con tirón de orejas por no haber prestado demasiada atención).

Saludos,

Hola
En tu ultimo ejemplo, que me parece genial ademas de practico me genera este error:
en esta linea:

Código Delphi [-]
Edit2.Text := GetLaminaText(Edit2.Text,ComboBox4.ItemIndex);

No se si tendra que ver con que tendria que devolver un integer y pide un string.
No entiendo el por que??.
Saludos

¡Ouch!
Como se nota que he perdido la práctica con los enumerados!:o:(

Entonces modifica a la función por esta otra:

Código Delphi [-]
function GetLaminaInfo(LaminaText: string; Info: integer): string;
var PosIni, PosEnd: integer;
begin
  //preventiva
  PosIni := 0;
  PosEnd := 0;

  // Dependiendo de la info a pedir, calculamos posiciones
  // iniciales y finales
  case Info of
  0: begin
            Posini := 1;
            PosEnd := Pos(' ',LaminaText);
          end;
  1: begin
                 PosIni := Pos(' ',LaminaText) + 1;
                 PosEnd := Length(LaminaText) - Pos(' ',ReverseString(LaminaText)) + 2;
               end;
  2: begin
             PosIni := Length(LaminaText) - Pos(' ',ReverseString(LaminaText)) + 1;
             PosEnd := Length(LaminaText) + 1;
           end;
  end;

  // copiamos el texto que esté comprendido desde PosIni a PosEnd
  result := Copy(LaminaText,PosIni,PosEnd - PosIni);
end;

Y te olvidas del tipo TLaminaInfo, borralo.
Y ya no deberías tener problemas.

Saludos,

Hola
Muy interesante el concepto, Efectivamente funciona.
Gracias por el apoyo, me cuesta entender el concepto de las funciones pero con estas practicas voy aprendiendo.
Gracias de nuevo amigo.
Saludos

Hola Carlos, tal vez estos links te sean de ayuda para comprender el tema de funciones y procedimientos:

http://www.clubdelphi.com/foros/showthread.php?t=49698
http://www.clubdelphi.com/foros/showthread.php?t=49246

Hay más, solo los pongo de ejemplo. Básicamente:

La función devuelve un valor, un procedimiento no.
Ambos no necesariamente pueden pertenecer a una clase, pueden estar "sueltos" en las units.

Por ejemplo cuando uno hace:

Código Delphi [-]
TForm1 = class
  // bla
  // bla, bla,
  funcion Elegir(Numero: integer): String;
  // bla
end;

Lo que hace es indicar que la función elegir es parte de la clase TForm1. Y es por ello que al momento de escribir su código debemos indicarle su "dueño":

Código Delphi [-]
function TForm1.Elegir(Numero: integer): string;
begin
  //bla...
end;

Pero si no necesariamente debe tener un "dueño", Podemos tenerla libremente en una Unit:

Código Delphi [-]
Unit UCualquiera;

interface

funcion Elegir(Numero: integer): string;

// ...

implementation

function Elegir(Numero: integer): string;
begin
  // bla...
end;

Ejemplos de funciones sueltas son inc(), dec(), Length().
Un ejemplo de una función con dueño es CloseQuery, que le pertenece a la clase de la cual desciende los objetos TForm.

Espero que esto te haya servido para comprender mejor la diferencia entre funciones y procedimientos e igualmente para comprender a que se debe ese TForm1.XXXXXX.

Saludos,

Hola
Gracias amigo, voy a revisar los link, si no entiendo algo ya te avisare (osea, lo mas seguro).
Saludos