formato de pantalla

[[cHackAll]]

Empezado por coso

...se debe haber obturado el condensador de fluzo...

[gallet]

si esque era muy simple la respuesta, no se ejecuta el screen shot en aplication console que es lo que pedi que me ayudaran a hacer, no pedia otra cosa.

[[egostar]]

Empezado por gallet

si esque era muy simple la respuesta, no se ejecuta el screen shot en aplication console que es lo que pedi que me ayudaran a hacer, no pedia otra cosa.

Hola

Mas bien creo que es muy simple la pregunta, la respuesta tal vez no lo sea tanto.....

Salud OS

[[cHackAll]]

Empezado por gallet

si esque era muy simple la respuesta, no se ejecuta el screen shot en aplication console que es lo que pedi que me ayudaran a hacer, no pedia otra cosa.

Disculpa por haberte dado otra cosa. (bien me lo dijo mi madre); estudia pa' ser veterinario mi'hijo... y ya ves, no le hice caso.

En fin, te aconsejo buscar "screen shot" a ver si así solucionas tu problema.

[[Lepe]]

Empezado por gallet

si esque era muy simple la respuesta, no se ejecuta el screen shot en aplication console que es lo que pedi que me ayudaran a hacer, no pedia otra cosa.

"screen shot" es captura de pantalla, es decir, una imagen de lo que contiene la pantalla en un momento determinado. No es eso lo que quieres, pero si pides eso, tendrás eso.

Eres tú el que debe dar toda la información, eres tú el interesado en obtener la respuesta acertada, nosotros no cobramos por ayudarte. Si además de entender lo que quieres decir, encima tenemos que adivinar lo que estás pensando.... yo, por ejemplo, ni contesto el hilo.

Edito: No me lo tomes a mal, no te recrimino nada, sólo quiero que entiendas nuestro punto de vista para ayudarte a formular mejor tus preguntas.

Saludos

[gallet]

Ya esque me equivoco al escribir por tanto mensaje, no era screenshot sino full screen, unicamente que la consola se ejecute a tamaño completo.
Sin ser programación visual, en delphi con console aplication la forma de que la consola se ejecute a tamaño completo.
gracias

[[coso]]

..encuentras sorprendente que te hagan caso, no gallet?

[[coso]]

..ya has desobturado el condensador? como te dije?

[[coso]]

..si no sabes como hacerlo, abre otro hilo, por eso

[dec]

Hola,

El hilo como para enmarcarlo. Casualmente tenía por aquí algo guardado...

Código Delphi [-]
program Project1;

{$APPTYPE CONSOLE}

uses
  Windows,
  Messages,
  SysUtils;

{
   There is no documented way to make a console application fullscreen.
   The following code works for both NT and Win9x.
   For win NT I used the undocumented SetConsoleDisplayMode and
   GetConsoleDisplayMode functions.
}


{
   Es gibt dokumentierte Möglichkeit, eine Konsolen-Anwendung per Code
   in den Vollbild Modus zu setzen.
   Folgender Code funktioniert unter NT und Win9x.
   Unter NT werden die undokumentierten SetConsoleDisplayMode und
   GetConsoleDisplayMode Funktion verwendet.
}

{
 function GetConsoleDisplayMode(var lpdwMode: DWORD): BOOL; stdcall;
   external 'kernel32.dll';
  // lpdwMode: address of variable for current value of display mode
}

function NT_GetConsoleDisplayMode(var lpdwMode: DWORD): Boolean;
type
  TGetConsoleDisplayMode = function(var lpdwMode: DWORD): BOOL;
  stdcall;
var
  hKernel: THandle;
  GetConsoleDisplayMode: TGetConsoleDisplayMode;
begin
  Result := False;
  hKernel := GetModuleHandle('kernel32.dll');
  if (hKernel > 0) then
  begin @GetConsoleDisplayMode :=
      GetProcAddress(hKernel, 'GetConsoleDisplayMode');
    if Assigned(GetConsoleDisplayMode) then
    begin
      Result := GetConsoleDisplayMode(lpdwMode);
    end;
  end;
