alinear a la derecha texto de un stringgrid

[ctronx]

Saludos, como podria alinear a la derecha el contenido de una columna de un stringgrid, tomando en cuenta que mi aplicacion es CLX.

Gracias por la ayuda que puedan darme.

[yusnerqui]

Primero que nada quiero pedirte disculpa por mi falta de conocimiento (No se que es una aplicación CLX ), pero quizás el truco 234 de Trucomanía te pueda ayudar, a continuación te lo cito.

Empezado por Trucomanía

Pon este código en el evento OnDrawCell de tu StringGrid:

Código Delphi [-]
procedure TForm1.StringGrid1DrawCell(Sender: TObject; Col, Row: Integer;
  Rect: TRect; State: TGridDrawState);
var sCad:String;
    i:integer;
    bEsNum:Bool;
begin 
  if StringGrid1.Cells[Col,Row] <> '' then 
  begin 
     bEsNum := True;
     sCad := StringGrid1.Cells[Col,Row];
     for i:=1 to length(sCad) do 
         if not (sCad[i] in ['0'..'9','-']) then bEsNum := False;
     if bEsNum then 
     begin 
        {'%15 para una longitud maxima de 15 caracteres}
        {'%15 for a Max Length of 15 characteres}
        sCad := Format('%15.0n',[StrToFloat(StringGrid1.Cells[Col,Row])]);
        with StringGrid1 do 
          with Canvas,Rect do 
          begin 
             i:=Right-TextWidth(sCad+' ');
             Canvas.FillRect(Rect);
             Canvas.TextOut(i,Top+2,sCad);
          end; 
     end; 
  end; 
end;

Espero que eso te pueda ayudar.

Un saludo

[ctronx]

Saludos, gracias por tu ayuda pero tu ejemplo no me permite especificar una determinada columna para alinear a la derecha.

este ejemplo si me pide la columna que quiero alinear pero me marca que no esta declarada ó definida DrawText, a de faltar una Unit ó algo asi, espero me puedan ayudar.

Código Delphi [-]

procedure Tfrmventas.StringGrid1DrawCell(Sender: TObject; ACol,
  ARow: Integer; Rect: TRect; State: TGridDrawState);
  begin
if ACol=2 then // voy a alinear a la derecha la 3ª columna
if ARow>0 then //No quiero alinear la línea de títulos
with StringGrid1 do
     begin
     Canvas.FillRect(Rect);
     DrawText(Canvas.Handle,PChar(Cells[Acol,ARow]),-1,Rect,
          DT_CENTER or DT_RIGHT or DT_SINGLELINE);
     end;

end;

[roman]

Empezado por ctronx

pero tu ejemplo no me permite especificar una determinada columna para alinear a la derecha.

¿Cómo está eso de que no te permite elegir la columna? ¡Se trata del mismo evento! Así que en ambos casos puedes usar condicionales para ACol y ARow.

// Saludos

[yusnerqui]

Como bien dice el amigo roman, se trata del mismo evento así que con solo unas pequeñas modificaciones lo podrás adaptar a lo que quieres.

Código Delphi [-]
procedure TForm1.StringGrid1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
var sCad:String;
    i: integer;
begin 
  if ACol=2 then // voy a alinear a la derecha la 3ª columna
  if ARow>0 then //No quiero alinear la línea de títulos
    if StringGrid1.Cells[ACol,ARow] <> '' then 
    begin 
       sCad := StringGrid1.Cells[ACol,ARow];
         with StringGrid1 do 
            with Canvas,Rect do 
            begin 
               i:=Right-TextWidth(sCad+' ');
               Canvas.FillRect(Rect);
               Canvas.TextOut(i,Top+2,sCad);
            end;      
    end; 
end;

Esto lo probé y me funciona.

Espero te Ayude.

Un saludo

[ctronx]

Ok, muchas gracias a ambos.