Centrar texto en una fila de un DBGRID
 

Hola amigos ... mi pregunta es sencilla ¿cómo hago para centrar el texto verticalmente de una celda en un DBGRID?

Gracias

Tienes que utilizar el evento OnDrawColumnsCell del DBGrid y "repintar" la celda "Manualmente".

Si haces una búsqueda utilizando el nombre del evento encontrarás muchos mensajes con código similar o igual al que necesitas.

Hola mcsebas.

Centrar texto vertical es posible, pero de acuerdo a la longitud que tenga el campo que se visualiza en la celda puede ser inviable.
No hay un modo de ajustar el tamaño del font para "encajar" textos de longitudes variables en determinado tamaño y que quede presentable. Lo mas simple es fijar el alto a la máxima longitud que puede alcanzar. Esto se complica así, por que el texto se debe mostrar en sentido vertical y las celdas tendrían que ser excesivamente altas.

Con un campo corto y de longitud fija no existiría problema...(Si tu gusto no es muy exigente :)). Como primera medida hay que extender el alto de las filas del TDBGrid para que el texto quepa en su nueva orientación. Podes aprovechar la estructura LOGFONT para rotar el texto y usar el evento OnDrawColumnCell para "dibujar" el texto vertical.

Te pongo un código de ejemplo que usa un TDBGrid asociado a la tabla orders de dbdemos.mdb que viene con Delphi para que puedas reproducirlo. La columna que se presenta con centrado vertical es la correspondiente al campo OrderNo:

Código Delphi [-]
...
implementation

const
  COLHEIGHT = 70;

procedure TForm1.FormCreate(Sender: TObject);
begin
  TStringGrid(DBGrid1).DefaultRowHeight:= COLHEIGHT; 
end;

procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  LF: LOGFONT;
begin
  if Column.FieldName = 'OrderNo' then
    with Sender as TDBGrid do
    begin
      ZeroMemory(@LF, SizeOf(LF));
      lf.lfHeight:= Canvas.Font.Height ;
      lf.lfWidth:= Canvas.Font.Size;
      LF.lfEscapement:= 10 * 90;
      LF.lfCharSet:= DEFAULT_CHARSET;
      LF.lfFaceName:= 'Arial';
      Canvas.FillRect(Rect);
      Canvas.Font.Handle:= CreateFontIndirect(LF);
      Canvas.TextOut(Rect.Left+(Rect.Right-Rect.Left) shr 1 - LF.lfWidth,
        Rect.Bottom+LF.lfHeight,Column.Field.AsString);
    end;
end;
end.

La presentación es esta:


Saludos :)

Creo que eso es orientación vertical, no centrado vertical (que es lo que pide mcsebas).

De todas formas es interesante el código.
Guardado. ^\||/

Sabes que creo que tenes razón... :o

mcsebas, la función Api DrawText hace muy simple centrar texto de forma vertical u horizontal.

Código Delphi [-]
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  R: TRect;
  Grid: TDBGrid;
begin
  R:= Rect;
  Grid:= TDBGrid(Sender);
  FillRect(Grid.Canvas.Handle, R, HBRUSH(Grid.Color));
  DrawText(Grid.Canvas.Handle, PChar(Column.Field.AsString),-1, R, DT_SINGLELINE or
           DT_VCENTER or  // Centrado vertical
           DT_CENTER);    // Centrado horizontal
end;

Y tampoco es complicado usando los métodos de TCanvas:

Código Delphi [-]
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  Grd: TDBGrid;
  Str: string;
begin
  Grd:= TDBGrid(Sender);
  Str:= Column.Field.AsString;
  Grd.Canvas.FillRect(Rect);
  Grd.Canvas.TextRect(Rect,
    (Rect.Right + Rect.Left-Grd.Canvas.TextWidth(Str)) shr 1, // Centrado horizontal
    (Rect.Top + Rect.Bottom-Grd.Canvas.TextHeight(Str))shr 1, // Centrado vertical
    Str);
end;

Cualquiera de los dos hace bién la taréa, elegí el de tu gusto. Evité el uso de with para que el código resulte mas claro.

Saludos :)

Se pasaron son unos genios !!!
Graciaaaaaaaaaaaas!!!

Sabes que probe en Lazarus el ejemplo en donde el metodo FillRect usa el HBRUSH pero en Delphi me causa problemas. ¿Que podrá ser?
Ahora usando el otro método perfecto ahora habrá una forma de que NO sea centrado horizontalmente.

Gracias

Hola mcsebas.

No se el problema ni la versión de Delphi que usas, pero podrías probar con:

Código Delphi [-]
 FillRect(Grid.Canvas.Handle, R,  0);

o también con:

Código Delphi [-]
Grid.Canvas.FillRect(Rect);

Sólamente quitá la constante de formato de centrado que no desees:

Código Delphi [-]
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  R: TRect;
  Grid: TDBGrid;
begin
  R:= Rect;
  Grid:= TDBGrid(Sender);
  FillRect(Grid.Canvas.Handle, R,  0); // o Grid.Canvas.FillRect(Rect);
  DrawText(Grid.Canvas.Handle, PChar(Column.Field.AsString),-1, R, DT_SINGLELINE or
           DT_VCENTER ); // Centrado vertical
end;

Saludos :)

Me olvide decirte que utilizo Delphi XE5 pero haciendo bien el testeo me da un error de access violation en el metodo DRAWTEXT.
Ahora si que no se como solucionarlo :(

Sabes que lo pude solucionar como no me voy a dar cuenta de que me faltaba llenar todas las columnas del DBGRID .... suele pasar que algunas veces uno se olvida ciertas cosas que son tan insignificantes pero que te joden el proyecto en fin.

Gracias