Recoger informacion de todas las ventanas de una aplicación

[ecfisa]

HolaJoviali y bienvenido a Club Delphi

Como a todos los que se inician te invitamos a que leas nuestra guía de estilo.

Para obtener los valores de las propiedades Name y Caption de los forms creados en una aplicacion podes utilizar la variable Screen.

Un ejemplo:

Código Delphi [-]
...
var
  i: Integer;
begin
  with Screen do
    for i:= 0 to FormCount-1 do
      ListBox1.Items.Add(Forms[i].Name + ' ' + Forms[i].Caption)
end;

En cuanto a "la case" no se que significa.

Saludos.

[ecfisa]

Hola de nuevo.

Releyendo tu mensaje, creo que te referis al nombre de la clase (no me dí cuenta en la primera leida).

En ese caso cambiá en el código anterior esta linea:

Código Delphi [-]
     ListBox1.Items.Add(Forms[i].Name + ' ' + Forms[i].Caption)

Por esta:

Código Delphi [-]
    ListBox1.Items.Add(Format('Name: %s, Caption: %s, ClassName: %s',
        [Forms[i].Name ,Forms[i].Caption, Forms[i].ClassName]))

Saludos.

[Joviali]

Buenas, esto funciona para la misma aplicacion en ejecución , lo que busco son esos mimos datos que me has comentado anteriormente pero de otra aplición . Yo he estado probando con las siguientes funciones:

FindWindow //Para encontrar la aplicacione en concreto.

GetWindowText(wnd, WinName, 144); // Obtiene el texto de la ventana actual
GetClassName(wnd, CName, 144); // Obtiene el nombre de la clase

siendo wnd el Handle de la aplicacion principal.

Pero esto no me funciona ya que no me recorre las ventanas hijas de la apliccion.



En definitiva lo que busco es que una aplicación "A" busque cuantas ventanas tiene la aplicación "B" abiertas. y me de la información de la clase de cada una de ellas:
b--->TF_principal.
b1--->Tf_aux1
b2--->tf_aux2.

Todo esto viene porque estoy haciendo un programa que actualiza otro y necesito saber que esta en la ventana principal de la aplicacion para poder cerrarla y actualizar la aplicación.


Gracias.

[Casimiro Noteví]

Recuerda poner los tags al código fuente, ejemplo:



Gracias

[[escafandra]]

Quizás esto te de pistas:

Código Delphi [-]
procedure ListWinInfoFromPId(PId: DWORD; Strings: TStrings);
type
  TWinParam = record
    Handle: THandle;
    PId: DWORD;
  end;
  PWinParam = ^TWinParam;
var
  WinParam: TWinParam;
  Buffer: array [1..255] of char;

  function EnumWindowsProc(Handle: Thandle; lParam: LPARAM): BOOL; stdcall;
  var
    PId: DWORD;
  begin
    Result:= true;
    PId:= 0;
    GetWindowThreadProcessId(Handle, PId);
    if PWinParam(lParam).PId = PId then
    begin
      PWinParam(lParam).Handle:= Handle;
      Result:= false;
    end;
  end;

begin
  WinParam.PId:= PId;
  EnumWindows(@EnumWindowsProc, LPARAM(@WinParam));
  Strings.Clear;
  repeat
    Strings.Add('hWnd: ' + IntToHex(WinParam.Handle, 8));
    GetWindowText(WinParam.Handle, @Buffer, 255);
    Strings.Add('Caption: ' + Buffer);
    GetClassName(WinParam.Handle, @Buffer, 255);
    Strings.Add('Clase: ' + Buffer);
    Strings.Add('-----------------------------------------------');
    WinParam.Handle:= Windows.GetParent(WinParam.Handle);
  until WinParam.Handle = 0;
end;

Ejemplo de uso:

Código Delphi [-]
ListWinInfoFromPId(4800, Memo1.Lines);

Saludos.

[[escafandra]]

Y mejor de esta otra forma:

Código Delphi [-]
procedure ListWinInfoFromPId(PId: DWORD; Strings: TStrings);
type
  TWinParam = record
    PId: DWORD;
    S: TStrings;
  end;
  PWinParam = ^TWinParam;
var
  WinParam: TWinParam;

  function EnumWindowsProc(Handle: Thandle; lParam: LPARAM): BOOL; stdcall;
  var
    PId: DWORD;
    Buffer: array [1..255] of char;
  begin
    Result:= true;
    PId:= 0;
    GetWindowThreadProcessId(Handle, PId);
    if PWinParam(lParam).PId = PId then
    begin
      PWinParam(lParam).S.Add('hWnd: ' + IntToHex(Handle, 8)+'h');
      GetWindowText(Handle, @Buffer, 255);
      PWinParam(lParam).S.Add('Caption: ' + Buffer);
      GetClassName(Handle, @Buffer, 255);
      PWinParam(lParam).S.Add('Clase: ' + Buffer);
      PWinParam(lParam).S.Add('-----------------------------------------------');
      Result:= true;
    end;
  end;

begin
  Strings.Clear;
  WinParam.PId:= PId;
  WinParam.S:= Strings;
  EnumWindows(@EnumWindowsProc, LPARAM(@WinParam));
end;

Con el mismo ejemplo de uso:

Código Delphi [-]
ListWinInfoFromPId(4800, Memo1.Lines);

Saludos.

[Joviali]

Buenas,
La funcion que me has pasado me ha ayudado mucho, por cierto he tenido que cambiar esto para que funcione

Código Delphi [-]GetWindowThreadProcessId(Handle, PId);
por GetWindowThreadProcessId(Handle,@ PId);



La funcion me ha devuelto mas informacion de la que esperaba y me ha surgido la siguiente duda.
¿Puedo preguntar si la Clase TF_MULTICONSULTA es una calse class(TForm) ?.Esto me ayudaria ya
que me mostraria solo los formularios de la aplicacion.

hWnd: 000202B6h
Caption: MultiConsulta
Clase: TF_MULTICONSULTA
-----------------------------------------------
hWnd: 000102B0h
Caption: Aplicación Servidor -
Clase: TF_Principal
-----------------------------------------------
hWnd: 000202A2h
Caption:
Clase: TfrProgressForm
-----------------------------------------------
hWnd: 00060248h
Caption: Servidor -
Clase: TApplication
-----------------------------------------------
hWnd: 011B04D2h
Caption:
Clase: ComboLBox
-----------------------------------------------
hWnd: 000102CAh
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102C8h
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102C6h
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102C4h
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102C2h
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102C0h
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102BEh
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102BCh
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102B4h
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102AEh
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102ACh
Caption:
Clase: TPUtilWindow
-----------------------------------------------
hWnd: 000102D8h
Caption: M
Clase: MSCTFIME UI
-----------------------------------------------
hWnd: 0004022Ch
Caption: Default IME
Clase: IME
-----------------------------------------------