Cargar Varios CSV's en un solo Memo

[dec]

Hola,

Propongo algo así, aunque, no sé si te servirá o qué.

Código Delphi [-]
function FileToStr(
 path: string): string;
var
  aFile: TextFile;
begin
  AssignFile(aFile, path);
  Reset(aFile);
  while not Eof(aFile) do
    ReadLn(aFile, result);
  CloseFile(aFile);
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  s: string;
  sr: TSearchRec;
begin
  SetCurrentDir(ExtractFileDir(ParamStr(0)));
  if FindFirst('.\*.csv', faAnyFile, sr) = 0 then
  begin
    try
      repeat
        s :=  s + FileToStr('.\' + sr.Name)
      until (FindNext(sr) <> 0);
    finally
      FindClose(sr);
    end;
  end;

  ShowMessage(s);
end;

[keyboy]

Empezado por Albertito

El LoadFromFile o LoadFroamStream del Memo, te machaca el anterior.

Bueno, sí, pero puedes usar un TStringList auxiliar para leer cada archivo (LoadFromFile) y luego usar Memo1.Lines.AddStrings para agregar al memo sin machacar nada.

Bye

[dec]

Hola,

Yo sigo a lo mío...

Código Delphi [-]
function ReadTextFiles(path,
 extension: string): string;

  function FileToStr(
   path: string): string;
  var
    aFile: TextFile;
  begin
    AssignFile(aFile, path);
    Reset(aFile);
    while not Eof(aFile) do
      ReadLn(aFile, result);
    CloseFile(aFile);
  end;

var
  sr: TSearchRec;
begin
  result := EmptyStr;
  path := ExtractFilePath(path);
  if FindFirst(path + extension,
   faAnyFile, sr) = 0 then begin
     try
       repeat
         result := Concat(
           result, FileToStr(path + sr.Name)
         );
       until (FindNext(sr) <> 0);
     finally
       FindClose(sr);
     end;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowMessage(
    ReadTextFiles('.\', '*.csv')
  );
end;

[dec]

Hola,

He descubierto que no estaba leyendo de los archivos sino una línea.

Código Delphi [-]
function ReadTextFiles(
 path, mask: string): string;

  function FileToStr(
   path: string): string;
  var
    line: string;
    aFile: TextFile;
  begin
    AssignFile(aFile, path);
    Reset(aFile);
    while not Eof(aFile) do
    begin
      ReadLn(aFile, line);
      result := result + line;
    end;
    CloseFile(aFile);
  end;

var
  sr: TSearchRec;
begin
  result := EmptyStr;
  path := ExtractFilePath(path);
  if FindFirst(path + mask,
   faAnyFile, sr) = 0 then begin
     try
       repeat
         result := result +
          FileToStr(path + sr.Name);
       until (FindNext(sr) <> 0);
     finally
       FindClose(sr);
     end;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Text := ReadTextFiles('.\', '*.csv');
end;

[keyboy]

Empezado por dec

Yo sigo a lo mío...

Podemos combinar ideas:

Código Delphi [-]
procedure ReadFiles(Path, Mask: String; Lines: TStrings);
var
  SearchRec: TSearchRec;
  SomeLines: TStringList;
  Result: Integer;

begin
  Path := ExtractFilePath(Path);
  Result := FindFirst(Path + Mask, faAnyFile, SearchRec);

  try
    if Result = 0 then
    begin
      SomeLines := TStringList.Create;

      try
        repeat
          SomeLines.LoadFromFile(Path + SearchRec.Name);
          Lines.AddStrings(SomeLines);

          Result := FindNext(SearchRec);
        until Result <> 0;
      finally
        SomeLines.Free;
      end;
    end;
  finally
    FindClose(SearchRec);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  ReadFiles('.\', '*.csv', Memo1.Lines);
end;

Bye

[dec]

Hola,

Pues claro que podemos combinar ideas, no faltaba más.

Código Delphi [-]

begin
  Result := _CopyObject('.\', '*.csv');
end;

Je, je, je... No he podido evitarlo.

[[egostar]]

Empezado por dec

Hola,

Pues claro que podemos combinar ideas, no faltaba más.

Código Delphi [-]
 
begin
   Result := _CopyObject('.\', '*.csv');
end;

Je, je, je... No he podido evitarlo.

Cuidaditoo con esa función, a ver si un día de estos se devela el misterio

Salud OS