Compatibilidad de imagenes en campos Blob

[roman]

A ver, creo que ya está un poco más claro, aunque sigue bastante oscuro .

Parece ser que siempre sí, la culpa es de SQLite, pero componentes como ZEOS saben cómo arreglar las cosas mientras que los componentes nativos de Lázarus no, o al menos todavía no encuentro como.

El problema con SQLite (y es que apenas hago mis pininos con este gestor) no es tanto que añada encabezados a un blob o que lo guarde en una forma no estándar. El problema es que SQLite usa los caracteres #0 (NULL) como separador de columnas de manera que no puede guardar bytes cero en un campo BLOB. Tal parece entonces que sustituye los ceros por un caracter de porcentaje %. Se supone que esto ya no es así en la versión 3 pero es con la que he estado haciendo pruebas y así es como guarda las imágenes.

No he instalado los componentes ZEOS en Lázarus (no pude ) pero examinando el código fuente, me encontré esto:

Código Delphi [-]
function DecodeString(Value: string): string;
var
  SrcLength, DestLength: Integer;
  SrcBuffer, DestBuffer: PChar;
begin
  SrcLength := Length(Value);
  SrcBuffer := PChar(Value);
  SetLength(Result, SrcLength);
  DestLength := 0;
  DestBuffer := PChar(Result);

  while SrcLength > 0 do
  begin
    if SrcBuffer^ = '%' then
    begin
      Inc(SrcBuffer);
      if SrcBuffer^ <> '0' then
        DestBuffer^ := SrcBuffer^
      else DestBuffer^ := #0;
      Inc(SrcBuffer);
      Dec(SrcLength, 2);
    end
    else
    begin
      DestBuffer^ := SrcBuffer^;
      Inc(SrcBuffer);
      Dec(SrcLength);
    end;
    Inc(DestBuffer);
    Inc(DestLength);
  end;
  SetLength(Result, DestLength);
end;

Esta función la usa en el método GetBlob de la clase TZSQLiteResultSet:

Código Delphi [-]
function TZSQLiteResultSet.GetBlob(ColumnIndex: Integer): IZBlob;
var
  Stream: TStream;
begin
{$IFNDEF DISABLE_CHECKING}
  CheckBlobColumn(ColumnIndex);
{$ENDIF}
  Stream := nil;
  try
    if not IsNull(ColumnIndex) then
    begin
      if TZAbstractResultSetMetadata(Metadata).GetColumnType(ColumnIndex)
        <> stBinaryStream then
        Stream := TStringStream.Create(GetString(ColumnIndex))
      else Stream := TStringStream.Create(DecodeString(GetString(ColumnIndex)));
      Result := TZAbstractBlob.CreateWithStream(Stream)
    end else
      Result := TZAbstractBlob.CreateWithStream(nil);
  finally
    if Assigned(Stream) then
      Stream.Free;
  end;
end;

Con un aplicación delphi abrí el archivo guardado desde el BlobField, le pase la función anterior y vacié la cadena nuevamente en un archivo y voilà, la imagen ya era la correcta.

La función compila sin problemas en Lázarus, pero no he podido usarla porque la clase TStringStream no es compatible con la de delphi así que todavía no encuentro cómo usarla para almacenar el blob, convertirlo y vaciarlo en un TBitmap.

Seguiremos informando...

// Saludos

[Casimiro Noteví]

Qué extraño resulta ese asunto

[Casimiro Noteví]

Una búsqueda en google encuentra casos hablando sobre ese tema, parece que es un problema de sqlite, como dices, que cambia el \0 por el %0

[roman]

Empezado por Casimiro Notevi

que cambia el \0 por el %0

¡Ah! Cuidado. Fue mi primer intento, pero no. Reemplaza \0 por %, no por %0.

// Saludos

[Casimiro Noteví]

¿Entonces el código que has puesto no es afectado por ese cambio de caracteres?

[roman]

El código que puse ya usa la función DecodeString que encontré en ZEOS, para poner los % en \0s.

// Saludos

[roman]

Empezado por Casimiro Notevi

Qué extraño resulta ese asunto

Bueno, va tomando lógica ¿no? Una limitante de SQLite lo obligaba a hacer esa conversión.

Ahora, lo de

Empezado por roman

la clase TStringStream no es compatible con la de delphi

lo dije, evidentemente, sin pensarlo bien. Estaba equivocado. Ya pude pasar el código a Lázarus para leer la imagen de SQLite y exhibirla en un Image:

Código Delphi [-]
procedure TForm1.Button2Click(Sender: TObject);
var
  BlobField: TBlobField;
  EncodedStream: TStringStream;
  DecodedStream: TStringStream;
  DataString: String;

begin
  BlobField := SQLQuery1.FieldByName('foto') as TBlobField;
  EncodedStream := TStringStream.Create('');

  try
     // Leemos el blob
     BlobField.SaveToStream(EncodedStream);

     // Decodificamos la cadena
     DataString := DecodeString(EncodedStream.DataString);

     // Creamos un nuevo stream con la cadena decodificada
     DecodedStream := TStringStream.Create(DataString);

     try
        // Creamos el bitmap con el blob ya decodificado
        Image1.Picture.Bitmap.LoadFromStream(DecodedStream);
     finally
       DecodedStream.Free;
     end;
  finally
    EncodedStream.Free;
  end;
end;

Al menos me ha funcionado la prueba. Habrá que ver si no tiene algún problema.

// Saludos

[ElMug]

Gracias, Roman, voy a estudiar lo que reportas.

Se agradece mucho tu analisis.

Yo estoy usando SQLite3, a proposito, la mas reciente, en Windows 7, 32 bits.

Mas no creo que esa vaya a ser la razon.

Habra que ver.

[roman]

Yo tambié usé SQLite3. Prueba el código a ver si te funciona.

// Saludos

[ElMug]

Gracias, Roman por compartir tu investigacion.

Voy a instalar Zeos pero me voy a ir despacio en esto por estar ahora en otras cuestiones relacionadas, tambien con algo de sorpresa en cuanto a no ser lo que me esperaba con SQLite3 y los componentes default de Lazarus. Creo que pondre otro hilo un poco despues, ya que cheque otras cosas al respecto.

[roman]

Empezado por ElMug

tambien con algo de sorpresa en cuanto a no ser lo que me esperaba con SQLite3 y los componentes default de Lazarus.

En un principio culpé a Lázarus, luego a SQLite, pero ahora más bien creo que la culpa es de SQLiteAdmin.

Vamos a ver, es posible que SQLiteAdmin haya tenido la precaución de solventar la limitante de SQLite en sus versiones 2.x pero, ahora, para la versión 3.x, sigue aplicando la conversión, que no debería.

He probado otros administradores, como SQLiteManager y SQLite2009 Pro Enterprise Manager y ambos han resultado ser compatibles con el TSQLite3Connection de Lázarus sin ningún tipo de conversión, esto es, simplemente guardando los datos en el blob tal cual.

Luego entonces, más que decepcionarse de Lázarus por este aspecto, quizá habría que contemplar el uso de otro administrador en lugar del SQLiteAdmin.

// Saludos

[ElMug]

Hola Roman,

Tengo ya dias investigando esto y entre otras cosas tratando de terminar mi aplicacion en Lazarus, y vine al foro de nuevo a comunicar practicamente lo mismo que concluyes, en lo que el problema este en SQLite Administrator.

Esto tambien lo verifica otro administrador llamado SQLite Man.

SQLite Man abre y muestra las imagenes que he cargado de mi aplicacion Lazarus, a una base de datos, perfectamente.

Vi que SQLite Man es un producto mas maduro y algo mas avanzado y se autorecomienda como "el mejor". Tal vez lo sea.

Voy a checar tambien los que mencionas.

En caso de alguna novedad, con gusto la reportaria.

Muchas gracias a todos ustedes por la ayuda y atencion prestada.