Constantes, COMO modificar EXTERNAMENTE?

[[Crandel]]

Al modificar los recursos del EXE, estas modificando el exe.

Tambien se puede modificar el EXE directamente, modificando sus valores, pero es mas complicado.

[[seoane]]

Vamos a poner un poco de código para aclara un poco el asunto. Como ya te dijeron la mejor opción es usar archivos de recursos. Lo primero es definir una estructura (un record) que contendrá los parámetros. Esta definición debe ser común a ambos programas, el que modifica y el que ha de ser modificado.

Por ejemplo:

Código Delphi [-]
  TParametros = packed record
    Parametro1: Integer;
    Parametro2: Integer;
    Parametro3: String[255]; // Si usas cadenas tienen que tener un tamaño conocido
  end;

Ahora para leer los parámetros desde nuestra aplicación utilizaremos algo como esto:

Código Delphi [-]
var
  Parametros: TParametros;
begin
  // 1001 es el identificador, debe ser el mismo en ambos programas
  if FindResource(GetModuleHandle(nil),MAKEINTRESOURCE(1001),RT_RCDATA) <> 0 then
  with TResourceStream.CreateFromID(GetModuleHandle(nil),1001,RT_RCDATA) do
  try
    Read(Parametros,Sizeof(Parametros));
    with Parametros do
      ShowMessage(Format('P1=%d P2=%d P3=%s',[Parametro1,Parametro2,Parametro3]));
  finally
    Free;
  end;
end;

Para actualizar los parámetros desde otra aplicación, haríamos algo como esto:

Código Delphi [-]
var
  hExe: THandle;
  Parametros: TParametros;
begin
  Parametros.Parametro1:= 10;
  Parametros.Parametro2:= 20;
  Parametros.Parametro3:= 'Hola mundo';
  hExe:= BeginUpdateResource(PChar(ExtractFilePath(ParamStr(0))+'Ejemplo35a.exe'),FALSE);
  if hExe <> 0 then
  begin
    UpdateResource(hExe,RT_RCDATA,MAKEINTRESOURCE(1001),0,@Parametros,Sizeof(Parametros));
    EndUpdateResource(hExe,FALSE);
  end;
end;

Bueno, aquí te dejo el código, empaquetado y listo para usar. Primero compila el Ejemplo35a, y comprueba que no lee los parámetros. Ahora compila el Ejemplo35b y pulsa en "Actualizar parámetros", entonces ejecuta de nuevo el Ejemplo35a y veras que ahora ya lee los nuevos parámetros.

[lag_0]

seoane: muchisimas gracias, el ejemplo más claro imposible

Un saludo a todos =)

[roman]

¡Qué manera de complicarse la vida! ¿Qué tiene de más sencillo usar una segunda aplicación que modifique los recursos de otra que usar esa segunda aplicación para modificar unas entradas en el registro?

// Saludos

[[seoane]]

Empezado por roman

¡Qué manera de complicarse la vida! ¿Qué tiene de más sencillo usar una segunda aplicación que modifique los recursos de otra que usar esa segunda aplicación para modificar unas entradas en el registro?

Nadie dijo que fuese mas sencillo, seguramente es mucho mas complicado. Ya para empezar se necesitan 2 aplicaciones, mientras que usando el registro o archivos .ini, con una nos llegaría. Pero lo que yo creo, y eso solo lag_0 lo sabe, es que el quiere hacer una aplicación tipo "instalador", es decir, un solo exe que tu puedas llevar a cualquier equipo y se comporte como la has configurado. La única ventaja que tendría sobre el método de utilizar archivos .ini, es que solo habría que trasladar un archivo y no dos. Es la única ventaja que se me ocurre

[roman]

Ya, ya, es que ando medio burro La modificación de los parámetros se hace antes de la distribución y se quiere mandar sólo el exe modificado.

// Saludos

[[Crandel]]

Tiene varias posibles aplicaciones, como medida de seguridad podrias enviar tu ejecutable a tu cliente con el nombre de usuario o serial incluido en el propio ejecutable.