Ejecucion de programas automatico

[Neftali [Germán.Estévez]]

A ver si con una imagen queda mnás claro...
imagen

En windows todavía hay tres sistema para ejecutar un programa al inicio; Registro, Startup folders y Win.INI (sí este todavía funciona )

Para Startup Folders y Registro hay los diferentes usuarios como bien ha explicado David.

[[Caral]]

Hola
Gracias Neftali , estoy tratando de aprender esto que es nuevo para mi, espero poder.
Saludos

[look]

Hola.... abran notepad y pegen esto:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run]
"notepad.exe"="C:\\WINDOWS\\notepad.exe"

luego lo guardan con extencion Reg... esto escrive directamente en el reg edit
hay otras cadenas que pueden servir como la de windows nt Shell ... bueno en fin aqui sola hay que modificar el path y el nombre del exe ,,, luego de que guarden el archivo con la extencion reg solo lo abren y listo...

[[Caral]]

Hola
Una duda que se me presenta:
Usando un codigo que trabaja con un componente he podido hacer que el programa se instale en el startub (inicio) de windows.
Metiéndome (en camisa de once varas) en el msconfig, esta el programa en la ultima paleta (startub).
Es programa lo que usa es la variable (creo que es asi) TRegistry y HKEY_LOCAL_MACHINE.
Pero como dije lo que hace es instalar el programa en el inicio de windows, osea que si algun usuario se loguea, el programa arrancara independientemente del que sea.
Bueno, mi duda:
El ordenador que tengo lo uso de servidor, osea no se loguea nadie.
Cuando arranca simplemente se queda asi y se puede acceder a el desde la red.
Me han dicho que la manera de hacerlo es colocando el programa como un servicio.
Pregunto:
Para colocar el programa como un servicio se puede hacer como con este (TRegistry).?
Se usa el mismo pero de otra manera?
Hay otra forma de hacer que sea servicio?.
Por favor me ayudáis.
Saludos

Este es el componente:

Código Delphi [-]
unit BootExec;

interface 
 
uses 
  Classes,Windows,SysUtils,Registry;
 
type 
  TBootExec = class(TComponent)
 
  Private
     NombreClave : String;
     NombreExec  : String;
     ProximaVez  : Boolean;
     Usuario     : Boolean;
 
  Protected
 
  Public
    constructor Create(AOwner: TComponent); override;
    function AppInReg  : Boolean;
    function AddAppReg : Boolean;
    function DelAppReg : Boolean;
 
  Published
    Property NombrePrograma : string 
             Read NombreClave
             Write NombreClave;
    Property NombreEjecutable : string 
             Read NombreExec
             Write NombreExec;
    Property SoloUnaVez : Boolean
             Read ProximaVez
             Write ProximaVez;
    Property SoloUsuario : Boolean
             Read Usuario
             Write Usuario;
  end; 
 
procedure Register;
 
implementation 
 
{==============================================================================}
constructor TBootExec.Create(AOwner: TComponent);
 
begin 
  Inherited;
  AddAppReg;
end; 
 
{==============================================================================}
function TBootExec.AppInReg : Boolean;
 
var 
  Reg      : TRegistry;
  RegInfo  : TRegDataInfo;
  Clave    : String;
  Valores  : TStringList;
  I        : Integer;
 
begin 
  Result:=False;//No está en el Registro
  Clave:='Software\Microsoft\Windows\CurrentVersion\Run';
  if ProximaVez then Clave := Clave+'Once';
  Reg:=TRegistry.Create;
  if Not(Usuario) then Reg.RootKey := HKEY_LOCAL_MACHINE;
  if Not(Reg.KeyExists(Clave)) Then//comprobar prexistencia de clave
    begin 
       Reg.Free;
       Exit;
    end; 
  Reg.OpenKey(Clave,False);//existe, por tanto podemos abrirla.
  Valores := TStringList.Create;
  Reg.GetValueNames(Valores);//Obtenemos una lista de los Nombres de los valores de la clave
  for I:=0 to (Valores.Count-1) do 
    begin 
      if Reg.GetDataInfo( Valores[i], RegInfo) then 
        begin 
          if (RegInfo.RegData = rdString) then 
            begin 
              if Lowercase(NombreExec)=LowerCase( Reg.ReadString(Valores[i]) ) then 
                begin 
                 Result:=True;
                 Break;
                end; 
            end; 
        end 
       else 
         Valores[i]:='';
    End;//For
  Valores.Free;
  Reg.Free;
end; 
 
{==============================================================================}
function TBootExec.AddAppReg : Boolean;
 
var 
  Reg   : TRegistry;
  Clave : string;
 