end;

{
  function SetConsoleDisplayMode(hOut: THandle; // standard output handle
  dwNewMode: DWORD;         // specifies the display mode
  var lpdwOldMode: DWORD    // address of variable for previous value of display mode
  ): BOOL; stdcall; external 'kernel32.dll';
}

function NT_SetConsoleDisplayMode(hOut: THandle; dwNewMode: DWORD;
  var lpdwOldMode: DWORD): Boolean;
type
  TSetConsoleDisplayMode = function(hOut: THandle; dwNewMode: DWORD;
  var lpdwOldMode: DWORD): BOOL;
  stdcall;
var
  hKernel: THandle;
  SetConsoleDisplayMode: TSetConsoleDisplayMode;
begin
  Result := False;
  hKernel := GetModuleHandle('kernel32.dll');
  if (hKernel > 0) then
  begin @SetConsoleDisplayMode :=
      GetProcAddress(hKernel, 'SetConsoleDisplayMode');
    if Assigned(SetConsoleDisplayMode) then
    begin
      Result := SetConsoleDisplayMode(hOut, dwNewMode, lpdwOldMode);
    end;
  end;
end;

function GetConsoleWindow: THandle;
var
  S: AnsiString;
  C: Char;
begin
  Result := 0;
  Setlength(S, MAX_PATH + 1);
  if GetConsoleTitle(PChar(S), MAX_PATH) <> 0 then
  begin
    C := S[1];
    S[1] := '$';
    SetConsoleTitle(PChar(S));
    Result := FindWindow(nil, PChar(S));
    S[1] := C;
    SetConsoleTitle(PChar(S));
  end;
end;

function SetConsoleFullScreen(bFullScreen: Boolean): Boolean;
const
  MAGIC_CONSOLE_TOGGLE = 57359;
var
  dwOldMode: DWORD;
  dwNewMode: DWORD;
  hOut: THandle;
  hConsole: THandle;
begin
  if Win32Platform = VER_PLATFORM_WIN32_NT then
  begin
    dwNewMode := Ord(bFullScreen);
    NT_GetConsoleDisplayMode(dwOldMode);
    hOut := GetStdHandle(STD_OUTPUT_HANDLE);
    Result := NT_SetConsoleDisplayMode(hOut, dwNewMode, dwOldMode);
  end
  else
  begin
    hConsole := GetConsoleWindow;
    Result := hConsole <> 0;
    if Result then
    begin
      if bFullScreen then
      begin
        SendMessage(GetConsoleWindow, WM_COMMAND, MAGIC_CONSOLE_TOGGLE, 0);
      end
      else
      begin
        // Better solution than keybd_event under Win9X ?
        keybd_event(VK_MENU, MapVirtualKey(VK_MENU, 0), 0, 0);
        keybd_event(VK_RETURN, MapVirtualKey(VK_RETURN, 0), 0, 0);
        keybd_event(VK_RETURN, MapVirtualKey(VK_RETURN, 0), KEYEVENTF_KEYUP, 0);
        keybd_event(VK_MENU, MapVirtualKey(VK_MENU, 0), KEYEVENTF_KEYUP, 0);
      end;
    end;
  end;
end;

begin

  SetConsoleFullScreen(true);
  Readln;
  SetConsoleFullScreen(false);

end.

[[coso]]

Hola,
parece ser que mi desconfianza (aunque algo acertada) esta generando la polemica. Pido disculpas, por si sirve para algo y espero que Gallet al menos haya entendido algo. saludos.

[[coso]]

Sinceramente me molesta mucho la gente que pregunta y, sin animo de entender, va apretando apretando hasta que alguien le da directamente el codigo escrito. Me parece que este ha sido el caso. Una cosa es preguntar por necesitar ayuda, y otra es abusar de la confianza de quien ayuda. De todas maneras, ya me ha pasado una o dos veces, asi que ire con mucho mas tiento antes de 'saltar' (lo siento de veras). saludos.

PD: Gallet, si tienes algo que decir, estaria bien que lo comentases.