Conversor Hexadecimal a texto y .pak

[[seoane]]

Empezado por Alfonsoft

¿Sabeis de algun conversor que introduciendo hexadecimal lo transforme a texto?

Si te refieres a ver un archivo en hexadecimal, puedes usar el siguiente código:

Es una aplicación de consola:

Código Delphi [-]
program HexDump;

{$APPTYPE CONSOLE}

uses Windows, SysUtils;

function Min(i,j: Integer): Integer;
begin
  if i < j then
    Result:= i
  else
    Result:= j;
end;

procedure Dump(Filename: String);
var
  Buffer: array[1..16] of Byte;
  F: File;
  Leidos: Integer;
  i: Integer;
  Offset: Cardinal;
begin
  AssignFile(F,Filename);
  Filemode:= 0;
  {$I-}
    Reset(F,1);
  {$I+}
  if IOResult = 0 then
  begin
    Offset:= 0;
    while not Eof(F) do
    begin
      Write(IntToHex(Offset,8) + ':' + #32#32);
      BlockRead(F,Buffer,16,Leidos);
      for i:= 1 to Min(Leidos,8) do
        Write(IntToHex(Buffer[i],2) + #32);
      Write(#32);
      for i:= 9 to Min(Leidos,16) do
        Write(IntToHex(Buffer[i],2) + #32);
      for i:= Min(Leidos,16) + 1 to 16 do
        Write(#32#32#32);
      Write(#32 + '|');
      for i:= 1 to Min(Leidos,16) do
        if Char(Buffer[i]) in ['A'..'Z','a'..'z','0'..'9'] then
          Write(Char(Buffer[i]))
        else
          Write('.');
      Writeln('|');
      inc(Offset,Leidos);
    end;
    CloseFile(F);
  end;
end;

begin
  if FileExists(ParamStr(1)) then
    Dump(ParamStr(1));
end.

La salida del programa sera parecida a esta:

00000000:  4D 5A 90 00 03 00 00 00  04 00 00 00 FF FF 00 00  |MZ..............|
00000010:  B8 00 00 00 00 00 00 00  40 00 00 00 00 00 00 00  |................|
00000020:  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  |................|
00000030:  00 00 00 00 00 00 00 00  00 00 00 00 E0 00 00 00  |................|
00000040:  0E 1F BA 0E 00 B4 09 CD  21 B8 01 4C CD 21 54 68  |...........L..Th|
00000050:  69 73 20 70 72 6F 67 72  61 6D 20 63 61 6E 6E 6F  |is.program.canno|
   ...

Si no era esto lo que buscabas, explica un poco mas lo que buscas.

Empezado por Alfonsoft

Otra cosa mas, con que programa se puede descomprimir un .pak?

Según esta pagina, se trata de un archivo perteneciente a Quake.
http://www.filext.com/detaillist.php...&Search=Search

Si es así su estructura no parece muy complicada.
http://www.wotsit.org/list.asp?search=pak