PopupMenu en modo de ejecución
 

Hola. Tengo un programa en C++ que crea varios paneles en modo de ejecución, pero también quería (en modo de ejecución) crear y asociarles un PopupMenu con tres opciones (opacionA; OpnciónB y OpciónC). Llevo ya varias horas y no doy con la solución; me haríais el favor de echarme una mano?... !cada vez estoy más perdido!. Muchas Gracias!!!

Hola a todos,

¿Dónde encuentras el problema? O sea, en qué punto... Sea como sea, la siguiente unidad, aunque de Delphi, acaso pueda ayudarte:

Código Delphi [-]
unit Unit1;

interface

uses
  Vcl.Forms,
  Vcl.Menus;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    // Manejador del evento click de nuestros items
    procedure MenuItemClick(Sender: TObject);
  private
    // Nuestro PopupMenu
    FPopupMenu: TPopupMenu;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
  Vcl.Dialogs;

procedure TForm1.FormCreate(Sender: TObject);
var
  MenuItem: TMenuItem;
begin
  // Creamos el PopupMenu
  FPopupMenu := TPopupMenu.Create(nil);

  // Creamos un item
  MenuItem := TMenuItem.Create(FPopupMenu);
  MenuItem.Caption := 'Opción A';
  MenuItem.OnClick := Self.MenuItemClick;
  FPopupMenu.Items.Add(MenuItem);

  // Creamos otro item
  MenuItem := TMenuItem.Create(FPopupMenu);
  MenuItem.Caption := 'Opción B';
  MenuItem.OnClick := Self.MenuItemClick;
  FPopupMenu.Items.Add(MenuItem);

  // Creamos el tercer item
  MenuItem := TMenuItem.Create(FPopupMenu);
  MenuItem.Caption := 'Opción C';
  MenuItem.OnClick := Self.MenuItemClick;
  FPopupMenu.Items.Add(MenuItem);

  // Asignamos al formulario nuestro PopupMenu
  Self.PopupMenu := FPopupMenu;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  // Destruimos nuestro PopupMenu
  FPopupMenu.Free();
end;

procedure TForm1.MenuItemClick(Sender: TObject);
begin
  // Mostramos el index del item al que se ha hecho click
  ShowMessageFmt('Has pulsado en el item con index: "%d"',
   [FPopupMenu.Items.IndexOf((Sender as TMenuItem))]);
end;

end.

dec te ha puesto un ejemplo perfecto en delphi, si te parece y con su permiso, lo lo traduzco a C++ Builder






Saludos.

Hola a todos,

Ahora este hilo también sirve para comparar el código de C++ con el de Delphi. Gracias escafandra. :)

Hola. Muchísimas gracias.!!!!... todo perfecto y funcionando... y lo que es mejor, creo que lo he entendido.

Hola a todos,

Eso está bien. :) Quizás lo que pueda llamar la atención (al menos en el código Delphi...) es que el PopupMenu lo creamos sin "owner", es decir, seremos nosotros quienes tendremos que hacernos cargo de la destrucción del PopupMenu, como lo hacemos en el evento "Destroy" del formulario. Sin embargo, los items sí que tienen "owner", el propio PopupMenu, de modo que dejamos a este que se encargue de su destrucción cuando ya no sean necesarios.

Ocurre lo mismo en C++ Builder. No fui completamente fiel en la traducción y preferí una destrucción automática. Podemos escribir esto, pero tendremos que destruirlo luego explicitamente:
Y para destrir en C++

Saludos.

^\||/ ^\||/