Firebird con Threads

[Jack]

Cris cambie todo el código al metodo execute del hilo.
Gracias por la puntualización del método create del thread, seguro que me servirá para futuras ocasiones.
Ahora se me ha quedado como te indico abajo, pero además he cambiado los componentes de la conexión a los zeos creo que es la versión 6 y además he cambiado de firebird a mssql y tampoco me funciona. No se que pasa, estaría conformado si no se pudiera hacer en ningún caso pero es que he leído que hay algunos programadores que consiguen realizar justamente lo que yo necesito. Me encuentro un poco frustrado llevo muchos días con este problema y no le veo la punta por ningún lado.
Ahí te pongo el nuevo código a ver si me dais alguna pista.
He puesto un timer y dos conexiones con nombre diferente para asegurarme que los componentes son diferentes y se ejecutan los dos a la vez.
El método vermensaje me indica justa en que linea se para el código , en este caso devuelve un error de dirección de memoria.
Muchas gracias de antemano.

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, Buttons, Button2011, IBDataBase, IBCustomDataSet, ExtCtrls,
  ZConnection, Db, ZAbstractRODataset, ZAbstractDataset, ZDataset;


type
  THilo = class(TThread)
    private
           DataBase: TZConnection;
           Tabla: TZQuery;
           DataBase1: TZConnection;
           Tabla1: TZQuery;
           procedure ActualizaMemo;
           procedure PonTag;
           procedure VerMensaje;
    public
          CadenaMostrar: string;
    constructor Create( Suspendido: Boolean );
    procedure Execute; override;
  end;



type
  THPrueba = class(TForm)
    Button20111: TButton2011;
    Memo1: TMemo;
    Timer1: TTimer;
    ZConnection1: TZConnection;
    ZQuery1: TZQuery;
    procedure Button20111Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  HPrueba: THPrueba;

implementation

{$R *.DFM}

procedure THilo.Execute;
begin
     // Aqui no tengo mu claro lo que tengo que poner
     while Self.Terminated = False do begin
           if HPrueba.Tag = 0 then begin
              Synchronize( PonTag );
           DataBase := TZConnection.Create( nil );
           DataBase.Protocol := 'mssql';
           DataBase.DataBase := 'BASE2011QO';
           DataBase.HostName := 'NUEVOJACK\SQLEXPRESS';
           DataBase.LoginPrompt := False;
           DataBase.Password := '';
           DataBase.User := '';
           DataBase.Connected := True;
           //
           Tabla := TZQuery.Create( nil );
           Tabla.Connection := DataBase;
           Tabla.SQL.Clear;
           Tabla.SQL.Add( 'select * from Articulo' );
           Tabla.Active := True;
           while not Tabla.Eof do begin
                 CadenaMostrar := Tabla.Fields[ 0 ].AsString + ' ' +
                                          Tabla.Fields[ 1 ].AsString;
                 Synchronize( ActualizaMemo );
                 sleep( 1000 );
                 Tabla.Next;
           end;
           end
           else begin
           Cadenamostrar := 'ooooooo';
           Synchronize( ActualizaMemo );
           DataBase1 := TZConnection.Create( nil );
           DataBase1.Protocol := 'mssql';
           DataBase1.DataBase := 'BASE2011QO';
           DataBase1.HostName := 'NUEVOJACK\SQLEXPRESS';
           DataBase1.LoginPrompt := False;
           DataBase1.Password := '';
           DataBase1.User := '';
           DataBase1.Connected := True;    // Aqui se cuelga

           Synchronize( Vermensaje );
           //
           Tabla1 := TZQuery.Create( nil );
           Tabla1.Connection := DataBase;
           Tabla1.SQL.Clear;
           Tabla1.SQL.Add( 'select * from Articulo' );
           Tabla1.Active := True;
           while not Tabla1.Eof do begin
                 CadenaMostrar := Tabla1.Fields[ 0 ].AsString + ' ' +
                                  Tabla1.Fields[ 1 ].AsString;
                 Synchronize( ActualizaMemo );
                 sleep( 1000 );
                 Tabla1.Next;
           end;
           end;
     end;
end;


constructor THilo.Create( Suspendido: Boolean );
begin
     inherited Create( True );
     // Quizas tuviera que crear un objeto TList con un database, transaction y tabla
     // para cada ejecución del hilo
