TrayIcon y su Popup

[[Caral]]

Hola
Perdon que me meta pero yo trate con el componente TrayIncon y la verdad no me funciono bien, me genero varios problemas.
Aqui tienes un ejemplo, sin ese componente, tal vez te sirva.
No pude subir el zip, estoy teniendo problemas con esto.
Colocas un popupmenu y le pones abrir en su primer item.

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, ShellApi,
  Forms, Dialogs, Menus;

type
  TForm1 = class(TForm)
    PopupMenu1: TPopupMenu;
    Abrir1: TMenuItem;
    procedure Abrir1Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private declarations }
    IconData : TNotifyIconData;
    procedure WMSysCommand(var Msg: TWMSysCommand); message WM_SYSCOMMAND;
    procedure Espabila(var Msg : TMessage); message WM_USER+1;

  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.WMSysCommand(var Msg: TWMSysCommand);
begin 
  if (Msg.CmdType = SC_MINIMIZE) then begin
    with IconData do 
    begin 
      cbSize := sizeof(IconData);
      Wnd := Handle;
      uID := 100;
      uFlags := NIF_MESSAGE + NIF_ICON + NIF_TIP;
      uCallbackMessage := WM_USER + 1;
      {Usamos de icono el mismo de la aplicacion}
      {We use the same icon as the application}
      hIcon := Application.Icon.Handle;
      {Como Hint del icono, el nombre de la aplicacion}
      {The name of te app for the hint of the icon}
      StrPCopy(szTip, Application.Title);
    end; 
    {Ponemos el icono al lado del reloj}
    {Place the icon next to the clock}
    Shell_NotifyIcon(NIM_ADD, @IconData);
    {Ocultamos la Form...}
    {Hide the form...}
    Hide;
  end else DefaultHandler(Msg);
end; 

procedure TForm1.Espabila(var Msg : TMessage);
{Aqui se recibe la pulsacion sobre el icono}
{Here we recieve the click on the icon}
var 
  p : TPoint;
begin 
  if Msg.lParam = WM_RBUTTONDOWN then begin 
    SetForegroundWindow(Handle);
    GetCursorPos(p);
    PopupMenu1.Popup(p.x, p.y);
    PostMessage(Handle, WM_NULL, 0, 0);
  end; 
end;


procedure TForm1.Abrir1Click(Sender: TObject);
begin
  {Mostramos de nuevo la form}
  {We show the form again}
  Form1.Show;
  ShowWindow(Application.Handle, SW_HIDE);
  {Y nos cargamos el icono de la system tray}
  {Destroy the systray icon}
  Shell_NotifyIcon(NIM_DELETE, @IconData);
  IconData.Wnd:=0;

end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
   {Quitamos el icono (en el caso de haberlo puesto antes...)}
  {Take off the icon (in case of had placed it before.....)}
  if IconData.Wnd <> 0 then Shell_NotifyIcon(NIM_DELETE, @IconData);

end;

end.

Saludos

[[gluglu]]

Caral, gracias por tu aporte también.

Lo he probado tal y como lo expones y denoto que tengo los mismos problemas. Cuando pulso sobre cualquier otra aplicación de la barra de tareas, esta se queda intermitente (algunas veces, otras no) y no trae al frente dicha aplicación seleccionada.

No sé si será un problema en general de Windows XP, de los iconos de Delphi en el SysTray, o de la instalación particular de mi ordenador.

Seguiré intentando de ambas formas y si encuentro una solución definitiva y satisfactoria, volveré a comentarla aquí.

Saludos,

[Arsenio]

Yo estoy usando el TTrayIcon en Delphi XE, y funciona todo correcto... salvo que al recuperar la ventana y querer otra vez minimizarla no ejecuta el evento, si cambio de ventana y vuelvo a la de mi proyecto vuelve a funcionar.

Lo que si hice distinto (y acá puede estar el tema) es que para capturar el evento que minimiza utilicé el de la aplicación:

Código Delphi [-]
  //Asigno evento a la aplicación
  Application.OnMinimize := MinimizarAplicacion;

El evento es de los "comunes":

Código Delphi [-]
procedure TFormCustom.MinimizarAplicacion(Sender: TObject);
begin
  TrayIcon1.Visible := True;
  Hide();
end;

Para restaurar la ventana hice un método que es llamado tanto en el doble click del TaryIcon como en un item del popUpMenu:

Código Delphi [-]
procedure TFormCustom.Restaurar1Click(Sender: TObject);
begin
  RestaurarVentana;
end;

procedure TFormCustom.TrayIcon1DblClick(Sender: TObject);
begin
  RestaurarVentana;
end;

procedure TFormCustom.RestaurarVentana;
begin
  //Lo siguiente es para darle prioridad a la ventana
  SetForegroundWindow(Self.Handle);
  TrayIcon1.Visible := False;
  Show();  
  WindowState := wsNormal;
end;

Si a alguno se le ocurre que puede estar fallando se agradece.