Foros Club Delphi
Página 1 de 2 1 2 >
Mostrar 40 mensajes desde este tema en una página

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)
-   Varios (https://www.clubdelphi.com/foros/forumdisplay.php?f=11)
-   -   Pasar una Clase por parametro (https://www.clubdelphi.com/foros/showthread.php?t=73912)

robacio_ivan 24-05-2011 16:35:42
Pasar una Clase por parametro
 
Buenas mis amigos delphiteros, tengo una consulta un tato extraña pero con fe de que alguno de ustedes me la puedan responder. Les explico más o menos qué es lo que quiero hacer así entienden el tema.

Lo que yo quiero hacer es un procedimiento al cual yo el pase por parámetro una clase y en este procedimiento ejecutar la misma. Dicho de otra forma y más directo con lo que quiero hacer es un procedimiento que le pase por parámetro una clase de tipo TForm y dentro de este método ejecutar un método de clase.

Bueno espero haber sido bastante claro con la consulta, desde ya agradezco cualquier tipo de ayuda.

Young 24-05-2011 16:59:42
Hola, supongo que necesitas pasar la instancia de una clase como parámetro y no la clase, bueno si es así, debes definir el parámetro con el tipo de la clase:

Código Delphi [-]
procedure algo( var miForm: TForm ); 
begin
    miForm.miMetodo();
end;

{ la llamada sería algo así... } 
... 
algo( Form1 );


Recuerda incluir las units donde tienes definidas los forms o las clases que quieres pasar como parámetros. Espero sea de ayuda.

Saludos.

ecfisa 24-05-2011 17:16:32
Hola.

Si no entiendo mál lo que buscas, por ejemplo sería:
Código Delphi [-]
procedure TForm1.SendClassProc(AClass: TFormClass);
begin
  with AClass.Create(nil) do
  begin
    ..
    ShowModal;
  end;
end;

Ejemplo de llamada:
Código Delphi [-]
   SendClassProc(TForm);
Si desearas que el procedimiento pueda recibir cualquier clase tendrías que declarar el argumento del procedimiento de tipo TClass.

Saludos.

Young 24-05-2011 17:30:18
Cita:
Empezado por ecfisa (Mensaje 401132)
Hola.

Si no entiendo mál lo que buscas, por ejemplo sería:
Código Delphi [-]procedure TForm1.SendClassProc(AClass: TFormClass); begin with AClass.Create(nil) do begin .. ShowModal; end; end;


Ejemplo de llamada:
Código Delphi [-] SendClassProc(TForm);

Si desearas que el procedimiento pueda recibir cualquier clase tendrías que declarar el argumento del procedimiento de tipo TClass.

Saludos.
La verdad no conocía esta técnica, no se me ocurre de momento en que caso práctico ocuparla pero bienvenida sea.

Gracias.

ecfisa 24-05-2011 18:12:50
Hola Young.

El tipo se denomina referencias de clase, en sí son punteros a tablas de métodos virtuales. Y una de las muchas aplicaciónes prácticas es precisamente la creación de ventanas.

Un saludo.

ecfisa 24-05-2011 18:48:16
Hola de nuevo.

Creo que me quedé corto con la explicación anterior sin dar ni un mísero ejemplo... :)

Ejemplos para encapsular la creación/muestra de diferentes tipos de ventanas:
Código Delphi [-]
(* Ventanas modales *)
procedure TForm1.MostrarVentanaModal(AClass: TFormClass);
begin
  with AClass.Create(Application) do
  try
    ShowModal;
  finally
    Free;
  end;
end;

(* Ventanas no modales *)
procedure TForm1.MostrarVentanaNoModal(AClass: TFormClass);
var
  Frm: TForm;
begin
  Frm:= Application.FindComponent(Copy(AClass.ClassName,2,MaxInt)) as TForm;
  if Assigned(Frm) then
    Frm.Show
  else
    Frm.Create(Application);
end;

(* Ventanas MDIChild *)
procedure TForm1.MostrarMDIChild(AClass: TFormClass);
var
  i: Integer;
begin
  for i:= 0 to Screen.FormCount -1 do  
    if Screen.Forms[i] is AClass then
    begin
      Screen.Forms[i].WindowState:= wsNormal;
      Screen.Forms[i].BringToFront;
      Exit;                                   
    end;
  AClass.Create(Application);
end;

Saludos.

Young 24-05-2011 18:58:09
Cita:
Empezado por ecfisa (Mensaje 401151)
Hola de nuevo.

Creo que me quedé corto con la explicación anterior sin dar ni un mísero ejemplo... :)

