Bloquear Teclas en XP

[jgarcia01]

Empezado por syul

Que buen pedazo de código! Funciona simplemente bien.
Lo probé en XP Profesional y todo bien.
Agradecido eternamente...
(Lo de la necesidad de dll
supongo que la documentación que viene con Delphi esta
bastante desactualizada)

necesito que alguien me ayude con el bloqueo del teclado para Win Xp, la direccion que da Roman ya no esta disponible y tengo que hacer esto para una aplicacion de ciber cafe.

[roman]

Prueba aquí:

http://romansg.net/index.php?pg=hooks

// Saludos

[jgarcia01]

Empezado por roman

Prueba aquí:

http://romansg.net/index.php?pg=hooks

// Saludos

Roman disculpa mi falta de conocimiento, no soy mu experto en la materia de programar en delphi, pero lo importante es que quiero aprender, no se como usar el codigo que me estas mostrando en el enlace que me distes, copie el codigo y lo coloque en una unidad que llame bloqueodeteclas pero no se como llamar a esta unidad para que me funcione en el programa, necesito de tu ayuda o alguien que me pueda orientar.

Saludos y gracias anticipadas.

[dec]

Hola,

Una vez incluída la unidad en tu proyecto, su utilización es bastante sencilla. Se trata de ejecutar el procedimiento "SetHook", a modo de preparación, y a continuación llamar al procedimiento "LockKey" tantas veces como te sea menester, esto es, como dice en la ayuda de la unidad "Hook.pas" el propio Román:

Código Delphi [-]
LockKey(lkAltEsc, true);

Para deshabilitar la combinación de teclas "ALT + ESC". Obviamente la llamada a dicho procedimiento ha de hacerse luego de hacer inicializado el "Hook", que ya he comentado que puede hacerse, sencillamente, llamando al procedimiento "SetHook" antes de llamar a "LockKey".

Para habilitar de nuevo una combinación de teclas basta con que llames a "LockKey" indicando la combinación y, esta vez, pasando como segundo parámetro el valor "false":

Código Delphi [-]
LockKey(lkAltEsc, false);

No tendrás que llamar explícitamente al procedimiento "ReleaseHook", que vendría a ser el "contrario" a "SetHook", puesto que este se llama en la cláusula "finalization" de la propia unidad "Hook.pas".

Código Delphi [-]
{...}
finalization
  ReleaseHook;
end.

Puedes usar, por ejemplo, el evento "OnCreate" de tu formulario principal para llamar al procedimiento "SetHook". A ver si el siguiente código te da alguna idea:

Código Delphi [-]
unit UfrmPrincipal;

interface

uses
  Forms, Classes, Controls, StdCtrls;

type
  TfrmPrincipal = class(TForm)
    btnHabilitar: TButton;
    btnDeshabilitar: TButton;
    procedure FormCreate(Sender: TObject);
    procedure btnHabilitarClick(Sender: TObject);
    procedure btnDeshabilitarClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  frmPrincipal: TfrmPrincipal;

implementation

{$R *.dfm}

uses
  UHooks; // Unidad UHooks.pas

procedure TfrmPrincipal.FormCreate(Sender: TObject);
begin
  UHooks.SetHook; // Establecemos el "hook" de teclado
end;

procedure TfrmPrincipal.btnDeshabilitarClick(Sender: TObject);
begin
  // Deshabilitamos la combinación ALT + F4
  UHooks.LockKey(lkAltF4, true);
end;

procedure TfrmPrincipal.btnHabilitarClick(Sender: TObject);
begin
  // Habilitamos la combinación ALT + F4
  UHooks.LockKey(lkAltF4, false);
end;

end.

[jgarcia01]

Ok funciona muy bien en win xp y 2000, ya lo probe y esta muy bueno, gracias a Roman y a Dec por su apoyo, pero te permite el bloqueo de ciertas teclas, alt + tab y otras, pero para ctrl + alt + supr no lo hace y se en mi aplicacion se hace imprecindible realizar este bloqueo de teclas, si tienen alguna ayuda al respecto de esto, o si Roman tiene alguna modificacion de su programa se lo sabria agradecer.

