[[nlsgarcia]]

danielmj,

Empezado por danielmj

...trato de buscar una cadena dada en un TRichEdit...partir del texto seleccionado en un ComboBox...

Empezado por ecfisa

...existen formas mas sofisticadas de búsqueda para un TRichEdit, usando FindDialog y FindText...

Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    Button1: TButton;
    FindDialog1: TFindDialog;
    ComboBox1: TComboBox;
    procedure Button1Click(Sender: TObject);
    procedure FindDialog1Find(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
   ComboBox1.Items.LoadFromFile('Search_Parameters.txt');
   RichEdit1.Lines.LoadFromFile('Search_File.txt');
end;

procedure TForm1.FindDialog1Find(Sender: TObject);
var
   FoundAt: LongInt;
   StartPos, ToEnd: Integer;

begin
   with RichEdit1 do
   begin
     if SelLength <> 0 then
        StartPos := SelStart + SelLength
     else
        StartPos := 0;

     ToEnd := Length(Text) - StartPos;

     FoundAt := FindText(FindDialog1.FindText, StartPos, ToEnd, [stMatchCase]);
     if FoundAt <> -1 then
     begin
        SetFocus;
        SelStart := FoundAt;
        SelLength := Length(FindDialog1.FindText);
     end
     else
        SelStart := 0;
   end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
   FindDialog1.FindText := ComboBox1.Text;
   FindDialog1.Position := Point(0,0);
   FindDialog1.Execute;
end;

end.

El código anterior en Delphi 7 bajo Windows 7 Professional x32, realiza búsquedas de texto en un TRichEdit por medio de un TComboBox y un TFindDialog como se muestra en la siguiente imagen:



El código esta disponible en : FindText_RichEdit

Espero sea útil

Nelson.