Combinaciones

[roman]

Si tenemos tres letras (a,b,c), las combinaciones con dos elementos serían:

aa
ab
ac
ba
bb
bc
ca
cb
cc

Si ahora queremos las combinaciones con tres elementos, basta tomar las anteriores y anexarles la a,

aaa
aab
aac
aba
abb
abc
aca
acb
acc

luego la b

baa
bab
bac
bba
bbb
bbc
bca
bcb
bcc

y finalmente la c

caa
cab
cac
cba
cbb
cbc
cca
ccb
ccc

Esto es, una vez que tenemos las combinaciones con N elementos, podemos, a partir de ellas, formar las de N+1 elementos, anexándoles cada uno de los distintos símbolos.

Todo esto lo digo, porque se puede hacer un procedimiento recursivo para evitar el número variable de índices.

Un ejemplo:

Código Delphi [-]
procedure Combinaciones(Simbolos: array of Char; Espacios: Integer; Lista: TStrings);
var
  ListaTemp: TStringList;
  I, J: Integer;

begin
  Assert(Espacios > 0);

  {
    Si sólo se requiere un espacio, la lista de combinaciones coincide con la
    lista de símbolos.
  }
  if Espacios = 1 then
    for I := Low(Simbolos) to High(Simbolos) do
      Lista.Add(Simbolos[i])
  else
  {
    En caso contrario, colocamos en una lista temporal las combinaciones con
    un elemento menos, e iteramos sobre los símbolos anexando cada uno a la
    lista temporal.
  }
  begin
    ListaTemp := TStringList.Create;

    try
      Combinaciones(Simbolos, Espacios - 1, ListaTemp);

      for I := Low(Simbolos) to High(Simbolos) do
        for J := 0 to ListaTemp.Count -1 do
          Lista.Add(Simbolos[i] + ListaTemp[J]);
    finally
      ListaTemp.Free;
    end;
  end;
end;

Al procedimiento Combinaciones le pasas la lista de símbolos o letras que desees, así como el número de elementos que quieras poner. El procedimeitno colocará en el tercer parámetro todas las combinaciones. Un ejemplo de uso:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  Lista: TStringList;

begin
  Lista := TStringList.Create;

  try
    {
      El número de espacios (4 en el ejemplo) puede leerse del usuario.
    }
    Combinaciones(['a','b','c','d','1','2','3', '#'], 4, Lista);
    Memo1.Lines.AddStrings(Lista);
  finally
    Lista.Free;
  end;
end;

// Saludos

[Delar]

u.U Tiene buena pinta, lo probaré en cuanto pueda.

Saludos!

[Delar]

Lo probé, ya la verdad que funciona tal y como pedia, PERO, hay un problemilla que no se solucionar, pues no trabajo demasiado con StringList...
Podría saber en un determinado momento, por que combinación va?
Y... hay alguna manera de que el programa no se congele mientras busca combinaciones?

Saludos!

[Ramiro_Hf]

Hola Buenos días, perdonar que re-abra este hijo, en el cual en principio con la última parte de código expuesto, genera perfectamente las combinaciones. Pero llevo dándole vueltas al tema varios días y lo que está ejecutando son permutaciones y no logro corregir el maldito código para que no se repitan las combinaciones, convirtiéndolo en combinaciones sin repetición, es decir me da igual que aparezca abcd que dcba en resumen para mi son lo mismo.
Pido disculpas por re-abrir el hijo (no se si es lo correcto), esperando me podáis dar una pequeña ayuda.
Gracias.
Ramiro Hernández