Saber si hay un disco dentro del lector de CD/DVD

[REHome]

Hola:

¿Se puede saber pulsando un botón con Delphi si hay un disco dentro o no?

Aquí un ejemplo de abrir y cerrar la bandeja del lector.

unit Bandeja_Delphi;

interface

// Añadir MMSystem en el uses.
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, MMSystem;

type
  TForm1 = class(TForm)
    GroupBox_Bandeja: TGroupBox;
    Button_Abrir: TButton;
    Button_Cerrar: TButton;
    Label_Mensaje: TLabel;
    procedure Button_AbrirClick(Sender: TObject);
    procedure Button_CerrarClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button_AbrirClick(Sender: TObject);
begin
    Label_Mensaje.Caption := 'Abriendo...';
    Application.ProcessMessages;
    mciSendString('Set cdaudio door open wait', nil, 0, 0);
    Label_Mensaje.Caption := 'Abierto.';
end;

procedure TForm1.Button_CerrarClick(Sender: TObject);
begin
    Label_Mensaje.Caption := 'Cerrando...';
    Application.ProcessMessages;
    mciSendString('Set cdaudio door closed wait', nil, 0, 0);
    Label_Mensaje.Caption := 'Cerrado.';
end;

end.

No se si existe esa posibilidad.

Saludos.

[ecfisa]

Empezado por REHome

Hola:

¿Se puede saber pulsando un botón con Delphi si hay un disco dentro o no?

Hola.

...check if a disk is in the drive?

Saludos

[REHome]

Lo he intentado ahcer pero nome sale.

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
function DiskInDrive(Drive: Char): Boolean;
  // Disk can be a floppy, CD-ROM,...

var
  Form1: TForm1;
  ErrorMode: Word;

  begin
  { make it upper case }
  if Drive in ['a'..'z'] then Dec(Drive, $20);
  { make sure it's a letter }
  if not (Drive in ['A'..'Z']) then
    raise EConvertError.Create('Not a valid drive ID');
  { turn off critical errors }
  ErrorMode := SetErrorMode(SEM_FailCriticalErrors);
  try
    { drive 1 = a, 2 = b, 3 = c, etc. }
    if DiskSize(Ord(Drive) - $40) = -1 then
      Result := False
    else
      Result := True;
  finally
    { Restore old error mode }
    SetErrorMode(ErrorMode);
  end;
end;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
if DiskInDrive('a') = False then
    ShowMessage('Drive not ready');
end;

end.

[Casimiro Noteví]

Empezado por REHome

Lo he intentado ahcer pero nome sale.

"no me sale", ¿qué error es?

[REHome]

[Casimiro Noteví]

¿Lo has copiado bien?, porque yo he hecho un simple "copia->pega" y funciona perfectamente.

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    bt1: TButton;
    procedure bt1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function DiskInDrive(Drive: Char): Boolean;
  // Disk can be a floppy, CD-ROM,...
var
  ErrorMode: Word;
begin
  { make it upper case }
  if Drive in ['a'..'z'] then Dec(Drive, $20);
  { make sure it's a letter }
  if not (Drive in ['A'..'Z']) then
    raise EConvertError.Create('Not a valid drive ID');
  { turn off critical errors }
  ErrorMode := SetErrorMode(SEM_FailCriticalErrors);
  try
    { drive 1 = a, 2 = b, 3 = c, etc. }
    if DiskSize(Ord(Drive) - $40) = -1 then
      Result := False
    else
      Result := True;
  finally
    { Restore old error mode }
    SetErrorMode(ErrorMode);
  end;
end;

procedure TForm1.bt1Click(Sender: TObject);
begin
  if DiskInDrive('a') = False then
    ShowMessage('Drive not ready');
end;

end.

[[ElDioni]]

Creo que no has declarado la funcion en la cabecera, tomo un ejemplo del amigo Dec para ilustrar lo que te digo.

Código Delphi [-]
unit Global;  

interface  

function SayHello() : boolean;   

Var   
Vusuario : string;   
vCia     : string;   
MonedaBase : String;   
Detener   : boolean;  

implementation  

uses   

Dialogs;  

function SayHello() : boolean; 
begin   
Dialogs.ShowMessage( 'Hello!' );   
result := true; 
end;  

end.

Saludos.