Funciones?, Procedimientos?

[LuisAlf::]

Interesante....

hOLA Ioco....

Disculpa, no puedes explicar mas a fondo el procedimiento que pones con parametros....

La verdad no se como es eso lo de OUT....si podrias explicarlo como funciona y como se manda a llamar tal procedimiento...

Saludos...

[[Caral]]

Hola
Segun lo que entiendo y que me corrija ioco OUT indica que las variables traspasan el procedimiento.
Para que este procedimiento funcione se tiene que tratar casi como una funcion.
Hay que declarar el procedimiento completo, donde estan los otros asi:

Código Delphi [-]
    procedure suma1;
    procedure suma2(num1,num2,sumado: String; OUT x: String; OUT b: Boolean);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);

Colocas las variables globales:

Código Delphi [-]
var
  Form1: TForm1;
  x: String;
  b: boolean;
implementation

Luego haces el procedimiento de ioco, asi:

Código Delphi [-]
Procedure TForm1.suma2(num1,num2,sumado: String; OUT x: String; OUT b: Boolean);
begin
  If StrToFloat(num1)+StrToFloat(num2)=StrToFloat(sumado) then
    begin
      x:= sumado;
      b:= true;
    end
  else
    b:= false;
end;

Y luego lo llamas asi:

Código Delphi [-]
procedure TForm1.Button3Click(Sender: TObject);
begin
   suma2(Edit2.Text,edit3.Text,edit1.Text,x,b);
  If b = True then
  Showmessage('El resultado es ' + x);
end;

Como ves, en vez de que sea el procedimiento el que contenga los datos, es al llamarlo que se los indicas.
Saludos

[[AzidRain]]

Cara,las funciones o procedimientos son meramente estructuras que el lenguaje nos ofrece, hay algunos donde todo método de clase es una función. Delphi es de los pocos que aún permite la existencia de ambos. En lenguaje C no existen por ejemplo los procedimientos si una funcion no tiene que devolver nada la hacemos igual a nil y punto.

Aquí nuestro querido Delphi nos dá oportunidad de usar "procedures" como funciones que no tienen por que devolver algo o bien funciones.
Al final es lo mismp hacer un función que siempre devuelve nil (que en efecto del Delphise puede hacer) una que devuelve algo.
Mas que nada es cuetión de estilos.

[[movorack]]

Si bien es cuestión de estilos... es bueno que nuestros estilos se acomoden a los estandares... al momento de que otra persona lea nuestro codigo se sentirá mas familiarizado.

Código Delphi [-]
x := sumar(100, 100);

personalmente... aquí entiendo que existe una asignación a X... haga lo que haga la función...

Código Delphi [-]
sumar(100, 100, x);

encambio aquí... no me deja muy claro que se está asignando un valor a X... podria ser perfectamente un parametro mas... tendria que ver la definición del procedimiento para entender que no es así...

[Lord Delfos]

Empezado por LuisAlf::

La verdad no se como es eso lo de OUT....si podrias explicarlo como funciona y como se manda a llamar tal procedimiento...

Bueno, habría que esperar a que ioco lo explique... pero le quiero ganar de mano y sumar otro post a mi favor

Hay dos maneras de pasar parámetros a un procedimiento/función:

[1] Por referencia (usando "var").
[2] Por valor (sin escribir nada).

Cuando uno pasa un parámetro por referencia, la variable que se pasa conserva el valor que se le haya dado adentro del procedimiento. Por ejemplo:

Código Delphi [-]
procedure HagoAlgo(var UnaVariable: Integer);
begin
  UnaVariable:= 22;
end;

var Pepito: Integer;

begin
  Pepito:= 4;
  HagoAlgo(Pepito);
  //Ahora Pepito vale 22.
end;

Al pasar por valor, en cambio, uno lo que pasa es una copia de la variable original. Así, si el procedimiento que la recibe la modifica, mi variable original no es modificada, porque lo que se modifica es una copia, no el original. Por ejemplo:

Código Delphi [-]
procedure HagoAlgo(UnaVariable: Integer); <-- sin el "var"
begin
  UnaVariable:= 22; <-- Modifica una copia de "Pepito", no el original.
end;

var Pepito: Integer;

begin
  Pepito:= 4;
  HagoAlgo(Pepito);
  //Pepito sigue valiendo 4.
end;

Ahora bien, en Delphi hay otros dos tipos de parámetros:

[1] El paso por constante (con la palabra "const").
[2] El paso por salida (con la palabra "out").

El paso por constante es útil para pasar algo que no queremos que se modifique (es decir, que pasaríamos por valor) pero que mide mucho como para dejar que el compilador haga una copia de la variable antes de pasarla. Al usar "const" lo que el compilador hace es pasar la variable original, pero controla que no se quiera hacer ninguna modificación. Por ejemplo:

Código Delphi [-]
procedure HagoAlgo(const UnaVariable: Integer);
begin
  UnaVariable:= 22; <-- Error de compilación, no se permite modificar la variable.
end;

Es útil cuando pasamos strings o arreglos, que son muy grandes como andar copiándolos. Hace al código más eficiente... por supuesto, siempre y cuando no quiéramos modificarlos.

