Capturar las teclas Alt+TAb

[[escafandra]]

Código Delphi [-]
unit Unit1;

interface

uses Windows, Messages, Classes, Graphics, Controls, Forms, Dialogs, StdCtrls;

type
 TForm1 = class(TForm)
  procedure FormCreate(Sender: TObject);
  procedure HotKey(var Message: TMessage); message WM_HOTKEY;

    procedure FormClose(Sender: TObject; var Action: TCloseAction); end;

var Form1: TForm1;

implementation

{$r *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
 RegisterHotKey(Handle, 111, MOD_ALT, VK_TAB);
end;

procedure TForm1.HotKey(var Message: TMessage);
begin
 if Message.WParam = 111 then
  begin
   MessageBox(0, 'Hola', 'jeje', 0);
  end;
end;
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  UnRegisterHotKey(Handle, 111);
end;

end.

Saludos.

[roman]

Escafandra, ¿esto funciona? Lo he probado en Windows Vista y no pasa nada.

// Saludos

[Galahad]

Empezado por roman

Escafandra, ¿esto funciona? Lo he probado en Windows Vista y no pasa nada.

// Saludos

Je,je,,, yo también lo he probado,, y efectivamente no funciona,, pero si
cambiamos MOD_ALT, por MOD_CONTROL,, funciona !!!,, osea

RegisterHotKey(Handle, 111, MOD_CONTROL, VK_TAB);

esto consigue el resultado correcto, llego a la conclusión de que Windows "procesa" su propio control antes del de nuestro programa.

Saludos...

[[escafandra]]

Empezado por roman

Escafandra, ¿esto funciona? Lo he probado en Windows Vista y no pasa nada.

// Saludos

Bueno, lo he probado en un XP profesional y otro Home y si me funciona.
No he tenido oportunidad de probar en Vista ni W7.

Saludos.

[[escafandra]]

Efectivamente, el sistema de capturar HotsKeys en Win 7 no funciona con ALT+TAB. Pero si funciona un Hook al teclado como el de este ejemplo que he preparado:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  WHookKeyboard: cardinal;

implementation

{$R *.dfm}
function KeyboardHook(Code, wParam, lParam: Integer): Integer; stdcall;
begin
  if (Code = HC_ACTION) and LongBool(PDWORD(lParam + 8)^ and $20{LLKHF_ALTDOWN}) and (PDWORD(lParam)^ = VK_TAB) then
  begin
      Beep();
  end;
  Result:= CallNextHookEx(WHookKeyboard, Code, wParam, lParam);
end;



procedure TForm1.FormCreate(Sender: TObject);
begin
 WHookKeyboard:= SetWindowsHookEx(13{WH_KEYBOARD_LL}, @KeyboardHook, HInstance, 0);

end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  UnhookWindowsHookEx(WHookKeyboard);
end;

end.

Saludos.