Forms: FreeAndNil ó Release y la validación Assigned?

[rgstuamigo]

Empezado por jbautista

....
Ahora tengo dudas mas especificas...

1: FreeAndNil me funciona bien desde el OnClose, cierra y libera el Form desde el boton para cerrar por default de las ventanas de windows.

Pero en algunos casos, cuando pongo un TBotón "Salir" y en su evento OnClick invovo a Close me genera un error.

Te cuento que he probado colocar un boton en el cual llamo al método Close del formualrio y no he tenido problemas.
Desde luego para mostrar el formulario lo hago asi (Siguiendo tu ejemplo):

Código Delphi [-]
procedure TForm1.Button3Click(Sender: TObject);
begin
 if not Assigned(Form2)then
      Application.CreateForm(TForm2, Form2);
Form2.WindowState:=wsNormal;
Form2.Show;
end;

En el evento OnClose del formulario (Form2 en mi caso) hago esto:

Código Delphi [-]
procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
FreeAndNil(Form2);
end;

Y en un boton que tengo en el formulario 2 (Form2) hago esto:

Código Delphi [-]
procedure TForm2.Button1Click(Sender: TObject);
begin
Close;
end;

Y no tengo problemas....
Quisas en tu caso tienes algun código mas por ahí , que es el causador del error que mencionas..

Empezado por jbautista

2. Assigned es la mejor forma de verificar si un Form ya esta creado???

Bueno.....si es una forma,en realidad la funcion Assigned lo que hace es Verificar si un puntero o variable es diferente de nulo(nil) algo asi:

Código Delphi [-]
if MiVarible<>Nil then// para el caso de una varible
...
ó
if @MiPuntero<>Nil then//para el caso de un puntero
....

De ahi la importancia de utilizar la funcion FreeAndNil.

Empezado por jbautista

3. Application.CreateForm(TForm_Prueba, Form_Prueba); es la mejor forma para crear el Form???

Es una forma de hacerlo, en realidad delphi en el archivo .DPR asi lo hace, pero tambien puedes hacerlo de esta forma que es equivalente:

Código Delphi [-]
procedure TForm1.Button3Click(Sender: TObject);
begin
 if not Assigned(Form2)then
      Form2:=TForm2.Create(Application);
Form2.WindowState:=wsNormal;
Form2.Show;
end;

Saludos...

[jbautista]

rgstuamigo y look :

Pues algo sigue estando raro con mi codigo, voy a checarlo bien.

Mientras probé de esta manera a ver que opinan:

Código Delphi [-]
procedure TForm_principal.btnAbrirClick(Sender: TObject);
var
    i:integer;
    existe:Boolean;
begin

    existe:=False;
    {Recorremos los todos Forms Creados}
    for i := 0 to (Screen.FormCount - 1) do
        {Buscamos si ya existe el Form_Ventana}
        if  Screen.Forms[i].Name = 'Form_Prueba' then begin
            existe:=True;
            break;
        end;
    {Si el Form no existe hay que crear el Form_Ventana}
    if not existe then begin
        Application.CreateForm(TForm_Prueba, Form_Prueba);
        Form_Prueba.Show;
    end else begin
        if Form_Prueba.WindowState <> wsNormal  then
            Form_Prueba.WindowState :=  wsNormal;
        Form_prueba.SetFocus ;
    end;
end;

Y desde el Form_Prueba puedo cerrar de las siguientes maneras sin ningun error hasta el momento:

Código Delphi [-]

procedure TForm_Prueba.BitBtn1Click(Sender: TObject);
begin
  close;
end;

procedure TForm_Prueba.FormClose(Sender: TObject;
  var Action: TCloseAction);
begin
  release;
end;

De esta forma le ven algún detalle que se me escape???

Con la forma que me recomendaron aun sigo checando si el problema es con la validación:

if not Assigned()

o con la llamada Close desde el evento OnClick del Boton.

Muchas gracias de verdad por su tiempo y comentarios.

[rgstuamigo]

Personalmente no lo veo muy óptimo yo prerferiría usar la funcion assigned en ves de recorrer todos formulario y usar el procedimiento FreeAndNil en lugar de Release tal como te hemos mencionado.

[roman]

Empezado por rgstuamigo

he probado colocar un boton en el cual llamo al método Close del formualrio y no he tenido problemas

Porque has tenido suerte

Yo hice la prueba del compañero y también obtuve un Access Violation. Luego agregué un tercer formulario al proyecto y "funcionó". O sea que, dependiendo de según qué circunstancias, puedes o no tener un problema.

El punto es, que no puedes usar FreeAndNil en el evento OnClose (y en ningún evento del formulario) por la misma razón que no puedes usar Free y debes usar Release en su lugar.

Tú mismo has observado que Release hace un Post del mensaje CM_RELEASE que, a su vez, genera la llamada a Free. Pero, al hacerse vía un Post, se garantiza que el formulario que se destruye ya ha procesado todos los eventos.

Al usar FreeAndNil e invocar el método Close tal como hace el compañero, el problema está en que el formulario se destruye cuando el evento Button1Click aún no termina.

