Agregar digitos
 

Hola.

reglas que se tienen que cumplir:

Numero de Personas: tiene que tener 11 dígitos (sino tiene los 11 dígitos rellenar con 0 a la derecha los dígitos
faltan-te);


Ej: Nº personas 12345 : entonces que me imprima en pantalla lo siguiente=00000012345


se que tengo que utilizar una condicion de pregunta, y utlizar las funciones pos, str (pero hasta hay es lo que se)...

espero sus respuesta por favor y gracias...

Hola maxzama.

Tres opciones:

Código Delphi [-]
var
  cad: string;
begin
  cad:= '12345';
  ShowMessage(
  {Opcion 1} StringOfChar('0', 11 - Length(cad)) + cad   + ' - ' +
  {Opcion 2} Format('%.11d',[StrToInt(cad)]) + ' - ' +
  {Opcion 3} Copy('00000000000', 1, 11 - Length(cad)) + cad
  );

Saludos :)

Como siempre, tú esforzándote al máximo para aprender ;)

gracias, tu información esta copiado y plasmado...

maxzama,

:rolleyes:

Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
   LenStr : Integer;
   AuxStr : String;
   i : Integer;

begin

    AuxStr := Edit1.Text;

    LenStr := Length(AuxStr);

    if LenStr > 11 then
       raise Exception.Create('Longitud Máxima de Variable es 11');

    for i := 1 to LenStr do
       if not (AuxStr[i] in ['0'..'9']) then
          raise Exception.Create('Solo se Permiten Caracteres Númericos');

    if LenStr < 11 then
       AuxStr := StringOfChar('0', 11-LenStr) + Edit1.Text;

    ShowMessage(AuxStr);

end;

procedure TForm1.Button2Click(Sender: TObject);
var
   LenStr : Integer;
   AuxStr : String;
   i : Integer;

begin

   AuxStr := Edit1.Text;

   LenStr := Length(AuxStr);

   if LenStr > 11 then
      raise Exception.Create('Longitud Máxima de Variable es 11');

   for i := 1 to LenStr do
      if not (AuxStr[i] in ['0'..'9']) then
         raise Exception.Create('Solo se Permiten Caracteres Númericos');

   AuxStr := Format('%.11d',[StrToInt(Edit1.Text)]);

   ShowMessage(AuxStr);

end;

end.

El código anterior en Delphi 7 sobre Windows 7 Professional x32, permite rellenar con 0 a la izquierda una cantidad numérica de máximo 11 dígitos y muestra el resultado por medio de 2 métodos diferentes.

Espero sea útil :)

Nelson.

Gracias, me a sido muy útil (nlsgarcia). Me as dado nuevas ideas...

Asi es: Casimiro Notevi.

jajaja.

Te entiendo Casimiro Notevi. Se que no muestro mis código(al hacer las preguntas), pero antes de hacer una pregunta, leo bastante.

Y así es como entiendo, de cada código que me muestran(aunque sea un código sencillo).

Bueno, está bien que aprendas, de eso se trata :)

maxzama,

:rolleyes:

Revisa esta información:
Espero sea útil :)

Nelson.

Hola, nuevamente.

// e intentado varias veces y no e encontrado hacer lo siguiente:

Como puedo agregar los 0 al contrario. Es decir agregar lo cero a la derecha...


Ej:

Código Delphi [-]
Regla a cumplir: cad= 10 dígitos;

cad:123

imprima en pantalla 1230000000

Este es el siguiente código(Se que son, para reírse o llorar ):

n:=StringOfChar(' ',11)

while not (Length(n)=cad) do
begin
      cad:=cad+'0';
      next;
end;

espero sus respuesta por favor y gracias...

gracias, nlsgarcia. (ya tengo conque, para perder el tiempo)...

maxzama,

:rolleyes:

Revisa este código:

Código Delphi [-]
procedure TForm1.Button3Click(Sender: TObject);
var
   LenStr : Integer;
   AuxStr : String;
   i : Integer;

begin

    AuxStr := Edit1.Text;

    LenStr := Length(AuxStr);

    if LenStr > 11 then
       raise Exception.Create('Longitud Máxima de Variable es 11');

    for i := 1 to LenStr do
       if not (AuxStr[i] in ['0'..'9']) then
          raise Exception.Create('Solo se Permiten Caracteres Númericos');

    if LenStr < 11 then
       AuxStr := Edit1.Text + StringOfChar('0', 11-LenStr);

    ShowMessage(AuxStr);

end;

El código anterior en Delphi 7 sobre Windows 7 Professional x32, permite rellenar con 0 a la derecha una cantidad numérica de máximo 11 dígitos y muestra el resultado.

Espero sea útil :)

Nelson.

gracias, disculpa la molestia.

lo tenia en mis narices:

Código Delphi [-]
AuxStr := Edit1.Text + StringOfChar('0', 11-LenStr);

Código Delphi [-]
He := h+StringOfChar ‎('0',10-length(h));

Hola maxama.

Y para redondear la cosa, podés unificar las acciones en una sola función que reciba como parámetro una cantidad arbitraria de ceros:

Código Delphi [-]
type
  TZeroCourse = (zLeft, zRight);

function AddZeros(const cifra: string; const zeros: Integer;
  Course: TZeroCourse): string;
begin
  if Course = zLeft then
    Result:= StringOfChar('0', zeros - Length(cifra)) + cifra
  else
    Result:= cifra + StringOfChar('0', zeros - Length(cifra));
end;

Ejemplo de uso:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
begin
  Label1.Caption:= AddZeros('13245',17, zLeft);
  Label2.Caption:= AddZeros('12345',15, zRight);
end;

Saludos :)

Daniel,

^\||/

Nelson.

De hecho, si además le pasas otro parámetro "const Carácter: Char" puedes concatenar cualquier tipo de dígito o carácter alfanumérico:

Código Delphi [-]
type
  TZeroCourse = (zLeft, zRight);

function AddChars(const cifra: string; const zeros: Integer; const Caracter: Char;
  Course: TZeroCourse): string;
begin
  if Course = zLeft then
    Result:= StringOfChar(Caracter, zeros - Length(cifra)) + cifra
  else
    Result:= cifra + StringOfChar(Caracter, zeros - Length(cifra));
end;

Y su uso, por ejemplo:

Código Delphi [-]
Label1.Caption:= AddChars('13245',17, '*', zLeft);

Saludos