Foros Club Delphi - Leve problema con parámetros.

Foros Club Delphi (https://www.clubdelphi.com/foros/index.php)

- SQL (https://www.clubdelphi.com/foros/forumdisplay.php?f=6)

- - Leve problema con parámetros. (https://www.clubdelphi.com/foros/showthread.php?t=75893)

marcoszorrilla

25-09-2011 20:27:35

Leve problema con parámetros.

Esta es la sentencia SQL, ataco una BD Firebird 2.5 con IBX y Delphi 7.

Código Delphi [-]procedure TfrFactMes.SpeedButton1Click(Sender: TObject);
begin
DmFact.IBDtsAlbaran.Close;
DmFact.IBDtsAlbaran.ParamCheck := True;
DmFact.IBDtsAlbaran.SelectSQL.Clear;
DmFact.IBDtsAlbaran.SelectSQL.Add('Select * From Albaranes');
DmFact.IBDtsAlbaran.SelectSQL.Add('Where CodClient ='+QuotedStr(DmFact.IBDtsCliCODIGO.Value));
//DmFact.IBDtsAlbaran.SelectSQL.Add(' And Fecha <= :f1');
//DmFact.IBDtsAlbaran.ParamByName('f1').AsDate:=DtpkHasta.Date;
DmFact.IBDtsAlbaran.SelectSQL.Add('And Activo =''S''');
DmFact.IBDtsAlbaran.SelectSQL.Add('And Facturar =''S''');
DmFact.IBDtsAlbaran.SelectSQL.Add('And Fecha <='+QuotedStr(FormatDateTime('mm/dd/yy',DtpkHasta.Date)));
DmFact.IBDtsAlbaran.SelectSQL.Add('Order by Fecha');

ShowMessage(DmFact.IBDtsAlbaran.SelectSQL.Text);
DmFact.IBDtsAlbaran.Open;
pnAlbaranes.Enabled:=True;
end;

El problema es que si utilizo parámetros no me funciona, no da error, símplemente no devuelve ningún registro, aunque lo he resuelto sin parámetros me gustaría saber cual es el problema.

Un Saludo.

Caral

25-09-2011 21:02:02

Hola
Lo que me da curiosidad es por que el uso de QuotedStr.
Esto lo que hace, segun entiendo, es colocar comillas en la consulta y me da curiosidad que lo uses para obtener la fecha.
Saludos

ecfisa

25-09-2011 21:14:47

Hola Marcos.

Hice una tabla resumida para la prueba:

Código SQL [-]CREATE TABLE ALBARANES (
    ID_ALBARANES  INTEGER,
    CODCLIENT     CHAR(5),
    ACTIVO        CHAR(1),
    FACTURAR      CHAR(1),
    FECHA         DATE
);

Ingresé los siguientes datos:

Código:

ID_ALBARANES        CODCLIENT   ACTIVO  FACTURAR  FECHA

1                00001            S            S              01/09/2011

2                00002            S            S              02/09/2011

3                00003            S            S              03/09/2011

4                00004            S            S              04/09/2011

Puse un IBQuery, un DataSource y un DBGrid. No pareciera ser cosa de los parámetros, usando este código funciona bién:

Código Delphi [-]  with IBQuery1 do
  begin
    Close;
    SQL.Clear;
    SQL.Add('SELECT * FROM ALBARANES');
    SQL.Add('WHERE CODCLIENT = :CODCLI');
    SQL.Add('AND ACTIVO = :ACTIVO ');
    SQL.Add('AND FACTURAR = :FACTURA ');
    SQL.Add('AND FECHA <= :FECHA ');
    SQL.Add('ORDER BY FECHA');
    ParamByName('CODCLI').AsString:= '00004';
    ParamByName('ACTIVO').AsString:= 'S';
    ParamByName('FACTURA').AsString:= 'S';
    ParamByName('FECHA').AsString:= '04/09/2011';
    Open;
  end;

DBGrid:

Código:

4 00004 S S 04/09/2011

Un saludo.

Edito: Reacomodé las lineas del where para que se entienda mejor

ecfisa

25-09-2011 21:31:23

Creo que descubrí donde está el problema:

Si hago:

Código Delphi [-]procedure TForm1.Button1Click(Sender: TObject);
var
  D: TDate;
begin
  D:= StrToDate('04/09/2011');
  with IBQuery1 do
  begin
    Close;
    Paramcheck:= True;
    SQL.Clear;
    SQL.Add('SELECT * FROM ALBARANES');
    SQL.Add('WHERE CODCLIENT = :CODCLI');
    SQL.Add('AND ACTIVO = :ACTIVO ');
    SQL.Add('AND FACTURAR = :FACTURA ');
    SQL.Add('AND FECHA <= :FECHA ');
    SQL.Add('ORDER BY FECHA');
    ParamByName('CODCLI').AsString:= '00004';
    ParamByName('ACTIVO').AsString:= 'S';
    ParamByName('FACTURA').AsString:= 'S';
    ParamByName('FECHA').AsString:= FormatDateTime('mm/dd/yy',D);
    Open;
  end;
end;

No muestra nada.

De este modo funciona bién:

Código Delphi [-]procedure TForm1.Button1Click(Sender: TObject);
var
  D: TDate;
begin
  D:= StrToDate('04/09/2011');
  with IBQuery1 do
  begin
    Close;
    Paramcheck:= True;
    SQL.Clear;
    SQL.Add('SELECT * FROM ALBARANES');
    SQL.Add('WHERE CODCLIENT = :CODCLI');
    SQL.Add('AND ACTIVO = :ACTIVO ');
    SQL.Add('AND FACTURAR = :FACTURA ');
    SQL.Add('AND FECHA <= :FECHA ');
    SQL.Add('ORDER BY FECHA');
    ParamByName('CODCLI').AsString:= '00004';
    ParamByName('ACTIVO').AsString:= 'S';
    ParamByName('FACTURA').AsString:= 'S';
    ParamByName('FECHA').AsString:= DateToStr(D);
    Open;
  end;
end;

Y es por que usando FormatDateTime('dd/mm/yy'..) , se envía: 04/09/11 y con DateToStr: 04/09/2011, es decir que tendría que ser: FormatDateTime('dd/mm/yyyy'...).

Saludos.

marcoszorrilla

25-09-2011 22:18:38

Gracias a todos por las observaciones:

Caral:

Código Delphi [-]DmFact.IBDtsAlbaran.SelectSQL.Add('And Fecha <='+QuotedStr(FormatDateTime('mm/dd/yyyy',DtpkHasta.Date)));

Sino utilizó QuotedStr, para envolver entre comillas la fecha me arroja un error de "Conversion String", este formato ya vengo utilizándolo hace tiempo con éxito.

ecfisa:

Utilizando:

Código Delphi [-]DmFact.IBDtsAlbaran.ParamByName('f1').AsString:=DateToStr(DtPkHasta.Date);

Sigue sin devolverme nada, DtpkHasta es un DateTimePicker.

Con la expresión que comenta Caral es con la que me funciona.

Un Saludo.

marcoszorrilla

25-09-2011 22:20:57

En el mismo programa me funciona:

Código Delphi [-]procedure TfrMovBancos.FormActivate(Sender: TObject);
begin
  if DmConex.IBDtsUsuariosUsuario.Value = 'ADMINISTRADOR' then
  Navega.VisibleButtons:=[nbFirst, nbPrior, nbNext, nBlast, nbDelete, nbInsert];

  DmBanc.IBDtsBanc.Close;
  DmBanc.IBDtsBanc.SelectSql.Text:='';

  case estado of
  1:begin
  DmBanc.IBDtsBanc.SelectSQL.Text:='Select * From Banco';
  frMovBancos.Caption:='Consulta de Movimientos Bancarios - Todos';
    end;

  2:begin
  DmBanc.IBDtsBanc.SelectSQL.Text:='Select * From Banco Where Comentario is null';
  frMovBancos.Caption:='Consulta de Movimientos Bancarios - No punteados';
    end;

  3:begin
  DmBanc.IBDtsBanc.SelectSQL.Add('Select * From Banco ');
  DmBanc.IBDtsBanc.SelectSQL.Add('Where foperacion Between :Ini And :Fin');
  DmBanc.IBDtsBanc.ParamByName('Ini').AsDate:=dIni;
  DmBanc.IBDtsBanc.ParamByName('Fin').AsDate:=dFin;

    frMovBancos.Caption:='Consulta de Movimientos Bancarios - entre '+DateToStr(dIni)+' y '+DateToStr(dFin);
    end;

  4:begin
  DmBanc.IBDtsBanc.SelectSQL.Text:='Select * From Banco Where Concepto like ' +'''%'+cFiltro+'%''';
  frMovBancos.Caption:='Consulta de Movimientos Bancarios - por Concepto:'+cFiltro;
    end;

  5:begin
  DmBanc.IBDtsBanc.SelectSQL.Text:='Select * From Banco Where Comentario like ' +'''%'+cFiltro+'%''';
  frMovBancos.Caption:='Consulta de Movimientos Bancarios - por Comentario:'+cFiltro
    end;


  6:begin
  DmBanc.IBDtsBanc.SelectSQL.Add('Select * From Banco Where Cargos Between ' +IntToStr(CantIni)+' And '+ IntToStr(CantFin));
  DmBanc.IBDtsBanc.SelectSQL.Add(' Or Abonos Between ' +IntToStr(CantIni)+' And '+ IntToStr(CantFin));
  frMovBancos.Caption:='Consulta de Movimientos Bancarios (cargos o abonos) - Entre '+ IntToStr(CantIni)+' y '+ IntToStr(CantFin)+' €';
    end;
  end;
 
  DmBanc.IBDtsBanc.Open;
  DmBanc.IbDtsBanc.Last;
end;

Un Saludo.

marcoszorrilla

25-09-2011 22:23:05

O esto:

Código Delphi [-] if lUnVendedor = True then
  IbDtsQrSuma.SelectSql.Add('And F.Vendedor = '+QuotedStr(DmCli.IbDtsVendCodigo.Value));

IbDtsQrSuma.SelectSql.Add('Group by C.Codigo,C.Buscar, F.Codclient');
IbDtsQrSuma.SelectSql.Add('Having Sum(Base) between :desde  And :Hasta');
IbDtsQrSuma.SelectSql.Add('Order by 3 Desc');
IbDtsQrSuma.ParamByName('desde').AsFloat:=StrToFloat(edDesde.Text);
IbDtsQrSuma.ParamByName('hasta').AsFloat:=StrToFloat(edhasta.Text);
IbDtsQrSuma.ParamByName('Ini').AsDate:= frDesdeHasta.dtpkfini.Date;
IbDtsQrSuma.ParamByName('Fin').AsDate:= frDesdeHasta.DtpkFFin.Date;
//ShowMessage(IbDtsQrSuma.SelectSql.Text);

IbDtsQrSuma.Open;
TFloatField(IbDtsQrSuma.Fields[2]).DisplayFormat:=',0.00';
TFloatField(IbDtsQrSuma.Fields[3]).DisplayFormat:=',0.00';
TFloatField(IbDtsQrSuma.Fields[4]).DisplayFormat:=',0.00';
lbAviso.Visible:=False;
pnDatos.Visible:=True;

DbgDesde.Columns[0].Width:=55;
DbgDesde.Columns[1].Width:=175;
DbgDesde.Columns[2].Width:=75;
DbgDesde.Columns[3].Width:=75;
DbgDesde.Columns[4].Width:=75;
DbgDesde.Columns[5].Width:=50;
IbDtsQrSuma.Last;

Un Saludo.

ecfisa

25-09-2011 23:01:06

Cita:

Empezado por marcoszorrilla (Mensaje 413401)

ecfisa:

Utilizando:

Código Delphi [-]DmFact.IBDtsAlbaran.ParamByName('f1').AsString:=DateToStr(DtPkHasta.Date);

Sigue sin devolverme nada, DtpkHasta es un DateTimePicker.

Hola Marcos.

No sabía que era un DateTimePicker, ¿ Pero entonces no te convendría asignar directamente el valor como TDate ?

Con los datos que use en la prueba (mensaje #3), este código me funciona bién:

Código Delphi [-]procedure TForm1.dpkHastaChange(Sender: TObject);
begin
  with IBQuery1 do
  begin
    Close;
    SQL.Clear;
    SQL.Add('SELECT * FROM ALBARANES');
    SQL.Add('WHERE CODCLIENT = :CODCLI');
    SQL.Add('AND ACTIVO = :ACTIVO ');
    SQL.Add('AND FACTURAR = :FACTURA ');
    SQL.Add('AND FECHA <= :FECHA ');
    SQL.Add('ORDER BY FECHA');
   // uso la fecha para armar el código ya que en los datos, coinciden el número de día con código de cliente
    ParamByName('CODCLI').AsString:= '000'+Copy(DateToStr(dpkHasta.Date),1,2);
    ParamByName('ACTIVO').AsString:= 'S';  // en la tabla todos tienen valor 'S'
    ParamByName('FACTURA').AsString:= 'S';// en la tabla todos tienen valor 'S'
    ParamByName('FECHA').AsDate:= dpkHasta.Date;
    Open;
  end;
end;

Saludos.

marcoszorrilla

25-09-2011 23:09:03

Eso es lo que he hecho inicialmente y no me funciona de forma inexplicable, porque como ves en otras partes de la misma aplicación si lo hace, pero recuerdo que en algún sitio más he tenido que recurrir ala misma solución que en este caso.

A ver si logro establecer que circunstancias concurren cuando no me funcionan los parámetros, curiosamente ocurre con fechas.

Si observas mi primer mensaje tengo comentado ese formato porque no me funciona.

Código Delphi [-]//DmFact.IBDtsAlbaran.SelectSQL.Add(' And Fecha <= :f1'); 
//DmFact.IBDtsAlbaran.ParamByName('f1').AsDate:=DtpkHasta.Date;

Un Saludo.

Caral

25-09-2011 23:26:03

Hola
Para mi sigue siendo extraño el uso de QuotedStr, sobre todo con la fecha y mas si es obtenida de un datetimepicker.
Yo hago esto y funciona perfectamente:

Código Delphi [-]ADOQuery1.SQL.Add(' AND Fecha >= :f1 AND Fecha <= :f2');
ADOQuery1.SQL.Add(' ORDER BY Fecha, Factura.CodFactura;');
ADOQuery1.Params[0].Value:= DateToStr(DTP1.Date);
ADOQuery1.Params[1].Value:= DateToStr(DTP2.Date);
ADOQuery1.Open;

OJO, no os confundáis, no son componentes ADO, son IBX.
Simplemente se llaman asi por motivos de vagancia.:D
Saludos

Delphius

26-09-2011 01:35:47

Hola Marcos,
Creo tal vez que parte del problema se deba a que en tu primer código expuesto mientras estás armando la consulta, justamente quieres pasar el dato al parámetro (el :f1) y luego continuar armando la consulta.

Es deseable primeramente armar la consulta, entera, y luego si proceder con el paso de datos a los parámetros. Por seguridad.

Por otro lado, creo que la posible discrepancia entre el .AsDate y el uso de FormatDateTime para armar la consulta también es motivo de problemas. ¿Te aseguraste de revisar la configuración regional para que dé el formato adecuado?

Se supone, en teoría, que la implementación del AsDate es la más segura ya que éste toma la responsabilidad de darle el formato adecuado y que corresponde al formato nativo que utiliza el motor.

Haz una prueba, muestra el contenido de un .AsDate y compáralo con un FormatDateTime para ver si hay alguna diferencia.

Saludos,

marcoszorrilla

26-09-2011 09:34:38

Delphius tu observación fue la correcta, colocando la entrada de los parámetros al final ha funcionado.

Código Delphi [-]procedure TfrFactMes.SpeedButton2Click(Sender: TObject);
begin
DmFact.IBDtsAlbaran.Close;
DmFact.IBDtsAlbaran.ParamCheck := True;
DmFact.IBDtsAlbaran.SelectSQL.Clear;
DmFact.IBDtsAlbaran.SelectSQL.Add('Select * From Albaranes');
DmFact.IBDtsAlbaran.SelectSQL.Add('Where CodClient = :C1');
DmFact.IBDtsAlbaran.SelectSQL.Add(' And Fecha <= :F1');
DmFact.IBDtsAlbaran.SelectSQL.Add('And Activo =''S''');
DmFact.IBDtsAlbaran.SelectSQL.Add('And Facturar =''S''');
DmFact.IBDtsAlbaran.SelectSQL.Add('Order by Fecha');
DmFact.IBDtsAlbaran.ParamByName('C1').AsString:=DmFact.IBDtsCliCODIGO.Value;
DmFact.IBDtsAlbaran.ParamByName('F1').AsDate:=DtpkHasta.Date;
DmFact.IBDtsAlbaran.Open;
end;

Un Saludo.

Delphius

26-09-2011 17:20:31

Cita:

Empezado por marcoszorrilla (Mensaje 413438)

Delphius tu observación fue la correcta, colocando la entrada de los parámetros al final ha funcionado.

Un Saludo.

Me alegro haber aportado en algo. Algo ya me decía que el problema estaba justo en eso. :rolleyes:
La verdad es que a mi, hasta el momento, nunca se me ha dado por pasar los datos a los parámetros en el medio del armado de la consulta por lo que no he tenido problemas con ellos.

Y más, habiéndome medio informado (viendo el código y leyendo la documentación) sobre como trabaja la clase TParams y TParam es que ni me animaría a hacerlo. ;)

Saludos,

marcoszorrilla

26-09-2011 20:37:05

Siempre los coloco al final lo que sucede es que añadí una linea máspara colocar el Order by y la puse detras de la última y a partir de ahí dejó de funcionarme, pero no me di cuenta de cual era el motivo, luego me maree cambiando las líneas y haciendo pruebas y no hubo manera.

Un Saludo.

La franja horaria es GMT +2. Ahora son las 04:51:11.