Canvas dolor de cabeza+helpme

[Casimiro Noteví]

Bueno, no te preocupes, es tu primer mensaje en estos foros y es normal que no lo supieras.

Lo del título sirve, entre otras cosas, porque al final de esta página aparecen enlaces con términos similares y puede que alguno sea lo que buscas.
En este caso, como puedes ver, han salido enlaces que no sirven para nada, al igual que el titulo que has puesto.

Creo que lo que quieres es copiar una imagen, supongo que de un TImage a otro sitio, a ver si alguien puede echarte una mano con eso.
Saludos.

[[escafandra]]

Creo que es esto lo que quieres hacer:

Código Delphi [-]
var
StartX, StartY : integer;

procedure TForm1.ImagenMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  Origen, Destino: TRect;
begin
  Origen.Left := StartX;
  Origen.Top := StartY;
  Origen.Right := x;
  Origen.Bottom := y;

  Destino.Left := 0;
  Destino.Top := 0;
  Destino.Right := abs(Origen.Left - Origen.Right);
  Destino.Bottom := abs(Origen.Top - Origen.Bottom);
  Canvas.Rectangle(Destino);
  Canvas.CopyRect(Destino, Imagen.Picture.Bitmap.Canvas, Origen);
end;

procedure TForm1.ImagenMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  StartX:= X;
  StartY:= Y;
end;

Saludos.

[Comandant]

Hola nuevamente, agradezco por su atención y estoy en deuda, aunque hoy estuve viendo mi código y me anduvo muy bien, nose porque la otra vez no me dio el resultado esperado me quede pensando en el porque?, Bien escafandra tu código es lo mismo que el mio nada mas que mas simplificado y me diste nuevas ideas con el valor absoluto, porque había probado de sumar a su left el width de un elemento dado y a veces me daba excepciones por el número negativo, dejo avisando que ambos códigos tienen un problema y es que cuando haces un rectángulo de derecha a izquierda da como un resultado final una imagen tipo espejo, no creo que sea muy difícil de solucionar así que me pondré a trabajar. Desde ya muchas Gracias

Aqui esta código final para los que lo quieran, obviamente el resto ya lo saben...

Código Delphi [-]
procedure TForm2.Image1MouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  Origen, Destino: TRect;
begin
//realizar el canvas
Canvas.Brush.Style:= bsClear;
  with Canvas do
  begin
    if StartX > X then
      begin
      Origen.Left := X;
      Origen.Right := StartX;
      end
    else
      begin
      Origen.Left := StartX;
      Origen.Right := x;
      end;
    if StartY > Y then
      begin
      Origen.Top := Y;
      Origen.Bottom := StartY;
      end
    else
      begin
      Origen.Top := StartY;
      Origen.Bottom := y;
      end;
    Canvas.Rectangle(Origen);
    Destino.Left := 0;
    Destino.Top := 0;
    Destino.Right := abs(Origen.Left - Origen.Right);
    Destino.Bottom := abs(Origen.Top - Origen.Bottom);
    CopyRect( Destino, Image1.Canvas, Origen);
  end;
end;

[[escafandra]]

Empezado por Comandant

cuando haces un rectángulo de derecha a izquierda da como un resultado final una imagen tipo espejo...

Puedes simplificarlo así:

Código Delphi [-]
uses Math;
var
StartX, StartY : integer;

procedure TForm1.ImagenMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  Origen, Destino: TRect;
begin
  Origen.Left := Min(StartX, x);
  Origen.Top := Min(StartY, y);
  Origen.Right := Max(StartX, x);
  Origen.Bottom := Max(StartY, y);;

  Destino.Left := 0;
  Destino.Top := 0;
  Destino.Right := abs(Origen.Left - Origen.Right);
  Destino.Bottom := abs(Origen.Top - Origen.Bottom);
  Canvas.Rectangle(Destino);
  Canvas.CopyRect(Destino, Imagen.Picture.Bitmap.Canvas, Origen);
end;

procedure TForm1.ImagenMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  StartX:= X;
  StartY:= Y;
end;

Saludos.