Se puede hacer un else en un While not query1.eof Do?

[ecfisa]

Hola negrokau.

Una opción de búsqueda es mediante un while como intentaste en tu mensaje inicial:

Código Delphi [-]
var
  Found: Boolean;
begin
  query1.First;
  Found:= False;
  while not query1.Eof and not Found do
  begin
    Found:= cod_barra.Text = query1.FieldValues['cod_barra'];
    query1.Next;
  end;
  if not Found then
   guardar.Click;
  ...

Creo que el error en tu primer código, parte de la confusión que tenés con las estructuras de control.
Como yá te han dicho más arriba, una cosa es una estructura decisión (if/then/else) y otra una de iteracion (for, while, repeat) aunque las dos últimas puedan evaluar alguna condición.

La otra opción, más eficiente, es mediante una consulta SQL:

Código Delphi [-]
function ExisteCodigo(const Value: string): Boolean;
begin
  with TQuery.Create(nil) do
  try
    DatabaseName:= 'NOMBRE_DE_TU_BD';  // Alias (o Ruta a donde esta la tabla)
    SQL.Text:= 'SELECT * FROM TU_TABLA WHERE COD_BARRA = :DATO';  // Cambia 'TU_TABLA' por tu nombre de tabla
    ParamByName('DATO').AsString:= Value;
    Open;
    Result:= not IsEmpty;
    Close;
  finally
    Free;
  end;
end;

De esta manera tu código inicial queda reducido a:

Código Delphi [-]
  if not ExisteCodigo(cod_barra.Text) then
    guardar.Click;

Un saludo.

[negrokau]

disculpame la ignorancia amigo... pero como nunca hice como esta en el ejemplo que me diste... en donde lo coloco la consulta?

Código Delphi [-]
function ExisteCodigo(const Value: string): Boolean;
begin
  with TQuery.Create(nil) do
  try
    DatabaseName:= 'C:\SGC v1.0\Database\SGC_v1.GDB';  // Alias (o Ruta a donde esta la tabla)
    SQL.Text:= 'SELECT * FROM FACTURAS WHERE COD_BARRA = ATO';  // Cambia 'TU_TABLA' por tu nombre de tabla
    ParamByName('DATO').AsString:= Value;
    Open;
    Result:= not IsEmpty;
    Close;
  finally
    Free;
  end;
end;

[Casimiro Noteví]

Donde quieras, da igual.
Tan sólo recuerda que además deberás declarar la function en la sección private (arriba, al principio del código).

Código Delphi [-]
private
  function ExisteCodigo(const Value: string): Boolean;

Y ese código, esa function, la pones por ejemplo, al final del todo.

[negrokau]

lo estoy probando pero me salta este error:
Declaration expected but identifier 'private' found
algo no estoy haciendo bien creo....

[Casimiro Noteví]

¿Dónde lo has puesto?.

El código, pega tu código, que no somos adivinos
_______________________________||
_______________________________\/

[ecfisa]

Hola negrokau.

Declararlo como un método como te indica Casimiro es la mejor opción ya que no importa la posición donde ubiques el código de la función:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages,...;

type
  TForm1 = class(TForm)
    ...
  private
     function ExisteCodigo(const Value: string): Boolean;
  public
  end;

var
  Form1: TForm1;

implementation  {$R *.dfm}

// aca el resto de tu codigo

function TForm1.ExisteCodigo(const Value: string): Boolean;
begin
 with TQuery.Create(nil) do
  try
    DatabaseName:= 'C:\SGC v1.0\Database\SGC_v1.GDB';
    SQL.Text:= 'SELECT * FROM FACTURAS WHERE COD_BARRA =:DATO';
    ParamByName('DATO').AsString:= Value;
    Open;
    Result:= not IsEmpty;
    Close;
  finally
    Free;
  end;
end;

// o, si preferís aca el resto de tu codigo

end.

Otra opción es declararlo como función, pero para ello, la cabecera debe estar declarada antes del método o función que la invoque. Para asegurar el tiro, inmediatamente después a la declaración Implementation, de ese modo la función, tendrá alcance a todo código subyacente a ella:

Código Delphi [-]
...
Implementation

function ExisteCodigo(const Value: string): Boolean;
begin
  ...

Saludos.