Crear Un Object Tree View
 

Hola a todos, deseo saber como puedo insertar en un Tree View los Controles y sus Componentes existentes en un Formulario, como lo hace el object Tree View, lo que pasa es que puedo listarlos todos en un tree view pero no puedo hacer que queden como nodos los Controles y como subnodos los componentes, ¿alguien puede ayudarme?.

Si no he entendido mal, tú quieres mostrar en un TreeView todos los controles que hay en un formulario (como en el Delphi (Structure)), y que estos estén anidados correspondientemente (Padre -> Hijo -> SubHijo -> Etc...):

Te he hecho este código, que creo que realiza lo que tu buscas:

Código Delphi [-]
procedure TForm1.AddSubControls(ParentNode: TTreeNode; ParentControl: TControl);
var
  n: Integer;
  lNode: TTreeNode;

begin
  if ParentControl is TWinControl then
    for n:=0 to TWinControl(ParentControl).ControlCount - 1 do
      begin
        lNode:=TreeView1.Items.AddChild(ParentNode, Format('%s: %s', [TWinControl(ParentControl).Controls[n].Name, TWinControl(ParentControl).Controls[n].ClassName]));
        AddSubControls(lNode, TWinControl(ParentControl).Controls[n]);
      end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  AddSubControls(TreeView1.Items.Add(nil, Format('%s: %s', [Self.Name, Self.ClassName])), Self);
end;

Lo he probado, añadiendo un montón de TPanels, TGroupBox, etc... y funciona bien.

Este es el resultado de un Formulario de prueba, para probar que funciona:
Esto es lo que se genera dentro del "TreeView".

Saludos.

Muchas Gracias xEsk, la verdad es que me es de gran ayuda.:D
y tambien tengo otra duda, como puedo hacer para que los componentes en run time parezcan como en tiempo de diseño (crear, arrastrar y cambiar tamaño).

Prueba buscando "Form Designer" en Google, Torry's, etc...

Mira aqui, a ver si encuentras algo util: "Form Designer" en Torry's

Saludos.

Estoy tratando de estudiar el código aportado por xEsk pero no entiendo dónde debo escribir la primera parte del mismo:

Código Delphi [-]
procedure TForm1.AddSubControls(ParentNode: TTreeNode; ParentControl: TControl);
var
  n: Integer;
  lNode: TTreeNode;

begin
  if ParentControl is TWinControl then
    for n:=0 to TWinControl(ParentControl).ControlCount - 1 do
      begin
        lNode:=TreeView1.Items.AddChild(ParentNode, Format('%s: %s', [TWinControl(ParentControl).Controls[n].Name, TWinControl(ParentControl).Controls[n].ClassName]));
        AddSubControls(lNode, TWinControl(ParentControl).Controls[n]);
      end;
end;

Recibo el siguiente mensaje de error
Undeclared identifier: 'AddSubControls'

Muchas gracias por la ayuda y disculpen mi ignorancia.
Un saludo y hasta pronto

Hola esocrates,

Añade:

Código Delphi [-]
procedure AddSubControls(ParentNode: TTreeNode; ParentControl: TControl);

arrriba en las declaraciones del TForm:

Ejemplo:

Código Delphi [-]
  TForm1 = class(TForm)
    procedure Button1Click(Sender: TObject);
  private
    procedure AddSubControls(ParentNode: TTreeNode; ParentControl: TControl);
  public
    { Public declarations }
  end;

Si lo pones en "Private", este procedure será sólo visible desde este "Form", si lo metes en "Public" entonces será visible para el resto de unidades (que conozcan a esta UNIT).

Cualquier otra duda, ya sabes.

Saludos.

Hola xEsk:
Gracias por responder.Lo que no sé es dónde se escribe este segmento de código.

Código Delphi [-]
procedure TForm1.AddSubControls(ParentNode: TTreeNode; ParentControl: TControl);
var
  n: Integer;
  lNode: TTreeNode;

begin
  if ParentControl is TWinControl then
    for n:=0 to TWinControl(ParentControl).ControlCount - 1 do
      begin
        lNode:=TreeView1.Items.AddChild(ParentNode, Format('%s: %s', [TWinControl(ParentControl).Controls[n].Name, TWinControl(ParentControl).Controls[n].ClassName]));
        AddSubControls(lNode, TWinControl(ParentControl).Controls[n]);
      end;
end;

Un saludo

Hola,

Ese código es la implementación del método "AddSubControls()" de la clase "TForm1". Eso es lo que puede verse. Así que ese código ha de ir en la "implementation" de la unidad en que se declare la clase a la que pertenece y el mismo método.

Código Delphi [-]
unit Unit1;

interface

// Esta es la interface de esta unidad, aquí vamos a declarar
// la clase TForm1, que cuenta con el método "AddSubControls()"

uses
  Forms;

type
  TForm1 = class(TForm)
  private
    procedure AddSubControls(ParentNode: TTreeNode; ParentControl: TControl);
  end;

implementation

// Y aquí está la implementación de la clase TForm1 declarada en la interface
// Aquí se implementa el método "AddSubControls()" de la clase TForm1

procedure TForm1.AddSubControls(ParentNode: TTreeNode; ParentControl: TControl);
var
  n: Integer;
  lNode: TTreeNode;

begin
  if ParentControl is TWinControl then
    for n:=0 to TWinControl(ParentControl).ControlCount - 1 do
      begin
        lNode:=TreeView1.Items.AddChild(ParentNode, 
         Format('%s: %s', [TWinControl(ParentControl).Controls[n].Name, 
          TWinControl(ParentControl).Controls[n].ClassName]));
        AddSubControls(lNode, TWinControl(ParentControl).Controls[n]);
      end;
end;

end.

¡¡Muchas gracias xEsk y dec !!
Con este código y las respectivas aclaraciones he aprendido un montón de cosas.
Un saludo y hasta pronto