En todo caso, podría funcionar algo como:

Código Delphi [-]
procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caFree;
  Form2 := nil;
end;

De todas maneras, a mi en lo particular no me gusta este tipo de métodos. Se supone que una clase no debería hacer referencia a ninguna instancia en particular de ella.

Lo que yo hago en estos casos, es usar el mecanismo de notificaciones entre componentes dado por FreeNotification y Notification.

Cuando creo el formulario, uso

Código Delphi [-]
Application.CreateForm(TForm2, Form2);
Form2.FreeNotification(Self);

Esto asegura que Self (el formulario desde donde se abre el segundo formulario) sea notificado cuando Form2 se destruya:

Código Delphi [-]
destructor TComponent.Destroy;
begin
  Destroying;
  if FFreeNotifies <> nil then
  begin
    while Assigned(FFreeNotifies) and (FFreeNotifies.Count > 0) do
      TComponent(FFreeNotifies[FFreeNotifies.Count - 1]).Notification(Self, opRemove);
    FreeAndNil(FFreeNotifies);
  end;
  DestroyComponents;
  if FOwner <> nil then FOwner.RemoveComponent(Self);
  inherited Destroy;
end;

Entonces, la parte que faltaría, es redefinir el método Notification de TForm1 para, ahí sí, poner en nil la variable:

Código Delphi [-]
procedure TForm1.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited;

  if (AComponent = Form2) and (Operation = opRemove) then
    Form2 := nil;
end;

// Saludos

[rgstuamigo]

Empezado por roman

Porque has tenido suerte

Yo hice la prueba del compañero y también obtuve un Access Violation. Luego agregué un tercer formulario al proyecto y "funcionó". O sea que, dependiendo de según qué circunstancias, puedes o no tener un problema.
...

Yo tambien he hecho la prueba nuevamente y he obtenido el error (y si que tuve suerte), la verdad creo que es un comportamiento extraño , ya que si tengo otras controles con algun evento codificado en algunos casos no obtengo dicho error pero en otros si me sale..
De todas formas tambien podriamos solucionarlo(segun mis pruebas) poniendo un componente TBitBtn en lugar del TButton y poner la propiedad Kind=bkClose para que cuando se presione dicho boton el formulario se cierre sin necesidad de codificar nada en su evento OnClick,desde luego ésto me ha funcionado usando FreeAndNil y no he tenido problemas.
Saludos...

[hach]

Hola,
proba con:

en el evento Close poner solo
Action := caFree;

y en el evento destroy
Form2:=nil;

Saludos

[jbautista]

Empezado por hach

Hola,
proba con:

en el evento Close poner solo
Action := caFree;

y en el evento destroy
Form2:=nil;

Saludos

Hola hach lo probe y al parecer funciona bien, incluso invocando al Close desde un Boton del mismo Form...

Me respeta correctamente la validación Assigned y no ha provocado ningún error por el momento :P

Con esto no se queda de basura en memoria o algo así???
El Form se libera bien y el puntero se pone a NIL correctamente al parecer...

Alguien opina algo diferente, algún detalle???

[jbautista]

Hola rgstuamigo y roman que tal, gracias poco a poco me va quedando claro este asunto, no puedo usar definitivamente FreeAndNil desde el mismo Form... suena logico sobre todo por el asunto de invocar al Close de un evento Click de un Botón.

Al usar el Release lo hace bien por que antes de destruir el Form termina todo los procesos pendientes...

Muy bien entonces las conclusiones son las siguientes:

* Entonces para usar la validación Assigned el Form que se valida necesia estar Liberado y con el punturo a NIL, de aqui la importancia del FreeAndNil

* Assigned pordria no funcionar bien con el Release por que antes de liberar al Form manda los mensajes a una cola de espera y poner el puntero a NIL un tiempo mas tarde, por eso al validar el Assigned podria regresar TRUE aunuqe ya se haya liberado el Form.

[jbautista]

Hola Roman de lo que sugeriste tengo unas dudas ya que intente aplicarlo y no pude :P

Esta parte no la tengo poner verdad? o si???

Empezado por roman

Código Delphi [-]
destructor TComponent.Destroy;
begin
  Destroying;
  if FFreeNotifies <> nil then
  begin
    while Assigned(FFreeNotifies) and (FFreeNotifies.Count > 0) do
      TComponent(FFreeNotifies[FFreeNotifies.Count - 1]).Notification(Self, opRemove);
    FreeAndNil(FFreeNotifies);
  end;
  DestroyComponents;
  if FOwner <> nil then FOwner.RemoveComponent(Self);
  inherited Destroy;
end;

Y en esta no me reconoce el procedure TForm1.Notification me falta alguna declaración en el USES???

Empezado por roman

Entonces, la parte que faltaría, es redefinir el método Notification de TForm1 para, ahí sí, poner en nil la variable:

Código Delphi [-]
procedure TForm1.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited;

  if (AComponent = Form2) and (Operation = opRemove) then
    Form2 := nil;
end;

// Saludos

Gracias! Saludos.