Varias instancias independientes de un form

[jachguate]

Creo que el problema aqui es que apicito está perdiendo de vista que la variable ExpConsulta es, en realidad, un puntero. Un puntero a una instancia en particular de un objeto de la clase TExpConsulta, que también podría estar apuntando a nil.

De el curso 1 de punteros, debes recordar que si haces:

Código Delphi [-]
  Puntero1 := Objeto.Create;
  Puntero1 := Objeto.Create;
  Puntero1 := Objeto.Create;

En memoria existirán tres instancias de la clase Objeto, pero Puntero1 hará referencia (apuntará) a la última de ellas.

Lo que está pasando con tu forma de enfocar el problema es precisamente que solo estas guardando una referencia al último TExpConsulta creado, y aún cuando los demás están en memoria, en tu código no tenes nada que apunte a ellos.

Afortunadamente, delphi lleva una lista de todos los forms que existen en cualquier momento creados en la memoria en el arreglo Forms del objeto global screen.

Así, podrías fácilmente encontrar un expediente de esta forma:

Código Delphi [-]
Procedure TForm1.MuestraExpediente(AIDExpediente: Integer);
var
  Exp: TExpConsulta;
begin
  Exp := nil;
  for I := 0 to Screen.FormCount - 1 do
    if Screen.Forms[i] is TExpConsulta then
      if TExpConsulta(Screen.Forms[i]).IDExpediente = AIDExpediente then
      begin
        Exp := TExpConsulta(Screen.Forms[i]);
        break;
      end;
  if not Assigned(Exp) then
  begin
    Exp := TExpConsulta.Create(Application);
    Exp.IDExpediente := AIDExpediente;
  end;
  Exp.Show;
  Exp.BringToFront;
end;

Procedure TForm1.Button1Click(Sender: TObject);
begin
  MuestraExpediente(StrToInt(Edit1.Text));
end;

Y claro está, si pensas mantener varias instancias de una clase de formulario en memoria, será mejor que te acostumbres a borrar la variable global que delphi amablemente crea, pues en este caso no hará mas que provocarte confusión.

Hasta luego.