variables entre forms

[roman]

Empezado por fedelphi

como hago para pasarle una referencia del formulario que llama al formulario modal?

La pregunta más bien es: ¿para qué quieres eso?

Según alcanzo a ver de tu código, el formulario modal está para preguntar al usuario un dato que requiere el otro formulario, y ese dato intentas asignarlo directamente desde el modal, pero esa no es tarea de éste formulario.

Piénsalo así: en general, un formulario modal se usa para preguntar valores, pero qué se hace con esos valores es responsabilidad de quien llama al formulario.

Por ejemplo, un cuadro de diálogo como OpenFileDialog tiene como finalidad preguntar al usuario por un nombre de archivo. El cuadro jamás va a colocar el nombre seleccionado en ninguna parte ajena a él, únicamente "devolverá" el archivo seleccionado en su propiedad FileName.

En tu caso yo haría algo similar. Al formulario modal le anexas una propiead al caso:

Código Delphi [-]
type
TFAdvierteBorraCirculante = class(TForm)
  ...
private
  FCantidad: Integer;

public
  property Cantidad: Integer read FCantidad write FCantidad;
end;

En el evento OnCloseQuery de este formulario verificas si el usuario oprimió OK. De se asi, asignas el dato en ECantidad.Text a FCantidad:

Código Delphi [-]
FCantidad := StrToInt(ECantidad.Text);

El otro formulario abriría el modal así:

Código Delphi [-]
procedure TFConsultaCirc.BEliminarClick(Sender: TObject);
var
  adv: TFAdvierteBorraCirculante;
begin
  adv := TFAdvierteBorraCirculante.create(self);

  try
    if adv.showmodal=mrYES then
    begin
      env_devs := adv.Cantidad;
    end;
  finally
    adv.Free;
  end;
end;

Observa el uso del try-finally para destruir al formulario modal. No dejes que éste se "autodestruya" poniendo Action := caFree en el evento OnClose. Lo necesitas "vivo" para cuando se cierre y tomes el vaor de su propiedad Cantidad.

// Saludos

[fedelphi]

Que grande roman, funciono perfectamente, muchisimas gracias por la ayuda

Le hice esto en el onclick

Código Delphi [-]
procedure TFAvierteBorraCirculante.BSiClick(Sender: TObject);
begin
  BSi.Tag:=1;
  Close;
end;

y asi en el onclosequery

Código Delphi [-]
procedure TFAvierteBorraCirculante.FormCloseQuery(Sender: TObject;
  var CanClose: Boolean);
begin
  if Bsi.tag=1then
  begin
    if ECantidad.Text<>''then
    begin
      CanClose:=True;
      ModalResult:=mrOK;
      FCantidad := StrToInt(ECantidad.Text);
    end
    else
    begin
      showmessage('Ingrese la cantidad de envases');
      CanClose:=False;
    end;
  end;

end;

y creo que asi queda completo
Fede

[roman]

Eso del BSi.tag está un poco feito

Lo normal es que a tu botón Aceptar le pongas su propiedad ModalResult en mrOk, para que automáticamente, al momento de oprimir el botón, se asigne mrOk al formulario. Y éso es lo que usas en CloseQuery para determinar si se oprimió Aceptar:

Código Delphi [-]
procedure TFAvierteBorraCirculante.FormCloseQuery(Sender: TObject;
  var CanClose: Boolean);
begin
  //if Bsi.tag=1then
  if MOdalResult = mrOk then
  begin
    if ECantidad.Text<>''then
    begin
      CanClose:=True;
      //ModalResult:=mrOK;
      FCantidad := StrToInt(ECantidad.Text);
    end
    else
    begin
      showmessage('Ingrese la cantidad de envases');
      CanClose:=False;
    end;
  end;
end;

y ya no usas el evento OnClick del botón.

// Saludos

[fedelphi]

OK, gracias de nuevo.
Fede