[delphi.com.ar]

Empezado por toni.vi

1.- Como puedo mantener los attributos de las fotos originales, es decir fecha de creacion o Imagen tomada del dia...etc

Para este punto, creo que esto te va a servir:

Código Delphi [-]
function GetFileTimeByName(lpFileName: PAnsiChar; lpCreationTime, lpLastAccessTime, lpLastWriteTime: PFileTime): boolean;
var
  hFile: THandle;
begin
  hFile := CreateFile(lpFileName, GENERIC_READ, FILE_SHARE_READ, Nil, OPEN_EXISTING, 0, 0);
  if hFile <> 0 Then
    try
      Result := GetFileTime(hFile, lpCreationTime, lpLastAccessTime, lpLastWriteTime);
    finally
      CloseHandle(hFile);
    end
  else
    Result := False;
end;

function SetFileTimeByName(lpFileName: PAnsiChar; lpCreationTime, lpLastAccessTime, lpLastWriteTime: PFileTime): boolean;
var
  hFile: THandle;
begin
  hFile := CreateFile(lpFileName, GENERIC_WRITE, FILE_SHARE_READ, Nil, OPEN_EXISTING, 0, 0);
  if hFile <> 0 Then
    try
      Result := SetFileTime(hFile, lpCreationTime, lpLastAccessTime, lpLastWriteTime);
    finally
      CloseHandle(hFile);
    end
  else
    Result := False;
end;

function CopyFileTimes(lpSource, lpDest: PAnsiChar): boolean;
var
  ftCreationTime,
  ftLastAccessTime,
  ftLastWriteTime: TFileTime;
begin
  if GetFileTimeByName(lpSource, @ftCreationTime, @ftLastAccessTime, @ftLastWriteTime) then
    Result := SetFileTimeByName(lpDest, @ftCreationTime, @ftLastAccessTime, @ftLastWriteTime)
  else
    Result := False;
end;

Simplemente deberías utilizar la función CopyFileTimes pasando el archivo origen y destino.

Para el resto... ¿Es necesario que lo cargues en un TImage?

Saludos!