end;

procedure THilo.ActualizaMemo;
begin
     HPrueba.Memo1.Lines.Add( CadenaMostrar );
end;

procedure THilo.PonTag;
begin
     HPrueba.Tag := 1;
end;

procedure THilo.VerMensaje;
begin
     showmessage( 'pp' );
end;




procedure THPrueba.Button20111Click(Sender: TObject);
          var Hilo: THilo;
begin
     Hilo := THilo.Create( True );
     Hilo.FreeOnTerminate := False;
     Hilo.Resume;
     Timer1.Enabled := True;
end;

procedure THPrueba.Timer1Timer(Sender: TObject);
begin
     Button20111Click( Self );
     Timer1.Enabled := False;

end;

end.

[[Chris]]

He revisado tu código. Generalmente no he visto ningún problema en él. Pero si lo he reducido para empezar a "debuguear" desde él:

Prueba este código y cualquier error, comparte en gran detalle toda la información del error que se presente, la clase de la excepción, el mensaje y la línea. Por allí ay que empezar

Código Delphi [-]
unit Unit1;

interface

uses
    Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
    StdCtrls, Buttons, Button2011, IBDataBase, IBCustomDataSet, ExtCtrls,
    ZConnection, Db, ZAbstractRODataset, ZAbstractDataset, ZDataset;


type
    THilo = class(TThread)
    private
        procedure ActualizaMemo;
        procedure PonTag;
    public
        CadenaMostrar: string;
        constructor Create( Suspendido: Boolean );
        procedure Execute; override;
    end;

    THPrueba = class(TForm)
        Button20111: TButton2011;
        Memo1: TMemo;
        Timer1: TTimer;
        ZConnection1: TZConnection;
        ZQuery1: TZQuery;
        procedure Button20111Click(Sender: TObject);
        procedure Timer1Timer(Sender: TObject);
    end;

var
    HPrueba: THPrueba;

implementation

// TODO: lee en la ayuda de Delphi sobre "Threadvar"
threadvar
    ZConnection; TZConnection;
    ZQuery: TZQuery;

{$R *.DFM}

{ ~~~~~~~~~~~~~~~~~~~~          THilo          ~~~~~~~~~~~~~~~~~~~~ }

constructor THilo.Create( Suspendido: Boolean );
begin
    inherited Create( Suspendido );
    // Quizas tuviera que crear un objeto TList con un database, transaction y tabla
    // para cada ejecución del hilo
    // R:/ NO ES NECESARIO, HASTA DÓNDE VEO TU CASO, ADEMÁS TE COMPLICARÍAS LAS COSAS.
end;

procedure THilo.Execute;
begin
    try
        ZConnection = TZConnection.Create(nil);
        ZQuery := TZQuery.Create(nil);
        
        with ZConnection do 
        begin
            Protocol := 'mssql';
            DataBase := 'BASE2011QO';
            HostName := 'NUEVOJACK\SQLEXPRESS';
            LoginPrompt := False;
            Password := '';
            User := '';
            Connected := True;
        end;
        
        with ZQuery do
        begin
            Connection := DataBase;
            SQL.Clear;
            SQL.Add( 'select * from Articulo' );
            Active := True;
            
            while not EoF do
            begin
                CadenaMostrar := (Fields[ 0 ].AsString + ' ' + Fields[ 1 ].AsString);
                Synchronize( ActualizaMemo );
                Sleep( 300 );
                Next;
            end;
        end;
    
    finally
        ZConnection.Free;
        ZQuery.Free;
    end;
end;


procedure THilo.ActualizaMemo;
begin
    HPrueba.Memo1.Lines.Add( CadenaMostrar );
end;

procedure THilo.PonTag;
begin
    HPrueba.Tag := 1;
end;

{ ~~~~~~~~~~~~~~~~~~~~          THPrueba          ~~~~~~~~~~~~~~~~~~~~ }

procedure THPrueba.Button20111Click(Sender: TObject);
var Hilo: THilo;
begin
    Hilo := THilo.Create( True );
    Hilo.FreeOnTerminate := False;
    Hilo.Resume;
    Timer1.Enabled := True;
end;