Ejemplos para encapsular la creación/muestra de diferentes tipos de ventanas:
Código Delphi [-](* Ventanas modales *) procedure TForm1.MostrarVentanaModal(AClass: TFormClass); begin with AClass.Create(Application) do try ShowModal; finally Free; end; end; (* Ventanas no modales *) procedure TForm1.MostrarVentanaNoModal(AClass: TFormClass); var Frm: TForm; begin Frm:= Application.FindComponent(Copy(AClass.ClassName,2,MaxInt)) as TForm; if Assigned(Frm) then Frm.Show else Frm.Create(Application); end; (* Ventanas MDIChild *) procedure TForm1.MostrarMDIChild(AClass: TFormClass); var i: Integer; begin for i:= 0 to Screen.FormCount -1 do if Screen.Forms[i] is AClass then begin Screen.Forms[i].WindowState:= wsNormal; Screen.Forms[i].BringToFront; Exit; end; AClass.Create(Application); end;


Saludos.
Exelente los ejemplos y gracias nuevamente, ya estoy pensando en un par de tareas en que me van a servir de mucho.

Saludos.

PD: El post no era mio, pero le he sacado buen provecho. :)

ecfisa 24-05-2011 19:23:21
Ya que te enganchaste con el tema, te comento otro recurso: Métodos de clase.

Los métodos de clase se aplican a una referencia de clase a diferencia de los métodos aplicados a la instancia de una clase.

Y seguimos con las ventanitas... :)

Form1:
Código Delphi [-]
...
uses Unit2; // donde está declarado Form2

procedure TForm1.Button1Click(Sender: TObject);
begin
  if  TForm2.Mostrar = mrCancel then
    ShowMessage('Cancelo')
  else
    ShowMessage('Acepto');
end;

Form2:
Código Delphi [-]
...
type
  TForm2 = class(TForm)
    BitBtnAceptar: TBitBtn;
    BitBtnCancelar: TBitBtn;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormDestroy(Sender: TObject);
  private
  public
    class function Mostrar: TModalResult;
  end;

var
  Form2: TForm2;

implementation

class function TForm2.Mostrar: TModalResult;
begin
  if not Assigned(Form2) then
    Form2:= TForm2.Create(nil);
  Result:= Form2.ShowModal;
end;
...
procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action:= caFree;
end;

procedure TForm2.FormDestroy(Sender: TObject);
begin
  Form2:= nil;
end;
(Fijate la diferencia en la declaracion class function o class procedure, con la de un método normal de instancia de clase)

En el ejemplo puse las propiedades ModalResult de los BitBtns a mrOk y mrCancel respectivamente para capturar como salió de Form2, en Form1.

Un saludo.

Young 24-05-2011 20:27:19
Amigo ecfisa a modo de cultura general...

1. ¿Desde que versión de delphi se introdujieron estos métodos de clases y referencias de clases?

2. ¿El método de clase se puede usar instanciado?

3. ¿Que diferencia tienen con los métodos estáticos?


Saludos.

ecfisa 24-05-2011 21:12:43
Hola.

El compañero Al, me ha hecho una observación sobre un error que cometí al tipear una línea de código:
Código Delphi [-]
procedure TForm1.MostrarVentanaNoModal(AClass: TFormClass);
var
  Frm: TForm;
begin
  Frm:= Application.FindComponent(Copy(AClass.ClassName,2,MaxInt)) as TForm;
  if Assigned(Frm) then
    Frm.Show
  else
    Frm.Create(Application);  <---- AQUI.
end;

Lo correcto es:
Código Delphi [-]
 AClass.Create(Application)

Mis disculpas si la confusión le acarreó dolores de cabeza a alguien :o y mi agradecimiento a Al por avisarme prontamente del error, ya que
la idea es que los ejemplos ayuden a simplificar el entendimiento y no que lo compliquen más... :)

Saludos.

robacio_ivan 24-05-2011 21:13:16
Respuesta
 
Lo que yo quiero hacer es algo mas o menos parecido pero no es del todo eso, adjunto el código de lo que hago que no me funciona. El procedimiento en si hace varias cosas más yo deje solamente la parte que no me funciona y me interesaria que me ayuden. Espero ser mas claro
Código Delphi [-]
procedure EjecutarForm(var pForm: TfrmForm);
begin
  inherited;
  pForm.ExecuteModal(self)
