[[Al González]]

¡Hola de nuevo!

Gracias por la aclaración Descendents.

Comprendiendo la naturaleza de este caso, debo decir que lo mejor sería crear una nueva clase de objeto banda para Quick Report. Donde el evento BeforePrint esté redefinido. Ejemplo:

Interface
  ...

  Type
    TBandQuickReport = Class (TQRBand)
      Private
        FBeforePrint :TQRBandBeforePrintEvent;

        { Manejador de Evento Before Print interno }
        Procedure ManeEvenBeforePrint (
          Remitente :TQRCustomBand; Var Imprimir :Boolean);
      Public
        Constructor Create (AOwner :TComponent); Override;
      Published
        { Evento Before Print redefinido (manejador de
          evento externo)                              }
        Property BeforePrint :TQRBandBeforePrintEvent
          Read FBeforePrint Write FBeforePrint;
    End;

  ...
Implementation
  ...

  { TBandQuickReport }

  Constructor TBandQuickReport.Create (AOwner :TComponent);
  Begin
    Inherited Create (AOwner);
    Inherited BeforePrint := ManeEvenBeforePrint;
  End;

  Procedure TBandQuickReport.ManeEvenBeforePrint (
    Remitente :TQRCustomBand; Var Imprimir :Boolean);
  Begin
    { Aquí puede ir código común para todas las bandas }

    { Llamar al manejador de evento BeforePrint externo }
    If Assigned (BeforePrint) Then
      BeforePrint (Self, Imprimir);

    { Aquí puede ir código común para todas las bandas }
  End;

De esta manera, cada banda de clase TBandQuickReport agregada al reporte tendrá internamente el comportamiento deseado, antes o después de dispararse el manejador de evento BeforePrint establecido por el programador final.

Bajo las circustancias que planteas, creo que definitivamente esta es la solución más adecuada. Esto se acostumbra en programación orientada a objetos cuando se tiene una clase y se crea una segunda clase derivada de la primera para agregarle características extras.

Espero esto sea de utilidad. Mantenernos informados.

Al González .