Es bueno engordar con RES mi ejecutable?

[Neftali [Germán.Estévez]]

Basta con que crees un fichero de recursos como los estandard de Delphi y lo añadas a un proyecto de DLL.

Crea un archivo .RC como este (icons.rc):

BACK          BITMAP ".\back.bmp"
BARCODE    BITMAP ".\barcode.bmp"
...

Lo compilas usando el programa brcc32 (desde la linea de comandos)

brcc32 icons.Rc > Errores.txt

Desde Delphi creas un nuevo proyacto en: File/New/Other/DLL Wizard

y donde pone {$R *.res} cambias eso por {$R ICONS.RES}
Compila, linka y la DLL resultante ya tiene los iconos.

Una vez que tengas la DLL creada, en mi caso, por ejemplo con el nombre: ResDLL.dll para recuperar los iconos haz lo siguiente:
(1) Crea una nueva aplicación de delphi.
(2) Coloca dos TImage y un botón.
(3) En el Onclick del botón coloca el siguiente código:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  DllHandle: THandle;
begin
  // Cargar la DLL (debe estar en el mismo directorio)
  DllHandle := LoadLibrary('.\ResDLL.dll');
  // Cargada correctamente?
  if DllHandle <> 0 then begin
    // proteccion
    try
      //Cargar los recursos desde la DLL
      Image1.Picture.Bitmap.Handle := LoadBitmap(DllHandle, 'BACK');
      Image2.Picture.Bitmap.Handle := LoadBitmap(DllHandle, 'BARCODE');
    finally
      // Liberarla
      FreeLibrary(DllHandle)
    end;
  end
  else begin
    // Error
    ShowMessage(SysErrorMessage(GetLastError))
  end;
end;

Una vez compilado si la DLL y el EXE están en el ismo directorio deberían funcionar.

[Deiv]

Neftali, muy didáctica tu explicación, seguí las instrucciones, he probado tu código y de maravilla!, Gracias. En un principio pensé que como existen muchos programas que trabajan con Iconos y recuperan formatos DLL (ArtIcons Pro, IconCool, etc) pensé que quedarían desprotegidos, intenté con un par de ellos abrir la DLL creada con Delphi (según tu ejemplo) y he observado que no los pueden abrir, ¿es así?. Estoy empezando a leer más sobre el Tema DLL, me parece que los Programas de Íconos recuperan otro tipo de dlls a los que se crea con Delphi....

Yo trabajo con Recursos para otros formatos de esta manera:

NuevoMP3 RCDATA MiMusica.mp3
NuevoWav WAVE MiWav.wav
NuevoAvi AVI MiAvi.avi
NuevoIco ICON Foto.ico
NuevoAni ANICURSOR Globos.ani
NuevoFont RCDATA FORTE.ttf

En las líneas:

Código Delphi [-]
DllHandle := LoadLibrary('.\ResDLL.dll');
  if DllHandle <> 0 then begin
    try
      //Cargar los recursos desde la DLL
      Image1.Picture.Bitmap.Handle := LoadBitmap(DllHandle, 'BACK');

¿Se realiza el mismo proceso para recuperar una DLL que tenga cargado un archivo ICO, ANI, WAV, MP3 y AVI?
Obviamente la última línea:

Código Delphi [-]
Image1.Picture.Bitmap.Handle := LoadBitmap(DllHandle, 'BACK');

tendrá que ser diferente para cada uno.

Imagino que la llamada a la DLL debe ser la misma para cualquier caso, pero....

¿Cual es la forma de cargar los Recursos desde la DLL para dichos casos? (ico, ani, wav, mp3, avi)

[Neftali [Germán.Estévez]]

Empezado por Deiv

...me parece que los Programas de Íconos recuperan otro tipo de dlls a los que se crea con Delphi...

Pues yo he probado con esa DLL dos de los que uso habituialmente (ResThief y ResHacker) y me recuperan los imágenes del interior perfectamente.

Empezado por Deiv

¿Se realiza el mismo proceso para recuperar una DLL que tenga cargado un archivo ICO, ANI, WAV, MP3 y AVI?

Obviamente no, cada tipo se debe recuperar de una forma distinta.

Seguro que buscando un poco por internet encuentras infomación para recuperar:
* Cursores, Iconos y GIF, WAV y MP3, ...

[Deiv]

Tienes razón los Programas ResThief y ResHacker (que no los conocía) abren y leen normal las DLLs que contienen BitMaps. Entonces el camino que me quedaría para camuflarlos sería cambiar los nombres a mis DLLs? cosa que no sean muy llamativas, tal vez.

Me sugerieron también guardar en formato DAT, no se si es solo cambiar la extensión y ya.

Gracias por orientarme como sugerencia algunas páginas, me sirvió de mucho y voy a seguir investigando.

Ahora me compliqué más, encontré en algunas: DLL vs BPL.

[[seoane]]

Si se trata de proteger las imagenes porque no las encriptas, una encriptacion sencilla, lo suficiente para desanimar a un posible fisgon.

[Deiv]

Encriptar 200 imágenes? (tabla periódica) ¿Cada una?

Perdón por lo novato pero es así?

[[seoane]]

No es tan difícil encriptar una imagen, puedes hacer un programita que encripte las 200 en un par de segundos. Aprovechando un poco de código que tenia por ahí te dejo una función para encriptar Bmps, no es una maravilla criptográfica pero lo suficiente para desanimar a los curiosos.

Código Delphi [-]
type
  Triple = array[1..3]of Byte;

procedure Cifrar(Imagen: TPicture; Clave: Longint);
var
  Bitmap: TBitmap;
  P: ^Triple;
  i, j: Integer;
begin
  RandSeed:= Clave;
  if not (Imagen.Graphic is TBitmap) then
  begin
    Bitmap:= TBitmap.Create;
    try
      Bitmap.Width:= Imagen.Width;
      Bitmap.Height:= Imagen.Height;
      Bitmap.Canvas.Draw(0,0,Imagen.Graphic);
      Imagen.Assign(Bitmap);
    finally
      Bitmap.Free;
    end;
  end;
  Imagen.Bitmap.PixelFormat:= pf24bit;
  for j:= 0 to Imagen.Bitmap.Height - 1 do
  begin
    P:= Imagen.Bitmap.ScanLine[j];
    for i:= 0 to Imagen.Bitmap.Width - 1 do
    begin
      P^[1]:= P^[1] xor Byte(Random(256));
      P^[2]:= P^[2] xor Byte(Random(256));;
      P^[3]:= P^[3] xor Byte(Random(256));
      inc(P);
    end;
  end;
end;

También te dejo el código en un zip listo para usar para que le eches un vistazo