Foros Club Delphi - traslado de informacion entre form

Página 1 de 2

Mostrar 40 mensajes desde este tema en una página

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)

- Varios (https://www.clubdelphi.com/foros/forumdisplay.php?f=11)

- - traslado de informacion entre form (https://www.clubdelphi.com/foros/showthread.php?t=75608)

rogercito

07-09-2011 00:17:44

traslado de informacion entre form

hola , buenas ... tengo un formulario que contiene 2 radiobutton , cunado el usuario seleciona el 1 radiobutton se gusradan en 2 variables diferens la hora de llegada y la hora de salida , lo mismo con el radio button 2
despues de eso el usuario regresa a otro formulario donde tendria que aparecer la sellecion que el realizo
como lo podria hacer
gracias

oscarac

07-09-2011 00:23:21

mas o menos asi
defines las variables en el form1
luego en el form2 usas el form1

Código Delphi [-] 
uses ... form1,

y lo llamas asi en el form2

Código Delphi [-] 
Procedure tForm2.MostrarVariables;
Begin
   label1.Caption := form1.Variable1
   label2.Caption := form1.Variable2
End;

rogercito

07-09-2011 00:34:21

en el form 1:
declaro las 2 variables a usar : var1,var2

luego en el form 2, en cada radio buton
tengo que escribir:
radiobuttononclick 1
var1:A
var2:b

radiobuttononclik2:

var1:D
var2:k

dependiendo la selecion del usuario por radiobutton 1 o radioburron 2 , le tebdria que aparecer en el primer formulario los datos selecionados

oscarac

07-09-2011 00:46:18

como ? como ? como ? como ? como ?

no entendi...
podrias ser un poquito mas especifico?

rogercito

07-09-2011 00:49:55

en el form 2
yo tengo un radiobutton1 tengo unas opciones en label que se me tienen que guardar algun lado para que me las pueda mostrar en otro formulario

ahora yo esa seeleccion que hago necesito que me lo muestre en algun edit o lo que sea pero en el form1

el form1 es el principal digamos, y el form 2 es el que supuestamente depende del form1

roman

07-09-2011 00:56:07

Yo lo vería de la siguiente manera:

Form2 es un formulario que sirve para escoger dos valores: HoraLlegada y HoraSalida. Entonces coloca dos propiedades para ello:

Código Delphi [-]TForm1 = class
private
  FHoraLlegada, FHoraSalida: TTime;

public
  property HoraLlegada: TTimea read FHoraLlegada write FHoraLlegada;
  property HoraSalida: TTime read FHoraSalida write FHoraSalida;
end;

Estos valores los puede (opcionalmente) inicializar Form1 al momento de abrir Form2:

Código Delphi [-]Form2.HoraLlegada := ...;
Form2.HoraSalida := ...;

if Form2.ShowModal = mrOk then
begin
  ...
end;

Claro está, que Form1 debe incluir en el uses la unidad de Form2.

Cuando Form2 se muestra, en el evento OnShow asignas los valores que tengan HoraLlegada y HoraSalida a los controles que tengas en Form2, si viene al caso y de acuerdo al valor por defecto que tenga el RadioButton.

Ahora, en el evento OnChange del RadioButton te fijas cuál item se escoge, y con base en ello, asignas los valores que corresponda a tus propiedades HoraLlegada y HoraSalida.

De esta manera, cuando regresas del ShowModal, Form2.HoraLlegada y
Form2.HoraSalida tendrán ya los valores adecuados.

// Saludos

oscarac

07-09-2011 00:59:02

ya lo dijo un experto como roman

mis conocimientos no son tan avanzados...:o

ecfisa

07-09-2011 01:37:24

Hola.

Otra opción, aunque un poco más complicada, puede ser:

Form1:

Código Delphi [-]type
  TForm1 = class(TForm)
    ...
    Edit1: TEdit;
    Edit2: TEdit;
  private
    procedure MsgHoraSalida(var Msg: TMessage); message WM_USER + 300;
    procedure MsgHoraLlegada(var Msg: TMessage); message WM_USER + 301;
  public
  end;
....
implementation

uses Unit2;

procedure TForm1.MsgHoraSalida(var Msg: TMessage);
begin
  Edit1.Text:= PChar(Msg.LParam);
end;

procedure TForm1.MsgHoraLlegada(var Msg: TMessage);
begin
  Edit2.Text:= PChar(Msg.LParam);
end;
...

Form2:

Código Delphi [-]...
implementation

procedure TForm2.RadioButton1Click(Sender: TObject);
var
  Salida,LLegada: string;
begin
  Salida:= '15:03:00';      // o convertir: TimeToStr(tu_hora_salida);...
  LLegada:= '15:30:12';   
  SendMessage(FindWindow(nil, 'Form1'), WM_USER+300, 0, DWORD(PChar(Salida)));
  SendMessage(FindWindow(nil, 'Form1'), WM_USER+301, 0, DWORD(PChar(LLegada)));
end;
...

Lo bueno es que en Form1 se ven reflejados los resultados inmediatamente.

Saludos.

rogercito

07-09-2011 04:44:11

muchas gracias por las ayuda
ahora biem cuando implemento el segundo codigo que me envieron
no se ve reflejado en los edit del form1 la informacion ....
gracias

rogercito

07-09-2011 04:46:16

tengo que asociar los edit del form1 con algo mas ?? no entiendo

ecfisa

07-09-2011 13:28:18

Cita:

ahora biem cuando implemento el segundo codigo que me envieron
no se ve reflejado en los edit del form1 la informacion .

Hola rogercito.

No sé cual de las tres propuestas estás usando, pero si es la que utiliza mensajes, con seguridad no has cambiado el nombre del form receptor 'Form1' por el que le pusiste a tu form y por lo tanto la función FindWindow no encuentra la ventana correspondiente.

Código Delphi [-]  SendMessage(FindWindow(nil, 'Nombre_De_Tu_Form'), WM_USER+300, 0, DWORD(PChar(Salida)));

Un saludo.

rogercito

07-09-2011 15:07:10

Código Delphi [-]unit Unit23;
nterface
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Db, DBTables, DBCtrls, StdCtrls, Mask;
type
  TForm23 = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    DBLookupComboBox1: TDBLookupComboBox;
    DataSource1: TDataSource;
    Table1: TTable;
    DBLookupComboBox2: TDBLookupComboBox;
    DataSource2: TDataSource;
    Table2: TTable;
    Button1: TButton;
    Button2: TButton;
    Label5: TLabel;
    Label6: TLabel;
    Button3: TButton;
    DataSource3: TDataSource;
    Table3: TTable;
    Edit1: TEdit;
    Edit2: TEdit;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    procedure MsgHoraSalida(var Msg: TMessage); message WM_USER + 300;
    procedure MsgHoraLlegada(var Msg: TMessage); message WM_USER + 301;
    { Private declarations }
  public
  end;
var
  Form23: TForm23;

implementation{$R *.DFM}

uses Unit24, Unit25;

procedure TForm23.FormCreate(Sender: TObject);
begin
  table1.active:=true;
  table2.active:=true;
  button2.visible:=false
end;

procedure TForm23.Button1Click(Sender: TObject);
begin
  if (dblookupcombobox2.keyvalue) = 4 then
  begin
    form24.show
  end
  else
  if  (dblookupcombobox2.keyvalue) = 2 then
  begin
    form25.show
  end
  else
    showmessage('no existen localidades intermedias');
end;

procedure TForm23.Button3Click(Sender: TObject);
begin
  button2.visible:=true
end;

procedure TForm23.MsgHoraSalida(var Msg: TMessage);
begin
  Edit1.Text:= PChar(Msg.LParam);
end;

procedure TForm23.MsgHoraLlegada(var Msg: TMessage);
begin
  Edit2.Text:= PChar(Msg.LParam);
end;

end.

rogercito

07-09-2011 15:09:15

eso es lo que utilizo en el primer form y lo que utilizo en el segundo form es es :

Código Delphi [-]unit Unit24;
interface
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;
type
  TForm24 = class(TForm)
    Label1: TLabel;
    RadioButton1: TRadioButton;
    RadioButton2: TRadioButton;
    RadioButton3: TRadioButton;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Button1: TButton;
    Label5: TLabel;
    Label6: TLabel;
    Label7: TLabel;
    procedure FormCreate(Sender: TObject);
    procedure RadioButton1Click(Sender: TObject);
    procedure RadioButton2Click(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
var
  form24:tform24;

implementation

uses Unit23; {$R *.DFM}

procedure TForm24.FormCreate(Sender: TObject);
begin
  label5.visible:=false;
end;

procedure TForm24.RadioButton1Click(Sender: TObject);
var
  Salida,LLegada: string;
begin

  Salida:= '15:03:00';      // o convertir: TimeToStr(tu_hora_salida);...
  LLegada:= '15:30:12';
  SendMessage(FindWindow(nil, 'Form23'), WM_USER+300, 0, DWORD(PChar(Salida)));
  SendMessage(FindWindow(nil, 'Form23'), WM_USER+301, 0, DWORD(PChar(LLegada)));
  label5.visible:=true;
  //label8.visible:=true;
end;

procedure TForm24.RadioButton2Click(Sender: TObject);
begin
  label6.visible:=true;
  //label9.visible:=true;
end;

procedure TForm24.Button1Click(Sender: TObject);
begin
  form23.show;
end;

end.

rogercito

07-09-2011 15:09:58

no me aparece nada en el form 1 , en los edit

ecfisa

07-09-2011 15:19:31

Hola rogercito.

Dame unos minutos para arreglar la presentación de tus mensajes y lo voy a revisar.

Cuando utilizes código Delphi Solamente utilizá las etiquetas [delphi] [/delphi] , no es necesario el uso de LIST

Un saludo.

rogercito

07-09-2011 15:21:26

muchas graias ....lo agradezco

ecfisa

07-09-2011 15:32:41

Hola de nuevo.

En apariencia no veo nada fuera de lo normal...

Te adjunto un demo funcionando, con los dos forms llamados como los tuyos (Form23 y Form24), para que puedas cotejarlo con tu código.
Al segundo form lo creo no modal para que se puedas acomodarlos y apreciar los cambios en el momento del click sobre el TRadioButton.

Un saludo

rogercito

07-09-2011 15:47:10

el tuyo funciona de 10 ; y el mio no , en breve te aviso si logre los resultados esperados
gracias

roman

07-09-2011 16:28:40

Hola,

No es mi ánimo demeritar ninguna solución, pero he de comentar que la solución planteada por ecfisa no me parece adecuada.

Cuando una ventana A hace uso de una ventana B para obtener cierta información (en este caso las horas de llegada y salida), la ventana B debería ser ignorante de la ventana A. Esto proporciona una independencia total y permite el reuso en otras partes, además de poderse modificar sin afectar a quienes la usan.

Piensen, por ejemplo, en un cuadro de diálogo para abrir un archivo (un OpenFileDialog). Una ventana puede hacer uso de él para obtener el nombre de un archivo, pero el cuadro de diálogo en sí, no tiene conocimiento alguno de nuestra ventana.

En la técnica propuesta, hay un conocimiento implícito de la ventana A desde el momento en que se usa el nombre de ella para lanzar el mensaje de actualización.

Si se quiere una actualización instantánea hay otras maneras de lograrla sin perder la independencia de la ventana que provee el servicio, por ejemplo, mediante el usao de eventos:

Código Delphi [-]THoraChange = procedure(Sender: TObject; NuevaHora: TTime) of object;

TForm2 = class(TForm)
private
  FOnHoraLlegadaChange: THoraChange;
  FOnHoraSalidaChange: THoraChange;

public
  property OnHoraLlegadaChange: THoraChange
    read FOnHoraLlegadaChange write FOnHoraLlegadaChange;

  property OnHoraSalidaChange: THoraChange
    read FOnHoraSalidaChange write FOnHoraSalidaChange;

En el evento OnChange del RadioButton:

Código Delphi [-]if Assigned(FOnHoraLlegada) then
  FOnHoraLlegada(Self, LaHoraQueCorresponda)

if Assigned(FOnHoraSalida) then
  FOnHoraSalida(Self, LaHoraQueCorresponda)

El formulario que llama, se suscribe al evento al momento de abrir la ventana:

Código Delphi [-]Form2.OnHoraLlegadaChange := HoraLlegadaChange;
Form2.OnHoraSalidaChange := HoraSalidaChange;

if Form2.ShowModal = mrOk then
  ...

donde HoraLlegadaChange y HoraSalidaChange son métodos declarados en Form1, del tipo THoraChange. Así, por ejemplo:

Código Delphi [-]procedure TForm1.HoraLLegadaChange(Sender: TObject; NuevaHora: TTime);
begin
  EditHoraLlegada.Text := TimeToStr(NuevaHora);
end;

// Saludos

Delphius

07-09-2011 16:33:29

Para hacerla corta roman, una versión simplificada de un Observador ;)
A mi me gusta esa idea :cool:

Saludos,

La franja horaria es GMT +2. Ahora son las 08:25:57.

Página 1 de 2

Mostrar 40 mensajes desde este tema en una página