ordenar un TList

[elcigarra]

Podría, pero pensé que ya lo había. De hecho esperaba que me mencionaras el método "Sort" de la clase pero la verdad es que no entendí como usarlo y la ayuda de delphi no me aclaró mucho y no funciona en mi caso por alguna razón qu edesconozco. Tal vez no sirva para eso.

[dec]

Hola,

Pues sí, revisando la ayuda (que no se me ocurrió antes, la verdad) se ve que "TList" cuenta con un método "Sort" que puede ayudarte. Hay un ejemplo y todo...

The following code sorts the objects in a list in alphabetical order based on their names. It assumes that the list contains only component references.

The CompareNames function performs the comparisons between objects in the list. The list is sorted when the user clicks a button.

Código Delphi [-]
function CompareNames(Item1, Item2: Pointer): Integer;
begin
  Result := CompareText((Item1 as TComponent).Name, (Item2 as TComponent).Name);
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  List1.Sort(@CompareText);
end;

[roman]

Empezado por dec

Hay un ejemplo y todo...

Ejemplo que, me parece, no puede compilar. Mejor hacer como Marcos.

// Saludos

[dec]

Hola,

Y qué culpa tengo yo de que el ejemplo de la ayuda de Delphi tenga una pequeña errata, porque es lo que parece. Ahora, de la ayuda de Delphi este código que sí que compila, o sea, se puede hacer, perfectamente, como se dice en la ayuda.

Código Delphi [-]
unit Unit1;

interface

uses
  Forms, Classes, Controls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormClose(Sender: TObject;
     var Action: TCloseAction);
    procedure FormCreate(Sender: TObject);
  private
    FMiLista: TList;
  end;

var
  Form1: TForm1;

type
  TMiClase = class(TObject)
  private
    FNombreClase: string;
  public
    property NombreClase: string
     read FNombreClase write FNombreClase;
  end;

implementation

{$R *.dfm}

uses
  SysUtils, Dialogs;

function CompararNombres(item1, item2: Pointer): integer;
begin
  Result := CompareText(TMiClase(item1).NombreClase,
             TMiClase(item2).NombreClase);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FMiLista := TList.Create;
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  FMiLista.Free;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  i: integer;
  unaClase, otraClase: TMiClase;
begin
  unaClase := TMiClase.Create;
  unaClase.NombreClase := 'Zaragoza';

  otraClase := TMiClase.Create;
  otraClase.NombreClase := 'Abecedario';

  FMiLista.Add(unaClase);
  FMiLista.Add(otraClase);

  FMiLista.Sort(@CompararNombres);

  for i := 0 to FMiLista.Count-1 do
  begin
    // Mostrará primero Abecedario y luego Zaragoza
    ShowMessage( TMiClase(FMiLista.Items[i]).NombreClase );
  end;
end;

end.

¿No?

La errata parece estar en el puntero a la función que se pasa como parámetro al método "Sort" de "Tlist":

Código Delphi [-]
List1.Sort(@CompareText);

Cuando debería ser:

Código Delphi [-]
List1.Sort(@CompareNames);

[roman]

El ejemplo de la ayuda no compila porque el operador as no es aplicable.

// Saludos

[dec]

Hola,

Vale, pero, tampoco compilaría aunque hicieras el "cast" como lo hago yo más arriba: porque el puntero no se pasa a la función correcta, y eso es una errata de la ayuda o me equivoco. Por otro lado todavía no tengo claro por qué el operador "as", como dices, no es aplicable...

Desde luego, si quitamos eso y la posible errata el código que he expuesto compila y funciona como se espera. O me equivoco...

[[maeyanes]]

No aplica el operador as por que Pointer no es una clase, es solo un tipo de datos y este operador es un operador de clases.



Saludos...

[[seoane]]

Después de de la primera respuesta de elcigarra me disponía a hacer un ejemplito, algo sencillo, pero tuve que atender a otro asunto durante un rato. Cuando vuelvo le doy a "Recargar" y me encuentro con todo esto . Así no hay forma de responder, si no te das prisa te pisan la respuesta

[[maeyanes]]

Bien dicen que "camarón que se duerme..."

[dec]

Hola,

Empezado por Maeyanes

No aplica el operador as por que Pointer no es una clase, es solo un tipo de datos y este operador es un operador de clases.

¿Cómo es que se pone en el ejemplo de la ayuda de Delphi, entonces? Aunque, si se piensa en la errata que parece contener... no sería extraño que algo más estuviera también equivocado, incluso cuando se mencione esto:

The following code sorts the objects in a list in alphabetical order based on their names. It assumes that the list contains only component references.

Que alguien me lo explique, por favor.

Empezado por Domingo

Después de de la primera respuesta de elcigarra me disponía a hacer un ejemplito, algo sencillo, pero tuve que atender a otro asunto durante un rato. Cuando vuelvo le doy a "Recargar" y me encuentro con todo esto . Así no hay forma de responder, si no te das prisa te pisan la respuesta

Sí, pero, cada uno aporta lo suyo, unos más modestamente que otros (hablo por mí). Por ejemplo, al ver que te habías unido al Hilo he pensado, ahí está Seoane con la solución del caso.

Por cierto, voy a ver si me preparo algo para cenar... y ceno... : D

[[maeyanes]]

Para usar el método Sort de TList, necesitas crear una función que devuelva un Integer y reciba como parámetros dos punteros:

Código Delphi [-]
function Compare(Item1: Pointer; Item2: Pointer): Integer;
var
  MiClase1: TMiClase;
  MiClase2: TMiClase;

begin
  MiClase1 := TMiClase(Item1);
  MiClase2 := TMiClase(Item2);
  if MiClase1.Propiedad > MiClase2.Propiedad then
    Result := 1
  else
    if MiClase1.Propiedad = MiClase2.Propiedad then
      Result := 0
    else
      Result := -1
end;

Saludos...

[pescriba]

Una forma mas simple de solucionar el problema

Código Delphi [-]
function Compare(Item1: Pointer; Item2: Pointer): Integer;
begin
  if TMiClase(Item1).Propiedad > TMiClase(Item2).Propiedad then
    Result := 1
  else
    if TMiClase(Item1).Propiedad = TMiClase(Item2).Propiedad then
      Result := 0
    else
      Result := -1
end;

Saludos...[/quote]

[[maeyanes]]

Alguién anda atrasado 3 años...