El paso por salida sirve para indicar que lo que tenga la variable adentro es irrelevante y que se va a sobreescribir con otro valor. En sí es un paso por referencia (como con "var"), pero sirve para que el que use la función/procedimiento sepa que si hay algo en la variable, más vale que esté destruido antes de llamar a la función, sino las cosas pueden salir mal. Por ejemplo:

Código Delphi [-]
procedure HagoAlgo(out UnaVariable: TObject);
begin
  UnaVariable:= TObject.Create;
  UnaVariable.TalCosa:= 4;
end;

var Pepito: TObject;

begin
  //Hago mil cosas con Pepito
  HagoAlgo(Pepito);
  //La sonamos. HagoAlgo crea el objeto, pero mi variable Pepito ya estaba creada y entonces tengo un goteo de memoria, porque creé un objeto "arriba" de otro.
end;

Lo correcto sería:

begin
  //Hago mil cosas con Pepito
  Pepito.Free; <-- Destruyo pepito
  HagoAlgo(Pepito);
end;

Saludongos.

[ioco]

Me dejaste a medio post Lord Delfos (si esque soy lentísimo escribiendo jaja)

Muy bien explicado, queda incluso más claro que en lo que estaba escribiendo yo ya que me estaba haciendo un lío en cómo organizar el texto xD

A todo esto comentar que lo que dice movorack de acomodarse a los estándares creo que es bastante conveniente, sobretodo cuando querramos que otros lean nuestro código (cada cual que escriba como quiera para sí mismo, pero para con los demás tenemos que tener un mínimo de consideración ).

Así, debemos plantearnos cómo se va a usar lo que estamos implementando y adecuarlo un poquito jeje.

Añadiré que se puede pasar los parámetros por referencia tanto en procedimientos como los del ejemplo, como en funciones (así podemos usar var, const y out en parámetros de una función tal que así:

Código Delphi [-]
function TrySuma(num1,num2:integer; out resultadoSuma:integer):boolean;

con una función así (similar a las funciones de conversión de formato de delphi del estilo TryStrToInt) obtenemos un valor booleano como resultado de la función pero a la vez guardaríamos el resultado de la suma en otra variable.

PD: para mas info sobre esto último consultar las funciones del estilo mencionado en la ayuda ya que no viene a cuento la implementación

[Lord Delfos]

Empezado por movorack

Código Delphi [-]
sumar(100, 100, x);

encambio aquí... no me deja muy claro que se está asignando un valor a X... podria ser perfectamente un parametro mas... tendria que ver la definición del procedimiento para entender que no es así...

Entiendo tu punto. En realidad ahí es donde entra el paso con "out". Aclara que el parámetro es para salida exclusivamente... Pero sí, puede prestarse a confusión, es cierto.

[[Caral]]

Hola
Estos son los hilos a los que se les saca provecho, aquí el que no aprende es por que no quiere.
Sois unos maestros señores.
Saludos

[Ñuño Martínez]

Los parámetros OUT tienen su utilidad; por ejemplo, para aquellas funciones o ecuaciones matemáticas que tienen más de una solución como es el caso de las ecuaciones de segundo grado:

Código Delphi [-]
(* Devuelve los ceros de una ecuación de segundo grado en la forma
    aX^2 + bX + c = 0.
   Los valores se devuelven en los parámetros X1 y X2.
   Devuelve FALSE si la función no tiene ningún cero para ningún X. *)
  FUNCTION EcuacionGrado2 (a, b, c: REAL; OUT x1, x2: REAL): BOOLEAN;
  VAR
    Delta: REAL;
  BEGIN
    RESULT := FALSE
  { Comprueba que el divisor no sea cero. }
    IF (2 * a) <> 0 THEN
      BEGIN
      { Comprueba que no se intentará obtener la raíz de un valor negativo. }
        Delta := (b * b) - (4 * a * c);
        IF Delta >= 0 THEN
          BEGIN
          { Resuelve la ecuación. }
            RESULT := TRUE;
            Delta := sqrt (Delta);
            b := b * (-1);
            x1 := (b + Delta) / (2 * a);
            x2 := (b - Delta) / (2 * a);
          END;
      END;
  END;

[[José Luis Garcí]]

Según me dijo mi amigo Jesús Cuando me enseñaba Clipper, ahi multitud de maneras de llegar a un mismo resultado, lo importante es primero llegar y luego ir mejorando hasta que llegues más rápido. Era un verdadero visionario, ya que también me decía un proceso que ahora ocupa un minuto, y nos parece rápido mañana ocupara diez segundos y nos desesperara. (se refería a la cada vez mayor rapidez de los procesadores, y que aún así el cliente con el paso del tiempo, aunque mete más datos, pretende que el proceso tarde meno)s.

[Lord Delfos]

Empezado por José Luis Garcí

Era un verdadero visionario, ya que también me decía un proceso que ahora ocupa un minuto, y nos parece rápido mañana ocupara diez segundos y nos desesperara. (se refería a la cada vez mayor rapidez de los procesadores, y que aún así el cliente con el paso del tiempo, aunque mete más datos, pretende que el proceso tarde meno)s.

¡Qué gran verdad! Uno se acostumbra, ¿viste?