Matar proceso

[delphi.com.ar]

¿Puedo agrega ralgo?
Siempre que hablamos de procesos, por compatibilidad con las plataformas Win9x, nos referimos a Tool Help Functions, pero si estamos en alguna plataforma NT, podríamos utilizar las funciones definidas en la unit PsAPI

Código Delphi [-]
 
{ Retorna el Handle del primer proceso de la lista coincidiente con el archivo pasado }
function GetProcessByFileName(AFileName: TFileName): DWORD;
var
  pidProcess: array [0..1023] of DWORD;
  hProcess: DWORD;
  dwCount: DWORD;
  hMod: HMODULE;
  ModuleFileName: array[0..MAX_PATH] of Char;
  i: Integer;
begin
  Result := 0;
  if EnumProcesses(@pidProcess, SizeOf(pidProcess), dwCount) then
    for i := 0 to dwCount div SizeOf(DWORD) do
    begin
      hProcess := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, False, pidProcess[i]);
      if (hProcess <> 0) then
        try
           EnumProcessModules(hProcess, @hMod, SizeOf(hMod), dwCount);
           GetModuleFilenameEx(hProcess, hMod, ModuleFileName, SizeOf(ModuleFileName));
           if SameFileName(ModuleFileName, AFileName) then
           begin
             Result := pidProcess[i];
             break;
           end;
        finally
          CloseHandle(hProcess);
        end;
    end;
end;

procedure KillProcess(hProcess: DWORD);
var
  hProc: DWORD;
begin
  hProc := OpenProcess(PROCESS_TERMINATE, False, hProcess);
  if hProc <> 0 then
    try
      TerminateProcess(hProc, 0);
    finally
      CloseHandle(hProc);
    end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  hProcess: DWORD;
begin
  hProcess := GetProcessByFileName('C:\WINNT\SYSTEM32\CALC.EXE');
  if hProcess <> 0 then
    KillProcess(hProcess);
end;

Saludos!

[Damisela]

Buenos días,

Estoy utilizando el código puesto por delphi.com.ar para matar un proceso.

El caso es que, desde mi aplicación llamo a un ejecutable externo que hace un serie de cálculos, el usuario debe poder cancelar este proceso puesto que tarda bastante tiempo. Usando el código de delphi.com.ar, si me fijo en el administrador de tareas se ve que el proceso se cancela pero éste se vuelve a autoejecutar.

¿Como se debe proceder para matar un proceso definitivamente?

Muchas gracias por vuestra ayuda. Un saludo.

[[seoane]]

El código que pone Federico los mata bien muertos. Si el proceso se vuelve a ejecutar, yo buscaría el problema en tu código o en las características del propio programa que quieres matar. En tu código busca si por algún motivo después de matar el proceso lo vuelves a ejecutar, y en el software que quieres controlar asegurate que es un solo proceso y no varios los que se ejecutan. Es decir, tu puede que solo ejecutes uno, pero que este llame a otro, y cuando tu matas el primero el segundo lo detecta y vuelve a ejecutar el primero.

[Damisela]

Exacto!!

Muchas gracias, mi fallo era precisamente ese, mi propio código volvia a ejecutar el programa externo.

Un saludo!!

[ixMike]

Supongo que ya no te hará mucha falta, pero en una pregunta de nuestro amigo woduro le sugerí un programa que viene con código fuente en Delphi que hace exatamente eso.