Posición mensajes (ShowMessage, Aceptar-Cancelar)

[Tomás]

¿Se puede hacer que los ShowMessage aparezcan en el lugar que yo quiera y no centrados?

La misma pregunta para:

if Application.MessageBox('¿Borrar registro?','Borrar',mb_OkCancel+mb_IconQuestion)= IdOk then

Un saludo. Tomás

[roman]

Para el caso de ShowMessage no sé. De cualquier forma siempre prefiero usar MessageBox ya que el texto de los botones sale con el idioma que tenga la PC.

Para el caso de MessageBox conozco una forma aunque quizá no muy elegante.

Básicamente cosiste en usar la función SetWindowPos de la API de Windows para cambiar la posición. El problema es que para ello debes saber cuál es el handle del cuadro de mensaje y la función FindWindow no te sirve ya que sólo podrás llamarla después de cerrar el cuadro.

La solución que sé es definiendo un manejador para el mensaje WM_ACTIVATE. Este mensaje llega a tu aplicación cuando se activa o cuando se desactiva. En el segundo caso te dice además cuál es el handle de la ventana que se está activando.

El código es así:

interface

type
  TForm1 = class(TForm)
  private
    MsgTitle: String; // Título del mensaje
    MsgX, MsgY: Integer;  // Posición del mensaje
    procedure WMActivate(var Message: TWMActivate); message WM_ACTIVATE;
  end;

implementation

procedure TForm1.WMActivate(var Message: TWMActivate);
var
  Buffer: array[Byte] of Char;

begin
  inherited;

  if Message.Active = WA_INACTIVE then
  begin
    GetWindowText(Message.ActiveWindow, Buffer, SizeOf(Buffer));
    if Buffer = MsgTitle then
      SetWindowPos(
        Message.ActiveWindow,
        0,
        MsgX, MsgY,
        0, 0,
        SWP_NOSIZE or SWP_NOZORDER
      )
  end;
end;

end.

Cuando desees mostrar el cuadro de mensaje ajusta primero las variables MsgTitle, MsgX y MsgY:

MsgTitle := 'Mi mensaje';
MsgX := 100;
MsgY := 100;
Application.MessageBox('Hola', PChar(MsgTitle), 0);

// Saludos

[andrestsas]

Hola Tomás, fijate si te sirve algo de esto :

Showmessagepos('Hola',600,300);

Messagedlgpos('Hola',mtInformation,[mbyes,mbNo],5,600,300);

donde 600 y 300 son las coordenadas X=horizontal e Y=Vertical respectivamentes.

Espero te sirva.
Saludos.-

[Tomás]

Hoy he podido probar las dos respuestas que me dais y van bien.
Más simple lo de andrestsas pero con resultado en inglés.
Mas práctico para mí lo de Román porque sale en español.

Muchas gracias a los dos.

PD.
Una pregunta a Román.
¿Tendría que repetir ese código en todas las forms que quiera sacar MessageBox de ese tipo, o hay alguna forma de ponerlo solo en la principal y que funcione en todas?

Gracias de nuevo. Tomás.