ftp Upload / Download (Aplicación)

[Jure]

Empezado por seoane

... Con lo simple que queda con wininet, además de pequeño (menos de 100 kb) y, sobre todo, utiliza la misma configuración del proxy que el internet explorer, ¿que mas se puede pedir?....

Seoane es un excelente código, como muy bien dices: Simple, corto y práctico. Gracias por compartirlo

[[seoane]]

Empezado por eduarcol

Esta muy bueno seoane, con tu permiso lo voy a comenzar a utilizar, voy a crear una especie de servicio para actualizar los sistemas, cuando lo termine lo coloco por aca a ver que tal

Excelente, ya nos contaras que tal te fue

Empezado por Jure

Seoane es un excelente código, como muy bien dices: Simple, corto y práctico. Gracias por compartirlo

Gracias

[[seoane]]

Vamos a darle un poco de vida a este hilo

Imaginar que que queremos descifrar un archivo cifrado con ftpup desde linux.

Nada nos impide usar algo como esto:

wine ftpup (Parametros)

Funcionaría, pero por qué no crear una aplicación propia para linux. Vamos a utilizar el compilador freepascal y el siguiente código:

Código Delphi [-]
program cifrar;

uses
  SysUtils,
  Classes,
  AES in 'AES.pas';

type
  EGetOptError = class(Exception);

var
  Options: record
    Decrypt: Boolean;
    Dest: String;
    Key: String;
    Source: String;    
  end;

function Starts(Sub, Str: String): Boolean;
begin
  Result:= SameText(Sub,Copy(Str,1,Length(sub)));
end;

procedure Getopt;
var
  i,j: Integer;
  Str: String;
begin
  FillChar(Options,Sizeof(Options),#0);
  for i:= 1 to ParamCount do
  begin
    Str:= ParamStr(i);
    if (Copy(Str,1,2) = '--') and (Length(Str) > 2) then
    begin
      if SameText(Str,'--Decrypt') then
        Options.Decrypt:= TRUE
      else if Starts('--Key=',Str) then
      begin
        if Options.Key = EmptyStr then
          Options.Key:= Copy(Str,Length('--Key=') + 1,MAXINT)
        else
          raise EGetOptError.Create(Str);
      end else if Starts('--Source=',Str) then
      begin
        if Options.Source = EmptyStr then
          Options.Source:= Copy(Str,Length('--Source=') + 1,MAXINT)
        else
          raise EGetOptError.Create(Str);
      end else if Starts('--Dest=',Str) then
      begin
        if Options.Dest = EmptyStr then
          Options.Dest:= Copy(Str,Length('--Dest=') + 1,MAXINT)
        else
          raise EGetOptError.Create(Str);
      end;
    end else if (Copy(Str,1,1) = '-') and (Length(Str) > 1) then
    begin
      Str:= UpperCase(Str);
      for j:= 2 to Length(Str) do
      begin
        if Str[j] = 'D' then
          Options.Decrypt:= TRUE
        else
          raise EGetOptError.Create(Str);
      end;
    end else
    begin
      raise EGetOptError.Create(Str);
    end;
  end;
end;


procedure Run;
var
  AESKey: TAESKey;
  ExKey: TAESExpandedKey;
  Src, Dst: TStream;
  Size: int64;
  IV: TAESState;
begin
  FillChar(AESKey,Sizeof(AESKey),#0);
  if Length(Options.Key) > Sizeof(AESKey) then
    move(PChar(Options.Key)^,AESKey,Sizeof(AESKey))
  else
    move(PChar(Options.Key)^,AESKey,Length(Options.Key));
  AESExpandKey(ExKey,AESKey);
  FillChar(IV,Sizeof(IV),#0);  
  Src:= TFileStream.Create(Options.Source,fmOpenRead or fmShareDenyNone);
  try
    Dst:= TFileStream.Create(Options.Dest,fmCreate); 
    try 
      if Options.Decrypt then
      begin
        if Src.Read(Size,Sizeof(Size)) = Sizeof(Size) then
        begin
          AESDecryptStreamCBC(IV,Src,Dst,ExKey);
          if (Size > 0) and (Src.Size > Size) then
            Dst.Size:= Size;
        end;
      end else
      begin
        Size:= Src.Size;
        Dst.Write(Size,Sizeof(Size));
        AESEncryptStreamCBC(IV,Src,Dst,ExKey);
      end;
    finally
      Dst.Free;
    end;
  finally
    Src.Free;
  end;
end;

procedure Help;
begin
  Writeln;
  Writeln('Uso: cifrar [opciones]');
  Writeln('  --decrypt -d');
  Writeln('    Descifrar (Cifrar es la opcion por defecto)');
  Writeln('  --key');
  Writeln('    Clave de cifrado, hasta 32 caracteres.');
  Writeln('  --source');
  Writeln('    Archivo de origen');
  Writeln('  --dest');
  Writeln('    Archivo de destino.');  
  Writeln;
  Writeln('Ejemplos:');
  Writeln('  cifrar --key=clave --source=archivo.txt --dest=archivo.bin');
  Writeln('  cifrar -d --key=clave --source=archivo.txt --dest=archivo.bin');
  Writeln;      
end;


begin
  try
    if ParamCount > 0 then
    begin
      GetOpt;
      Run;
    end else
      Help;
  except
    On E: EGetOptError do
    begin
      Writeln('Error en el parametro: ',E.Message);
      Help;
    end;
    On E: Exception do
      Writeln(E.Message);
  end;
end.

Y lo compilamos de la siguiente manera:

fpc -Sd cifrar.pas

El programa resultante permite cifrar y descifrar un archivo utilizando AES 256, siguiendo el mismo formato que el programa ftpup.

Por ejemplo, así cifra:

./cifrar --source=archivo.txt --dest=archivo.bin --key=clave

Y así descifra:

./cifrar -d --source=archivo.bin --dest=archivo.txt --key=clave

PD: La unit AES.pas la puedes conseguir aquí

[Casimiro Noteví]

Estupendo, seoane, lo pruebo en cuanto tenga un momento. (*)






(*) Cuando reciba mi nuevo monitor

[[seoane]]

Empezado por Casimiro Notevi

Estupendo, seoane, lo pruebo en cuanto tenga un momento.

Sera un placer que me digas tu opinión


PD: Usa el código que hay ahora, el que puse al principio tenia algunos errores.

[Casimiro Noteví]

Empezado por seoane

Sera un placer que me digas tu opinión

PD: Usa el código que hay ahora, el que puse al principio tenia algunos errores.

Un poquito tarde, pero más vale tarde que nunca

Lo he probado en mi ubuntu, compilación sin ningún error, el programita funciona perfecto, sin problema alguno y muy rápido.
Lo estoy usando para hacer copias encriptadas y luego subirlas por ftp con tu ftpup.

[[seoane]]

Excelente me encanta que la gente use los programas que hago.

Para saber mas sobre el tema, 4 entradas de mi pagina que tratan sobre AES:

• Cifrado AES-256
• Ejemplo de AES utilizando freepascal
• Cifrar texto con AES-256
• Subir archivos cifrados a un ftp