procedure THPrueba.Timer1Timer(Sender: TObject);
begin
    Button20111Click( Self );
    Timer1.Enabled := False;
end;

end.

Este es tu mismo código, con la misma funcionalidad, nada más que acortado y adaptado para que sea más entendible (por lo menos desde mi punto de vista :P)

Saludos,
Chris

[[gluglu]]

... me siento absoluta y totalmente ignorado !

.... bueno, allá vosotros !

Aun así, os vuelvo a indicar que el código expuesto es imposible que funcione correctamente, ya cambies a Oracle o a superbasededatos Ver 1000.1, oc ambies igualmente cualquier componente a supercomponentes Ver 2021.7.

De nuevo os indico los errores, según mi punto de vista, la mayoría de ellos ya los comenté anteriormente :

Código Delphi [-]
THilo = class(TThread)
  private
    procedure ActualizaMemo;
    procedure PonTag;
  public
    CadenaMostrar: string;
    // Olvídate de este Constructor 
    constructor Create( Suspendido: Boolean );
    // Indica que el procedimiento Execute está en protected
  protected
    procedure Execute; override;
end;

El Thread debe de ser TOTALMENTE encapsulado. A lo mejor a la primera no da problemas, pero a ls segunda o tercera, seguro que dá problemas ...

Código Delphi [-]
procedure THilo.Execute;
begin
     // Aqui no tengo mu claro lo que tengo que poner
     while Self.Terminated = False do begin
           if HPrueba.Tag = 0 then begin
              Synchronize( PonTag );

No debes de acceder a una Variable de HPrueba dentro del propio Thread.

Por qué os empeñais en crear dos hilos diferentes con el mismo nombre de la variable ?

Código Delphi [-]
procedure THPrueba.Button20111Click(Sender: TObject);
var Hilo: THilo;
begin
    Hilo := THilo.Create( True );
    Hilo.FreeOnTerminate := False;
    Hilo.Resume;
    Timer1.Enabled := True;
end;

Por mucho que lo ejecuteis después en un Timer, el Thread se vuelve a crear dentro de Button20111Click con el mismo nombre de la variable, y eso os va a dar problemas porque en ningún caso va a saber referenciar correctamente cualquier llamada.

Por qué no probais :

Código Delphi [-]
procedure THPrueba.Timer1Timer(Sender: TObject);
var Hilo2: THilo;
begin
    Hilo2 := THilo.Create( True );
    Hilo2.FreeOnTerminate := False;
    Hilo2.Resume;
    Timer1.Enabled := False;
end;

Saludos ... !

[[gluglu]]

Acabo de generar este código, con Firebird 2.1 y componentes IBX, y me funciona perfectamente, sin problema alguno :

Código Delphi [-]
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, IBCustomDataSet, IBDatabase, StdCtrls;
 
type

  THilo = class(TThread)
  private
    Hilo_DataBase: TIBDatabase;
    Hilo_Transact: TIBTransaction;
    Hilo_Tabla:    TIBDataSet;
    procedure ActualizaMemo;
  public
    CadenaMostrar: string;
  protected
    procedure Execute; override;
  end;
 
  TForm1 = class(TForm)
    IBDatabase1: TIBDatabase;
    IBTransaction1: TIBTransaction;
    IBDataSet1: TIBDataSet;
    Memo1: TMemo;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    Num_Hilo : Integer;
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
  Hilo1: THilo;
  Hilo2: THilo;
 
implementation
{$R *.dfm}
 
procedure THilo.Execute;
var
  i, j : Integer;
  Aux_Date, Aux_Date2   : TDateTime;
  Aux_Valid    : Boolean;
  Count_Categ  : Integer;
  Count_SubCat : Integer;
