¿Se puede modificar el idioma predeterminado por código?

[[cHackAll]]

Tengo entendido que el meollo del asunto está en los nombres de los días y los meses... Siendo éste el caso divagué entre APIs y la unidad SysUtils para producir tu resultado, espero sea lo que necesitas.

Código Delphi [-]
function GetLocaleStr(const Locale, LCType: Cardinal): ShortString;
begin
 Result[0] := Char(GetLocaleInfo(Locale, LCType, @Result[1], 255) - 1);
 Result[1] := Char(Byte(Result[1]) and not $20);
end;

function GetDateStr(DateTime: TDateTime; Lang: Cardinal): string;
var SystemTime: TSystemTime; Locale, LCID: Cardinal;
begin
 LCID := GetThreadLocale;
 SetThreadLocale(Lang);
 Locale := GetThreadLocale;
 DateTimeToSystemTime(DateTime, SystemTime);
 Result := GetLocaleStr(Locale, LOCALE_SDAYNAME1 + Word(SystemTime.wDayOfWeek - 1) mod $FFF9) + ', ' + IntToStr(SystemTime.wDay) + ' de ' +
           GetLocaleStr(Locale, LOCALE_SMONTHNAME1 + SystemTime.wMonth - 1) + ' del ' + IntToStr(SystemTime.wYear);
 SetThreadLocale(LCID);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
var xxx: string;
begin
 DateTimeToString(xxx, 'dddd, d "de" mmmm "de" yyyy', Now);
 Caption := xxx + ' ~ ' + GetDateStr(Now, LANG_PORTUGUESE) + ' ~ ' + GetDateStr(Now, LANG_ENGLISH) + ' ~ ' + GetDateStr(Now, LANG_SPANISH);
end;

Saludos

[[cHackAll]]

Pequeño bug! para los que vieron antes de que lo corrija, hubo un errorcillo en el día ya esta solucionado !

[Isabel_AS]

cHackAll, muchas gracias, efectivamente es lo que necesitaba, con esto funciona ok, como yo quería.
La verdad es que yo sola no lo hubiera sacado, ni siquiera entiendo muy bien el tema leyendo el código.... creo que me toca empollar un poquito por este camino...
Otra vez gracias y saludos!!

[DarKraZY]

Anteriormente ví este código en la sección de trucos y puse un comentario. Y ahora que veo el hilo también responderé aquí.

Creo que sería más sencillo de la siguiente manera:

Código Delphi [-]
function GetDateStr(DateTime: TDateTime; Lang: Cardinal): string;
var
  fs: TFormatSettings;
begin
  GetLocaleFormatSettings(Lang, fs);
  Result := FormatDateTime('dddd, d "de" mmmm "del" yyyy', DateTime, fs);
end

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
begin
 Caption := GetDateStr(Now, LANG_PORTUGUESE) + ' ~ ' + GetDateStr(Now, LANG_ENGLISH) + ' ~ ' + GetDateStr(Now, LANG_SPANISH);
end;