Ejecutar codigo de dos dentro de Programa Delphi

[[seoane]]

Si lo unico que quieres es obtener la ip del equipo creo que te estas liando demasiado. Usa esta funcion para hacerlo:

Código Delphi [-]
uses Winsock;

function ObtenerIP : String;
var
  HostEnt: PHostEnt;
  Buffer: array[0..256] of Char;
  WSAData : TWSAData;
begin
  Result:= '';
  if WSAStartup(MAKEWORD(1, 1), WSAData) = 0 then
  begin
    if GetHostName(@Buffer, Sizeof(buffer)) = 0 then
    begin
      HostEnt := gethostbyname(@Buffer);
      if HostEnt <> nil then
        Result := inet_ntoa(PInAddr(HostEnt^.h_addr_list^)^);
    end;
    WSACleanup;
  end;
end;

[JELIRM]

GRACIAS DE NUEVO
mira y como utilizo la funcion para que me devuelva el resultado en un string??

[edelphi]

Hola Amigos, yo estoy buscando algo similar a esto; lo que deseo es hacer una backup de mi base de datos en posgresql, me dijeron que eso se hace por consola y no se que parametros le tendria que enviar para que desde un form se cree automaticamente.

estoy trabajando en delphi 7.0 con POsgesql 8, SO WinXP conexion ADO
espero sus respuestas y de antemano gracias

[JELIRM]

Gracias seoane por toda la informacion que me proporcionaste, revise bien el codigo ultimo que me distes y ya se usar la funcion realmente no se le mete parametros sino que de una sola vez te lo da asi que por si alguien mas quiere usuarla es asi:

Var
ResuladoIP:String;
begin
ResultadoIP:=(ObtenerIP);

y ya!!! asi de simple todo lo hace la funcion no hay necesidad de parametros ni nada.. y lo mejor de todo que esta funcion no ve si es un windows 98, 95 nt 2003 xp o lo que sea.

//Las Caidas te hacen aprender a caminar

[JELIRM]

mira si lo que quieres es hacer un backup has lo siguiente:
copia la funcion CMDEXEC justo abajo de implementation y luego en un boton pones el codigo que abajo te describo.


codigo de Funcion

 
function CmdExec(Cmd: string): string;
var
  Buffer: array[0..4096] of Char;
  si: STARTUPINFO;
  sa: SECURITY_ATTRIBUTES;
  sd: SECURITY_DESCRIPTOR;
  pi: PROCESS_INFORMATION;
  newstdin, newstdout, read_stdout, write_stdin: THandle;
  exitcod, bread, avail: Cardinal;
begin
  Result:= '';
  if IsWinNT then
  begin
    InitializeSecurityDescriptor(@sd, SECURITY_DESCRIPTOR_REVISION);
    SetSecurityDescriptorDacl(@sd, true, nil, false);
    sa.lpSecurityDescriptor := @sd;
  end
  else sa.lpSecurityDescriptor := nil;
  sa.nLength := sizeof(SECURITY_ATTRIBUTES);
  sa.bInheritHandle := TRUE;
  if CreatePipe(newstdin, write_stdin, @sa, 0) then
  begin
    if CreatePipe(read_stdout, newstdout, @sa, 0) then
    begin
      GetStartupInfo(si);
      with si do
      begin
        dwFlags := STARTF_USESTDHANDLES or STARTF_USESHOWWINDOW;
        wShowWindow := SW_HIDE;
        hStdOutput := newstdout;
        hStdError := newstdout;
        hStdInput := newstdin;
      end;
      Fillchar(Buffer, SizeOf(Buffer), 0);
      GetEnvironmentVariable('COMSPEC', @Buffer, SizeOf(Buffer) - 1);
      StrCat(@Buffer,PChar(' /c ' + Cmd));
      if CreateProcess(nil, @Buffer, nil, nil, TRUE, CREATE_NEW_CONSOLE, nil, nil, si, pi) then
      begin
        repeat
          PeekNamedPipe(read_stdout, @Buffer, SizeOf(Buffer) - 1, @bread, @avail, nil);
          if bread > 0 then
          begin
            Fillchar(Buffer, SizeOf(Buffer), 0);
            ReadFile(read_stdout, Buffer, bread, bread, nil);
            Result:= Result + String(PChar(@Buffer));
          end;
          Application.ProcessMessages;
          GetExitCodeProcess(pi.hProcess, exitcod);
        until (exitcod <> STILL_ACTIVE) and (bread = 0);
      end;
      CloseHandle(read_stdout);
      CloseHandle(newstdout);
    end;
    CloseHandle(newstdin);
    CloseHandle(write_stdin);
  end;
end;

y luego en un boton pon el siguiente codigo, en mi caso lo puse en el Create del formulario.
y pones un Tlabel para que veas tu resultado de tu backup

 
procedure TForm1.FormCreate(Sender: TObject);
var
ResultadoComando:String;
begin
 //Corre comando de Dos 
ResultadoComando:=(CmdExec('copy bases*.Extencion c:\Backup'));
//Despliega como que fuera la ventana del dos en tu form del resultado del comando .//
 
Label1.caption:=ResultadoComando;
end;
end.

y listo!!!!!!!!!

[edelphi]

ok amigo muchas gracias por la informacion voy aprobarla y te digo si me funciono o no ok gracias nuevamente

[edelphi]

holas amigos ahora la idea es hacerlo con MySQL claro lo mismo con un formulario para crear el backup y tambien para restaurar la Base de Datos y que no me genere conflictos al momento de cargar la BBDD

ok amigos muchas gracias de antemano por sus respuestas