Automatizar la votación en un sistema de votaciones en línea

[[seoane]]

Esto es todo lo que voy a dedicar a este asunto, espero que te sirva. Yo no lo puedo comprobar porque ahora ya ni me deja entrar a la pagina de votación, me dice que ese servidor esta offline y que no puedo votar por el

Es una aplicación de consola.

Código Delphi [-]
program Voto;

{$APPTYPE CONSOLE}

uses
  Windows, SysUtils, WinInet, Classes;

function URLEncode(Str: string): string;
var
  i: integer;
begin
  Result:= '';
  for i:= 1 to Length(Str) do
    if Str[i] in ['A'..'Z','a'..'z','0'..'9','-','_','.'] then
      Result:= Result + Str[ i ]
    else
      Result:= Result + '%' + IntToHex(Ord(Str[ i ]),2);
end;

function SendRequest(Server, Uri: string; Port: Word; Params: TStringList;
  Response: TStream): Boolean;
var
  hNet: HINTERNET;
  hCon: HINTERNET;
  hReq: HINTERNET;
  Context: DWORD;
  Buffer: array[0..10240] of Char;
  BytesRead: DWORD;
  i: integer;
  Str: String;
  Success: Boolean;
begin
  Context:= 0;
  Result := FALSE;
  hNet := InternetOpen('Agente', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if (hNet <> nil) then
  begin
    hCon:= InternetConnect(hNet,PChar(Server),Port,nil,nil,
      INTERNET_SERVICE_HTTP,0,Context);
    if (hCon <> nil) then
    begin
      if Params <> nil then
        hReq:= HttpOpenRequest(hCon,'POST',PChar(Uri),nil,nil,nil,
          INTERNET_FLAG_RELOAD,Context)
      else
        hReq:= HttpOpenRequest(hCon,'GET',PChar(Uri),nil,nil,nil,
          INTERNET_FLAG_RELOAD,Context);
      if (hReq <> nil) then
      begin
        if Params <> nil then
        begin
          Str:= Emptystr;
          for i:= 0 to Params.Count - 1 do
            Str:= Str + '&' + URLEncode(Params.Names[i]) + '=' +
              URLEncode(Params.ValueFromIndex[i]);
          Delete(Str,1,1);
          Success:= HttpSendRequest(hReq,
           'Content-Type: application/x-www-form-urlencoded',Cardinal(-1),
            PChar(Str),Length(Str));
        end else
          Success:= HttpSendRequest(hReq,nil,0,nil,0);
        if Success and (Response <> nil) then
        try
          while (InternetReadFile(hReq,@Buffer,sizeof(Buffer),BytesRead)) do
          begin
            if (BytesRead = 0) then
            begin
              Result := TRUE;
              break;
            end;
            Response.Write(Buffer,BytesRead);
          end;
        except end;
        InternetCloseHandle(hReq);
      end;
      InternetCloseHandle(hCon);
    end;
    InternetCloseHandle(hNet);
  end;
end;

procedure Votar;
var
  Campos: TStringlist;
  Respuesta: TStringStream;
  Str: String;
begin
  Campos:= TStringList.Create;
  Respuesta:= TStringStream.Create('');
  try
    if SendRequest('l2.hopzone.net','/vote.php?site=60199',80,nil,Respuesta) then
    begin
      if Pos('<INPUT TYPE="HIDDEN" NAME="',Respuesta.DataString) > 0 then
      begin
        Str:= Respuesta.DataString;
        Respuesta.Size:= 0;
        Delete(Str,1,Pos('<INPUT TYPE="HIDDEN" NAME="',Respuesta.DataString)+
          Length('<INPUT TYPE="HIDDEN" NAME="') - 1);
        Delete(Str,Pos('"',Str),MAXINT);
        Campos.Values[Str]:= '60199';
        Campos.Values['gogogo']:= 'VOTE FOR Insomnyo Server';
        if SendRequest('l2.hopzone.net','/regvote.php',80,nil,
          Respuesta) then
        begin
          // Aqui comprobariamos la respuesta, pero en principio el voto
          // se ha realizado
        end else Writeln('No puedo acceder al servidor');
      end else Writeln('No encuentro el campo oculto');
    end else Writeln('No puedo acceder al servidor');
  finally
    Campos.Free;
    Respuesta.Free;
  end;
end;

begin
  Votar;
end.