Acceder a la lista de procesos

[aeff]

si a lo que te refieres es a lo que yo entendí, entonces te diré que puedes obtener los nombres de los procesos de la siguiente manera,

colocas primeramente un Listview con dos columnas, ID y Name del proceso:

implementas esta función para obtener los procesos, y sus dos descripciones anterior:

Código Delphi [-]
 
procedure GetMemoryProcess();
var
 foto: Cardinal;
  datos: tagPROCESSENTRY32;
  r: Integer;
begin
 r := 1;
  datos.dwSize := sizeOF(tagPROCESSENTRY32);
  foto := CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  while Process32Next(foto, datos) do
   begin
      Form1.ListView1.Items.Add.Caption := IntToStr(datos.th32ProcessID);
   Form1.ListView1.Items[r -1].SubItems.Add('EXE: '  + datos.szExeFile);
     inc(r);
    end;
 CloseHandle(foto);
end;

ahora, para la parte de obtener los subprocesos o los modulos cargados por un proceso, puedes implementar esta otra función:

Código Delphi [-]
  
procedure GetModulesProcess(idProcess, tData: Integer);
var
 foto: Cardinal;
  datos: tagMODULEENTRY32;
  r: Integer;
begin
 foto := CreateToolhelp32Snapshot(TH32CS_SNAPMODULE, idProcess);
 r := 1;
  datos.dwSize := sizeOf(tagMODULEENTRY32);
  while Module32Next(foto, datos) do
   begin
     case tData of
       1: ShowMessage(IntToStr(datos.hModule));
       2: ShowMessage(datos.szModule);
       3: ShowMessage(datos.szExePath);
    end;
      inc(r);
    end;
 CloseHandle(foto);
end;

el primer parámetro de esta última funcion es para obtener los subprocesos del proceso que tenga el ID especificado, por ejemplo el 456, winlogon.exe...

y el segundo parámetro de esta función es para mostrar en un mensajito la descripción del subproceso:
1 => Handle
2 => Nombre
3 => Path + name

espero que te funcione...

[yarielrs]

Hola aeff tengo una duda en cuanto a la función GetModulesProcess que pusiste, el problema es que cuando le doy el ID del winlogon.exe o de cualquier otro proceso que se ejecuta como un proceso de sistema no me devuelve ningún resultado esto es en windows xp sp2 y mi cuenta es administrativa, entonces lo que quisiera que me dijeras es porque sucede esto porque a la verdad mira que me e ron pido tratando de averiguarlo pero no e podido dar con la respuesta.

Gracias de antemano y disculpa la molestia....

[[seoane]]

Yaeris, eso ocurre porque no tienes suficientes privilegios. Pero lo bueno de ser administrador es que tu mismo te los puedes conceder . La siguiente función permite elevar los privilegios de tu aplicación, de esta forma ya podrás usar la función.

Código Delphi [-]
function EnablePrivilege(PrivilegeName: PChar; Enable: Boolean): Boolean;
var
  hToken: THandle;
  Tp: TOKEN_PRIVILEGES;
  Luid: TLargeInteger;
begin
  Result:= FALSE;
  if OpenProcessToken(GetCurrentProcess(), TOKEN_ADJUST_PRIVILEGES or
    TOKEN_QUERY or TOKEN_READ, hToken) then
    if LookupPrivilegeValue(nil,PrivilegeName,Luid) then
    begin
      Tp.PrivilegeCount:= 1;
      Tp.Privileges[0].Luid:= Luid;
      if Enable then
        Tp.Privileges[0].Attributes:= SE_PRIVILEGE_ENABLED
      else
        Tp.Privileges[0].Attributes:= 0;
      Result:= AdjustTokenPrivileges(hToken,FALSE,Tp,0,nil,PDWORD(nil)^);
      CloseHandle(hToken);
    end;
end;

Por ejemplo:

Código Delphi [-]
EnablePrivilege('SeDebugPrivilege', TRUE);
// Aqui usamos la funcion
GetModulesProcess(524,2);
EnablePrivilege('SeDebugPrivilege', FALSE);

[yarielrs]

Muchas gracias seoane por tu ayuda pues ahora la funcion si que me funciona a las mil maravillas.......