begin 
  Result:=False;
  if (NombreClave='') or (NombreExec='') then 
    Exit;
  if AppInReg then 
    Exit;
  Clave:='Software\Microsoft\Windows\CurrentVersion\Run';
  if ProximaVez then Clave := Clave+'Once';
  Reg:=TRegistry.Create;
  if Not(Usuario) then Reg.RootKey := HKEY_LOCAL_MACHINE;
  if Not(Reg.KeyExists(Clave)) then 
    begin 
       Reg.Free;
       Exit;
    end; 
  Reg.OpenKey(Clave,False);
  Reg.WriteString(NombreClave,NombreExec);
  Reg.Free;
  Result:=True;
end; 
 
{==============================================================================}
function TBootExec.DelAppReg : Boolean;
 
var 
  Reg     : TRegistry;
  RegInfo : TRegDataInfo;
  Clave   : string;
  Valores : TStringList;
  I       : integer;
 
begin 
  Result:=False;
  if Not(AppInReg) then 
    Exit;
  if (NombreClave='') or (NombreExec='') then 
    Exit;
  Clave:='Software\Microsoft\Windows\CurrentVersion\Run';
  if ProximaVez then Clave := Clave+'Once';
  Reg:=TRegistry.Create;
  if Not(Usuario) then Reg.RootKey := HKEY_LOCAL_MACHINE;
  if Not(Reg.KeyExists(Clave)) then 
    begin 
       Reg.Free;
       Exit;
    end; 
  Reg.OpenKey(Clave,False);
  Valores := TStringList.Create;
  Reg.GetValueNames(Valores);//Obtenemos una lista de los Nombres de los valores de la clave
  for I:=0 to (Valores.Count-1) do 
    begin 
      if Reg.GetDataInfo( Valores[i], RegInfo) then 
        begin 
          if (RegInfo.RegData = rdString) then 
            begin 
              if Lowercase(NombreExec)=LowerCase( Reg.ReadString(Valores[i]) ) then 
                begin 
                  Reg.DeleteValue( Valores[i] );
                  Result:=True;
                end; 
            end; 
        end; 
    end; 
  Valores.Free;
  Reg.Free;
end; 
 
{==============================================================================}
procedure Register;
 
begin 
  RegisterComponents('LabGalia', [TBootExec]);
end; 
 
{==============================================================================}
END.

Asi grabo:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
begin
   BootExec1.NombrePrograma:='Programa Hola';
   BootExec1.NombreEjecutable:='C:\Hola\Hola.exe';
   BootExec1.SoloUnaVez:=False;{queremos que se ejecute siempre}
   BootExec1.SoloUsuario:=False;{que se ejecute con cualquier usuario}
if BootExec1.AddAppReg then
   ShowMessage('Ok, se ha instalado correctamente')
  else 
   ShowMessage('NO, Error en la instalación, posiblemente ya esté instalado...');

end;

Y asi lo elimino de windows:

Código Delphi [-]
procedure TForm1.Button3Click(Sender: TObject);
begin
     BootExec1.NombrePrograma:='Programa Hola';
     BootExec1.NombreEjecutable:='C:\Hola\Hola.exe';
     BootExec1.SoloUnaVez:=False;{queremos que se ejecute siempre}
     BootExec1.SoloUsuario:=False;{que se ejecute con cualquier usuario}

if BootExec1.DelAppReg then
   ShowMessage('Ok, se ha Desinstalado correctamente')
  else 
   ShowMessage('NO, Error en la Desinstalación, posiblemente ya fuese desinstalado...'); 
 

end;

[QMartinez]

Tal vez te sea de utilidad que Windows arranque en automático con un usuario predeterminado. De esta manera no sale la ventana de dialogo donde se tiene que ingresar usuario y password.


Abre el registro de Windows (con REGEDIT.EXE de Windows)

Abre WinLogon del registro de Windows, se encuentra en:
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon

Hay 3 valores que nos interesan, las cuales permiten arrancar Windows con un usuario predeterminado.

DefaultUserName = User // Usuario con que se firmara
AutoAdimLogon = 1 //(Coloca un valor de "uno" para arranque automático, “cero” para que no arrancar en automático)
DefaultPassword = Password //Password con que se firmara el usuario al PC

Es probable que no existan los valores AutoAdminLogon y DefaultPasswod. Tendrás que crearlas como nuevo valor alfanumérico.


Ya ingresado el usuario, se ejecutan las aplicacion definidas en Startuo

Espero que esto sea de utilidad.

[Khronos]

¿Alguien sabe como se podría iniciar un proceso al arrancar windows como un proceso de sistema? En el taskmanager hay procesos que corren bajo el nombre de usuario System.

Salu2

[aeff]

saludos!
esto creo que se ha tratado en varias ocaciones en el Club, creo que sería conveniente que hagas una pequeña búsqueda, ¿que crees?