SGSCan - Capturar imagen de camara web

[[seoane]]

Estuve haciendo unas pruebas y este es el resultado. Antes de nada aclaro que no tengo webcam, las pruebas las hago con la capturadora de televisión, pero para el caso es lo mismo, porque los dos son dispositivos de captura y windows los trata como si fueran iguales.

Bueno, primero creamos una ventana de captura, utilizando un TPanel como padre:

Código Delphi [-]
// Remodele un poco la definicion de la funcion
function CreateCaptureWindow(Name: PChar; Style: Longint; X, Y: Integer;
 Width, Height: integer; Parent: HWND; id: integer): HWND; stdcall;
 external 'AVICAP32.DLL' name 'capCreateCaptureWindowA';


CapWindow:= CreateCaptureWindow('Ventana de captura',WS_CHILD or WS_VISIBLE,
    0,0,Panel1.Width,Panel1.Height,Panel1.Handle,0);

Ahora que tenemos una ventana de captura, nos conectamos con el driver.

Código Delphi [-]
  SendMessage(CapWindow, WM_CAP_DRIVER_CONNECT, 0, 0);

Ahora estaríamos conectados, pero no veríamos nada en la ventana de captura, o como mucho una imagen fija. Para tener un visualización podemos indicarle, por ejemplo, que utilice el método overlay (por hardware). Algo así:

Código Delphi [-]
  SendMessage(CapWindow, WM_CAP_SET_OVERLAY, 1, 0);

En este momento ya deberíamos de ver la imagen en movimiento en la ventana de captura. Ahora, si no me equivoco, tu querías capturar una imagen fija, pues en un botón, por ejemplo, coloca este código:

Código Delphi [-]
  SendMessage(CapWindow, WM_CAP_SAVEDIB, 0, lParam(PChar('c:\1.bmp')));

El código anterior captura una imagen fija y la guarda en la ruta "c:\1.bmp". Creo que esto era todo lo que necesitabas, si necesitas algo mas o si te falla en algún punto comentalo y veremos si podemos averiguar que esta fallando. Por cierto recuerda que cuando termines tienes que desconectar el driver:

Código Delphi [-]
if CapWindow <> 0 then
    SendMessage(CapWindow, WM_CAP_DRIVER_DISCONNECT, 0, 0);

También dejo por aquí algunas de las constantes que se utilizan, para que luego la gente no se me queje

Código Delphi [-]
const
  WM_CAP_START = WM_USER;
  WM_CAP_STOP = WM_CAP_START + 68;
  WM_CAP_DRIVER_CONNECT = WM_CAP_START + 10;
  WM_CAP_DRIVER_DISCONNECT = WM_CAP_START + 11;
  WM_CAP_SAVEDIB = WM_CAP_START + 25;
  WM_CAP_GRAB_FRAME = WM_CAP_START + 60;
  WM_CAP_SEQUENCE = WM_CAP_START + 62;
  WM_CAP_FILE_SET_CAPTURE_FILEA = WM_CAP_START + 20;
  WM_CAP_SET_PREVIEW = WM_CAP_START + 50;
  WM_CAP_SET_OVERLAY = WM_CAP_START + 51;

PD: Aunque no tiene mucho que ver con el tema, estoy enfadado con los fabricantes de mi tarjeta capturadora. Imaginaros mi sorpresa cuando intento probar el código anterior desde delphi y me salta un mensaje de error diciendo que han detectado que estoy usando un debugger (el propio delphi) y que me va a cerrar la aplicación, así que tuve que ejecutar el programa desde fuera de delphi. Supongo que no seré al único que sorprende que un driver implemente una función antidebugger, es ridículo, ya compre la tarjeta ¿que piensan que voy a piratear?. Increíble ....

[dec]

Hola,

Empezado por Seoane

(...) ya compre la tarjeta ¿que piensan que voy a piratear?

Huy... pues tratándose de ti no sé yo... Je, je, je. Gracias por estos "tips" tan curiosos Seoane.

[lag_0]

ya compre la tarjeta ¿que piensan que voy a piratear?. Increíble .... :mad:

En el tiempo que llevo con tarjetas capturadoras de TV solo me di cuenta que son todas mierda y que las casas que las fabrican unos cabrones.. xD No será pinnacle? xD
Luego testeare el codigo, yo tengo uno parecido por ahí

[lag_0]

Bueno...
Ahora me surgieron a mi las dudas .

En el codigo que yo tenia pasa lo mismo que en este y es que..:
Si no tienes una camara por defecto en windows seleccionada se te abre el panel para escojer una.

A ver si alguien se le ocurre la solución, por que yo en su dia lo intenté y ni patras:
-Evitar que te salga la ventana de windows para seleccionar capturadora
-Listar las capturadoras y obtener el identificador para:
-Seleccionar la capturadora a usar por CODIGO

a ver si algún experto lo consigue

[[seoane]]

Empezado por lag_0

a ver si algún experto lo consigue

Yo no soy un experto, pero lo puedo intentar ...

Empezado por lag_0

Si no tienes una camara por defecto en windows seleccionada se te abre el panel para escojer una.

A mi no me ocurre lo mismo, me abre directamente mi tarjeta de televisión, que es la que tiene el índice cero, y ese mismo índice es le que mando en aquí (marcado en rojo):

Código Delphi [-]
SendMessage(CapWindow, WM_CAP_DRIVER_CONNECT, 0, 0);

Empezado por lag_0

Listar las capturadoras y obtener el identificador para:

Para obtener una lista de las capturadoras instaladas y su index, solo tenemos que hacer un bucle con la función capGetDriverDescription, algo así:

Código Delphi [-]
var
  i: integer;
  Name, Ver: array[0..1024] of Char;
begin
  for i:= 0 to 9 do
    if capGetDriverDescription(i,@Name,Sizeof(Name)-1,@Ver,Sizeof(Ver)-1) then
  // Aqui añadimos a un listbox el nombre y el index de la capturadora    
  Listbox1.Items.AddObject(Name,TObject(i));
end;

Se me olvidaba poner la definición de la función capGetDriverDescription

Código Delphi [-]
function capGetDriverDescription(Index: WORD; Name: PChar; cbName: Integer;
  Ver: PChar; cbVer: Integer): BOOL;  stdcall;
 external 'AVICAP32.DLL' name 'capGetDriverDescriptionA';

[jacanche]

Hola, puedes probar el componente TvideoCapture, esta en torry, trae un componente vcl que puedes poner en tu pantalla, no necesitas que se abran otras adicionales, yo lo uso en un programa que hice para emitir credenciales con foto, y funciona bien, te dejo la liga de torry, espero te sirva.

http://torry.net/vcl/mmedia/video/eavcap.zip

Saludos
Alfredo

[lag_0]

Gracias a los dos una vez más ,

Saludoooooooos!