Firebird con Threads

[[gluglu]]

Bueno ....

A ver .... a falta de mejores criterios de otros compañeros del foro, veo algunos errores básicos de concepto !

Empecemos por el más grave :

Código Delphi [-]
procedure THPrueba.Button20111Click(Sender: TObject);
var Hilo: THilo;
begin
 Hilo := THilo.Create( True );
Hilo.Execute;
Hilo := THilo.Create( True );
Hilo.Execute;

Sin duda alguna, y con el 10000% de seguridad, esto se te va a quedar colgado siempre y en todas las ocasiones.

Estás declarando una variable Hilo, que utilizas dos veces y como no, se tiene que quedar colgado a la fuerza. No puedes utilizar la misma variable para dos Thread's diferentes que además se están ejecutando a la vez.

O bien declarar una variable Hilo1 y otra Hilo2, o si vas a crear una lista grande de Threads, lo que te recomiendo es que te crees un Array de THilo.

En primer lugar, probaría con dos variables diferentes, al menos para comprobar que tu código funciona, y ya después te puedes plantear la creación de un Array.

Código Delphi [-]
procedure THPrueba.Button20111Click(Sender: TObject);
var Hilo1, Hilo2: THilo;
begin

  Hilo1 := THilo.Create( True );
  Hilo1.FreeOnTerminate := True;
  Hilo1.Resume;

  Hilo2 := THilo.Create( True );
  Hilo2.FreeOnTerminate := True;
  Hilo2.Resume;

end;

Además no se llama al procedimiento Execute del propio hilo de manera directa (o al menos yo tampoco lo hago), sino al procedimiento Resume que a su vez ejecutará el Execute del hilo.

Si Hilo1 e Hilo2 tienen que estar accesibles en otra parte de tu Form, tendrías que declarar ambas variables en el apartado 'var' del Form.

Código Delphi [-]
var
  HPrueba: THPrueba;
  Hilo1: THilo;
  Hilo2: THilo;

Siguiente tema : Aunque queda claro que declaras y creas la BBDD y la tabla como parte del Hilo, personalmente incluiría también en cualquier caso la delcaración de la Transacción :

Código Delphi [-]
type
THilo = class(TThread)
private
  DataBase: TIBDataBase;
  Transaccion : TIBTransaction;
  Tabla: TIBDataSet;
procedure ActualizaMemo;
public
  CadenaMostrar: string;
  constructor Create( Suspendido: Boolean );
protected
  procedure Execute; override;
end;

Nunca lo he visto así, y no sé si puede o no dar problemas, pero nunca he visto ni utilizado un Constructor declarado en el propio Thread. En todas mis declaciones de Thread's, además el procedimiento Execute lo tengo en el apartado de declaraciones 'Protected'.

Al no utilizar nunca un Constructor, toda la creación de la BBDD, transacción y tablas, yo las meto en el propio Execute.

Código Delphi [-]
procedure THilo.Execute;
begin

  // Aqui no tengo mu claro lo que tengo que poner
  { while Self.Terminated = False do
  Self.Synchronize;}
 
  // Quizas tuviera que crear un objeto TList con un database, transaction y tabla
  // para cada ejecución del hilo
 
  //Como ya te indiqué, no tienes que crear un Tlist para cada uno de los elementos que indicas, sino
  // tienes que crear un Array o TList para cada Hilo en sí.

  DataBase := TIBDataBase.Create( nil );
  DataBase.DataBaseName := 'C:\DATOS\BASEDATOS.FDB';
  DataBase.LoginPrompt := False;
  DataBase.Params.Clear;
  DataBase.Params.Add( 'user_name=sysdba' );
  DataBase.Params.Add( 'password=masterkey' );
  DataBase.Connected := True;

  Transaccion := TIBTransaction.Create( nil );
  Transaccion.DefaultDataBase := DataBase;
  Transaccion.Params.Clear;
  Transaccion.Params.Add( 'read_committed' );
  Transaccion.Params.Add( 'rec_version' );
  Transaccion.Params.Add( 'nowait' );

  Tabla := TIBDataSet.Create( nil );
  Tabla.DataBase := DataBase;
  Tabla.Transaction := Transaccion;
  Tabla.Transaction.StartTransaction;
  Tabla.SelectSQL.Clear;
  Tabla.SelectSQL.Add( 'select Codigo, Denominacion from Apuntes' );
  Tabla.SelectSQL.Add( 'where Periodo = 2010' );
  Tabla.Active := True;

  while not Tabla.Eof do begin
    CadenaMostrar := Tabla.Fields[ 0 ].AsString + ' ' + Tabla.Fields[ 1 ].AsString;
    Synchronize( ActualizaMemo );
    Tabla.Next;
  end;

  Tabla.Close;
  Transaccion.Active := False;
  Database.Close;

  DataBase.Free;
  Transaccion.Free;
  Tabla.Free; 

  Terminate;

end;

La llamada a Synchronize(ActualizaMemo), en principio me parece correcta, al igual que la propia ejecución del procedimiento ActualizaMemo.

Intenta de momento hacer estos cambios que te propongo, a ver si así ya vas mejorando y si hace falta algo más, ya te intentamos ayudar posteriormente.

Un saludo

P.D. Se me olvidaba, también muy importante, debes de liberar todos los elementos creados, dentro del propio Thread.