Saludos y gracias anticipadas.

[roman]

Pues no, no hay manera. Windows 2000 y XP protegen muy bien esa combinación de teclas interceptándola desde el arranque del SO, aún antes de la identificación del usuario, por lo que no hay nada que pueda hacerse. Bueno, sí la hay pero es muy compleja y propensa a errores porque debes reemplazar la dll que maneja la identificación de usuarios (gina.dll) por una propia, y aunque está documentado como hacerlo, no parece tarea sencilla, al menos requiere de mucha paciencia.

No obstante, yo preguntaría, ¿por qué consideras que es imprescindible tal bloqueo? La más de las veces, lo que importa bloquear se puede hacer con directivas del mismo S.O, por ejemplo, el acceso al administrador de tareas.

Si nos dices qué es lo que quieres evitar, quizá te podamos dar alguna idea.

// Saludos

[jgarcia01]

bueno quizas el termino imprescindible no fue el mas adecuado, lo que realmente quiero Roman es evitar que algún usuario teclee esta combinación (Ctrl + Alt + Supr) y aparezca la pantalla de dialogo de seguridad de windows donde esta el administrador de tareas y otros mas, eso es lo que realmente quiero. si existe algún metodo por lo menos de evitar que aparezca eso aunque no se desactiven estas teclas tambien me sirve.

Saludos y gracias anticipadas.

[jsc]

Empezado por roman

Prueba aquí:

http://romansg.net/index.php?pg=hooks

// Saludos

este hilo me es de gran ayuda y agradeceria si alguien pudiera decirme la manera de llegar a bloquear el teclado. no encontre el codigo en la url que se indica arriba

basicamente me interesaria bloquear el teclado y raton para mi aplicacion delphi de manera que quede protegida, pero que se pudiera hacer uso del teclado y raton en el pc en general; dicho de otra manera, que se pueda andar en el pc pero no en la aplicación delphi
es posible?
gracias de antemano

[[escafandra]]

Bloquear el teclado y el ratón no es muy buena idea. ¿No será mejor que tu aplicación sea un servicio?

De cualquier forma, te muestro como realizar el bloqueo:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
  public
  end;

var
  Form1: TForm1;
  WHookKeyboard: HHOOK = 0;
  WHookMouse: HHOOK = 0;

implementation

{$R *.dfm}
function KeyboardHook(Code, wParam, lParam: Integer): Integer; stdcall;
begin
  if (Code = HC_ACTION) then
    Result:= -1
  else Result:= CallNextHookEx(WHookKeyboard, Code, wParam, lParam);
end;

function MouseHook(Code, wParam, lParam: Integer): Integer; stdcall;
var
  Point: TPoint;
begin
  if(Code = HC_ACTION) then
  begin
    GetCursorPos(Point);
    ScreenToClient(Form1.Handle, Point);
    if PtInRect(Form1.GetClientRect, Point) then
    begin
      Result:= -1;
      exit;
    end;
  end;
  Result:= CallNextHookEx(WHookMouse, Code, wParam, lParam);
end;


procedure TForm1.FormCreate(Sender: TObject);
begin
 WHookKeyboard:= SetWindowsHookEx(2{WH_KEYBOARD}, @KeyboardHook, HInstance, GetCurrentThreadId);
 WHookMouse:= SetWindowsHookEx(7{WH_MOUSE}, @MouseHook, HInstance, GetCurrentThreadId);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  UnhookWindowsHookEx(WHookKeyboard);
  UnhookWindowsHookEx(WHookMouse);
end;

end.

Saludos.

[DarKraZY]

Empezado por jsc

basicamente me interesaria bloquear el teclado y raton para mi aplicacion delphi de manera que quede protegida

Quizás te pueda servir mostrar un formulario en modo ShowModal. De esta manera no se podrá acceder al resto de la aplicación.

Saludos!