begin
 
  Hilo_Database := TIBDatabase.Create(nil);
  Hilo_Database.DatabaseName := 'MiBasedeDatos';
  Hilo_Database.LoginPrompt  := False;
  Hilo_Database.Params.Clear;
  Hilo_Database.Params.Add( 'user_name=SYSDBA' );
  Hilo_Database.Params.Add( 'lc_ctype=ISO8859_1' );
  Hilo_Database.Params.Add( 'password=masterkey' );
  Hilo_Database.SQLDialect   := 3;
  Hilo_Database.Connected    := True;
 
  Hilo_Transact := TIBTransaction.Create(nil);
  Hilo_Transact.DefaultDataBase := Hilo_DataBase;
  Hilo_Transact.DefaultAction   := TARollback;
  Hilo_Transact.Params.Clear;
  Hilo_Transact.Params.Add( 'read_committed' );
  Hilo_Transact.Params.Add( 'rec_version' );
  Hilo_Transact.Params.Add( 'nowait' );
  Hilo_Transact.StartTransaction;
 
  Hilo_Tabla := TIBDataSet.Create(nil);
  Hilo_Tabla.Transaction := Hilo_Transact;
  Hilo_Tabla.SelectSQL.Clear;
  Hilo_Tabla.SelectSQL.Add( 'Select NOMBRE, APELLIDO from CLIENTES' );
  Hilo_Tabla.Prepare;
  Hilo_Tabla.Open;
 
  while not Hilo_Tabla.Eof do begin
    CadenaMostrar := Hilo_Tabla.Fields[0].AsString + ' ' +
                     Hilo_Tabla.Fields[1].AsString;
    Synchronize(ActualizaMemo);
    Sleep(1000);
    Hilo_Tabla.Next;
  end;
 
   Cadenamostrar := 'Fin de Fichero';
   Synchronize(ActualizaMemo);
 
end;
 
procedure THilo.ActualizaMemo;
begin
  Form1.Memo1.Lines.Add(CadenaMostrar);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
 
  if Num_Hilo = 1 then begin
    Hilo1 := THilo.Create( True );
    Hilo1.FreeOnTerminate := False;
    Hilo1.Resume;
    Num_Hilo := 2;
  end;
 
  if Num_Hilo = 2 then begin
    Hilo2 := THilo.Create( True );
    Hilo2.FreeOnTerminate := False;
    Hilo2.Resume;
  end;
 
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  Num_Hilo := 1;
end;
 
end.

[[maeyanes]]

Hola...

gluglu, este código:

Código Delphi [-]
procedure THPrueba.Button20111Click(Sender: TObject);
var 
  Hilo: THilo;

begin
  Hilo := THilo.Create(True);
  Hilo.FreeOnTerminate := False;
  Hilo.Resume;
  Timer1.Enabled := True
end;

se puede ejecutar las veces que quieras y no va a dar ningún problema, no se por que sigues diciendo que si. Es más, hasta se podría escribir así:

Código Delphi [-]
begin
  with THilo.Create(True) do
  begin
    FreeOnTerminate := False;
    Resume
  end;
  Timer1.Enabled := True
end;

y seguiría sin dar problemas. Esto claro, en el caso expuesto en el ejemplo. En algún otro caso, donde si necesites hacer referencia a algún hilo en particular, entonces si que se podría usar algún mecanismo para guardar estas referencias.



Saludos...

[[gluglu]]

Pues tienes toda la razón. Estoy equivocado. También funciona como indicas. Lo acabo de comprobar.

Tenía entendido que era 'necesario' tener diferentes referencias de cada hilo. Me queda claro que si no necesito hacer referencia desde otro sitio a ninguno de estos hilos en particular, no hace falta darle diferentes nombres.

... disculpas

[Jack]

gluglu tu código funciona perfecto, mil millones de gracias por tus indicaciones y agradecimiento a todos los que me han dado alguna pista.
Sólo me queda transformar este código para acoplarlo a la recepción y reenvio de datos via socket. Espero no tener ningún problema y poder averiguar donde estaba cometiendo el error que tantos quebraderos de cabeza me ha dado. Cuando lo tenga implementado y funcionando volveré a agradeceros a todos vuestras indicaciones. Un saludo Jack.

[aladelta]

Hola a todos,
Me gustaria hacerles una pregunta...¿se puede interactuar con una tabla creada dentro de un thread?, es decir, en los ejemplos precedentes se declara una database, transaccion y dataset, y la cuestion es si este dataset se puede poner en un dbgrid e interactuar con el dbgrid de forma habitual.
Yo actualmente trabajo en XE2 y firebird 2.5 con los componentes de DBExpress, y si esto se puede extrapolar a estos componentes, ¿podriamos abrir un tclientdataset de un datamodulo dentro de un Thread e interactuar con el en la forma descrita antes?
Gracias a todos por la ayuda.