Deshabilitar un TabSheet de un PageControl

[Colgueit]

Gracias Dec,

Al final lo he conseguido, lo explico y pongo aquí el código por si alguien le ha surgido el mismo problema.

Lo que he hecho es crear una variable que guarda el indice del ultimo TabSheet seleccinado y cuando cambio de TabSheet compruebo si es el que no quiero que se visualize, si es ese vuelvo al TabSheet anterior.

Código Delphi [-]
TabAnterior:Integer;

procedure TFormX.PageControlChange(Sender: TObject);
begin
   if (PageControlVisitas.ActivePageIndex = 6) then
   begin
     If TabAnterior=6 then
       TabAnterior:=0;
     PageControl.ActivePageIndex := TabAnterior
   end
   else
      TabAnterior := PageControlVisitas.ActivePageIndex;
end;

Un saludo!

[Colgueit]

Una ultima cosa , que estoy probando y no se hacerlo. ¿Como cambio el color de una pestaña en concreto? Se cambiar el color de todas, obiamente, y el color de la pestaña activa. Pero lo quiero es cambiar el color de una pestaña cualquiera , este activa o no.

Hasta luegoooo

[dec]

Hola,

Me alegro. Yo tambiéne estaba investigando y creo que entre los dos y Román puedes lograr más o menos lo que querías en un principio. El método que has puesto quedaría así:

Código Delphi [-]
procedure TForm1.PageControl1Change(Sender: TObject);
begin
  if not (PageControl1.ActivePage.Enabled) then
  begin
    PageControl1.ActivePageIndex := TabAnterior
  end
  else
    TabAnterior := PageControl1.ActivePageIndex;
end;

El evento "OnDrawTab" del "PageControl" quedaría así:

Código Delphi [-]
procedure TForm1.PageControl1DrawTab(Control: TCustomTabControl;
  TabIndex: Integer; const Rect: TRect; Active: Boolean);
var
  R: TRect;
  Texto: String;

begin
  if not (PageControl1.Pages[TabIndex].Enabled) then
    Control.Canvas.Font.Color := clGrayText;

  Texto := PageControl1.Pages[TabIndex].Caption;

  R := Rect;
  Control.Canvas.FillRect(R);

  if not Active then
    InflateRect(R, 0, -3);

  DrawText(Control.Canvas.Handle, PChar(Texto), -1,
    R, DT_SINGLELINE or DT_CENTER or DT_VCENTER);
end;

La propiedad "OwnerDraw" del "PageControl" ha de valer "True", para el anterior código haga su trabajo.

Por último, ya podrías habilitar/deshabilitar pestañas mediante su propiedad "Enabled":

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
begin
  TabSheet2.Enabled := false;
  TabSheet4.Enabled := false;
  PageControl1.Repaint;
end;

El problema que he visto (de momento) es que al utilizar el evento "OnDrawTab", si utilizas también la unidad "XpMan", para lograr la apariencia del tema de Windows XP, ya sabes, pues resulta que la cosa no parece funcionar correctamente...

Es decir, el tema de Windows XP se aplicará (tendrá efecto) sobre otros controles, pero, no sobre el "PageControl", no sé si me explico.

[dec]

Hola,

Como puede verse, me limité a copiar el código que Román escribió en su momento en cierto Hilo de estos Foros. Entonces, parece que las siguientes instrucciones:

Código Delphi [-]
  if not Active then
    InflateRect(R, 0, -3);

No son necesarias en el código anterior, o, en todo caso, llevan a cabo algo que ahora mismo se me escapa. Que conste.

Actualización: Adjunto una especie de ejemplo de esto que estamos tratando.

[Colgueit]

Muchisimas Gracias Dec!!!!!!!!!!!

Ya lo tengo en perfecto funcionamiento, y aparte he hecho que ademas de mostrar en gris el Tab deshabilitado, tambien hago que se muestre en otro color el Tab activo. Solo es una pequeña modificacion del codigo que me has pasado.

Código Delphi [-]
procedure TFormVisitas.PageControl1DrawTab(
  Control: TCustomTabControl; TabIndex: Integer; const Rect: TRect;
  Active: Boolean);
var
  R,R2: TRect;
  Texto,Texto2: String;
begin

  if not (PageControl1.Pages[TabIndex].Enabled) then
    Control.Canvas.Font.Color := clGrayText;
  Texto2 := PageControl1.Pages[TabIndex].Caption;
  R2 := Rect;
  Control.Canvas.FillRect(R2);
  if not Active then
    InflateRect(R2, 0, -3);
 
  if Active then
    Control.Canvas.Font.Color := clBlue;
  Texto := PageControlVisitas.Pages[TabIndex].Caption;
  R := Rect;
  Control.Canvas.FillRect(R);
  if not Active then
    InflateRect(R, 0, -3);
 
  DrawText(Control.Canvas.Handle, PChar(Texto2), -1, R,
  DT_SINGLELINE or DT_CENTER or DT_VCENTER);
  DrawText(Control.Canvas.Handle, PChar(Texto), -1, R2,
  DT_SINGLELINE or DT_CENTER or DT_VCENTER);
end;

Muchas gracias otra vez!!!!!!! Agradezco mucho tu tiempo!!!!

[dec]

Hola,

Bueno, pues las gracias son mutuas entonces, porque de no haber sido por ti no hubiera yo sabido continuar. Justamente, si no llegas a escribir la implementación del método "OnChange" para el "PageControl" me parece a mí que me hubiera quedado encallado, así que gracias a ti. Y no se olvide a Román, puesto que el código del evento "OnDrawTab" lo escribió él originalmente.