end;
Para despues llamar a la ejecución de un form de la siguiente manera

EjecutarForm(TfrmVenta);

ecfisa 24-05-2011 21:35:55
Cita:
Empezado por Young (Mensaje 401174)
Amigo ecfisa a modo de cultura general...

1. ¿Desde que versión de delphi se introdujieron estos métodos de clases y referencias de clases?

2. ¿El método de clase se puede usar instanciado?

3. ¿Que diferencia tienen con los métodos estáticos?

Saludos.
Hola.

Según tengo entendido:

1. No lo sé. :)
2. Se puede usar sin necesidad de instanciar la clase.
3. Ninguna, los métodos de clase son estáticos.

Saludos.

maeyanes 24-05-2011 21:37:19
Hola...

Cita:
Empezado por robacio_ivan (Mensaje 401178)
Lo que yo quiero hacer es algo mas o menos parecido pero no es del todo eso, adjunto el código de lo que hago que no me funciona. El procedimiento en si hace varias cosas más yo deje solamente la parte que no me funciona y me interesaria que me ayuden. Espero ser mas claro
Código Delphi [-]
procedure EjecutarForm(var pForm: TfrmForm);
begin
  inherited;
  pForm.ExecuteModal(self)
end;
Para despues llamar a la ejecución de un form de la siguiente manera

EjecutarForm(TfrmVenta);
¿Y por qué no te funciona? ¿Algún error? ¿Cuál es el mensaje del error?

Por que así como lo pones, para empezar, la palabra reservada inherited solo tiene uso en métodos de la clase que son override, no en simples procedimientos.

Otro error que veo es el uso de la variable Self, que también solo tiene uso dentro de algún método de una instancia de una clase (o como referencia a un tipo de clase dentro de un método de clase).


Saludos...

maeyanes 24-05-2011 21:40:39
Hola...

Cita:
Empezado por ecfisa (Mensaje 401183)
Hola.

Según tengo entendido:

3. ninguna, los métodos de clase son estáticos.

Saludos.
A lo mejor estoy confundido, pero yo puedo hacer algo como:

Código Delphi [-]
TMyClass = class
public
  class procedure MyClassMethod; virtual;
end;

TInheritedClass = class
public
  class procedure MyClassMethod; override;
end;

Y compila y se ejecuta perféctamente.


Saludos...

robacio_ivan 24-05-2011 21:40:48
El error que me tira es el siguiente
FMainGeneral.pas(1705): Incompatible types: 'TfrmVenta' and 'Class reference'

ecfisa 24-05-2011 22:32:39
No estas confundido maeyanes.

Creo que la aplicación que estoy tecleando y el deseo de cumplir lo mejor posible con los foros, me están reclamando un descanso ;)
Si me hubiera detenido un momento a pensar habría recordado al constructor Create que puede ser virtual y de echo es un método de clase...

Saludos.

robacio_ivan 24-05-2011 22:34:21
Pregunta de otra forma
 
¿como pasar como parametro una referencia de una clase en delphi? yo creo que esa es la pregunta correcta.

maeyanes 24-05-2011 22:38:37
Hola...

Como bien ya ha explicado ecfisa más arriba:

Código Delphi [-]
procedure ShowFormModal(AFormClass: TFormClass);
var
  AForm: TForm;

begin
  AForm := AFormClass.Create(nil);
  try
    AForm.ShowModal
  finally
    AForm.Free
  end
end;

// Para llamarla
ShowFormModal(TVentasFrm);


Saludos...

robacio_ivan 24-05-2011 22:42:59
Probe con la respuesta que me diste pero sigo con el mismo problema, me sigue tirando el mismo error

[Error] FMainGeneral.pas(1706): Incompatible types: 'TfrmForm' and 'Class reference'



Cita:
Empezado por maeyanes (Mensaje 401198)
Hola...

Como bien ya ha explicado ecfisa más arriba:

Código Delphi [-]procedure ShowFormModal(AFormClass: TFormClass); var AForm: TForm; begin AForm := AFormClass.Create(nil); try AForm.ShowModal finally AForm.Free end end; // Para llamarla ShowFormModal(TVentasFrm);



Saludos...

maeyanes 24-05-2011 22:50:29
Hola...

¿Puedes copiar el código completo del procedimiento/método así de cómo haces la llamada al mismo?



Saludos...


La franja horaria es GMT +2. Ahora son las 03:23:05.
Página 1 de 2 1 2 >
Mostrar 40 mensajes desde este tema en una página

Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2026, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi