Texto de Edit a Image BMP?

[wolfran_hack]

Tenemos un Edit que tiene un texto, por ejemplo un numero y necesitamos que ese numero se aplique a un Image o bmp con negrita y demás para ser impreso. Esto es posible?

[[AgustinOrtu]]

Necesitas si o si la imagen? No podes usar un RichEdit?

[wolfran_hack]

si tiene que ser una imagen porque el printer de delphi xe no se pasa a multiplataforma y solo logre imprimir bmp

[[AgustinOrtu]]

No soy ningun experto pero proba con esto

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    Button1: TButton;
    PaintBox1: TPaintBox;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  // dibujar texto del edit en el paintbox
  PaintBox1.Canvas.Font.Style := [fsBold];
  PaintBox1.Canvas.Font.Name := 'Calibri';
  PaintBox1.Canvas.Font.Size := 190;
  PaintBox1.Color := clWhite;
  PaintBox1.Canvas.Rectangle(0, 0, PaintBox1.Width, PaintBox1.Height);
  PaintBox1.Canvas.TextOut(PaintBox1.Width div 4, 1, Edit1.Text);
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  FImage: TBitmap;
  FDest, FSource: TRect;
begin
  // guardar la imagen generada
  FImage := TBitmap.Create;
  try
    FImage.Height := PaintBox1.Height;
    FImage.Width := PaintBox1.Width;
    FDest := Rect(0, 0, FImage.Width, FImage.Height);
    FSource := Rect(0, 0, PaintBox1.Width, PaintBox1.Height);
    FImage.Canvas.CopyRect(FDest, PaintBox1.Canvas, FSource);
    // guardar la imagen..
    FImage.SaveToFile('test.bmp');
  finally
    FImage.Free;
  end;
end;

end.

[ecfisa]

Hola wolfran_hack.

Otra opción:

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
begin
  Edit1.Color      := clSilver; // (*)
  Edit1.Font.Name  := 'Segoe Print';
  Edit1.Font.Size  := 12;
  Edit1.Font.Style := Edit1.Font.Style + [fsBold];
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  bm : TBitmap;
  cc : TControlCanvas;
  sz : TSize;
begin
  bm := Image1.Picture.Bitmap;
  cc := TControlCanvas.Create;
  try
    cc.control :=  Edit1;
    cc.Font.Assign(Edit1.Font);
    bm.Width  := cc.ClipRect.Right;
    bm.Height := cc.ClipRect.Bottom;
    GetTextExtentPoint32(cc.Handle, PChar(Edit1.Text), Length(Edit1.Text), sz);
    BitBlt(bm.Canvas.Handle, 0, 0, sz.cx, sz.cy, cc.Handle, 0, 0, SRCCOPY);
  finally
    cc.free;
  end;
end;

(*) El color clSilver es a fin de resaltar el área de lo copiado.

Salida:


Saludos

[wolfran_hack]

@ecfisa: Mil gracias, es exactamente lo que estaba buscando. Le agrego un .Picture Nil para limpiarla y volver a generarla.

Código Delphi [-]
  sz : TSize;
begin
  Image1.Picture := nil;
  bm := Image1.Picture.Bitmap;

Por ahora en Delphi7 funciona, luego probare en el DelphiXE8 haber como funciona.