Como hacer para totalizar una columna de un stringgrid por valor

[steelha]

Ok voy a implementar las lineas a ver

[[duilioisola]]

He estado jugando un poco con el código y he creado esta función, que creo que hace lo que tu necesitas, pero no lo va pasando de Memo en Memo...
La única interacción que tiene con el formulario es el Label que cuenta las líneas. Si quitas eso y el Application.ProcessMessages será mucho más rápido.

He creado un botón llamado ButtonAgrupar y le he puesto el código.

No utiliza StringGrids, que son visuales, por lo que no utiliza tanta memoria. De todos modos carga el texto en un TStringList.
Es fácilmete modificable para no utilizar nada de memoria, abriendo el archivo origen y escribiendo en el archivo destino mediante Readln(F, s); y Writeln(F, s);

Espero que te sirva.

Código Delphi [-]
procedure TForm1.ButtonAgruparClick(Sender: TObject);
var
   s1, s2 : TStringList;
   archivo: string;
   monto, nombre, autoriz, fecha : string;
   i : Integer;
   cant : Integer;
   conv : Double;
   ruta : string;
   dia  : Word;
   mes  : Word;
   ano  : Word;
   hor  : Word;
   min  : Word;
   sec  : Word;
   mil  : Word;
   romp : string;
   total: Real;
begin
   // inicializo variables
   detener := 'N';
   autoriz :='';
   nombre := '';
   fecha :='';
   total := 0;
   cant := 0;

   // Creo StringLists para trabajar con los textos
   s1 := TStringList.Create;
   s2 := TStringList.Create;
   try
      // Pido datos origen
      OpenDialog1.Execute;
      archivo := OpenDialog1.FileName;

      // Cargar archivo de texto
      s1.LoadFromFile(archivo);

      // Obtengo el nombre del fichero destino
      DecodeDate(Now,ano,mes,Dia);
      DecodeTime(Now,hor,min,sec,mil);
      ruta := OpenDialog1.InitialDir +'Universal_'+inttostr(Dia)+inttostr(mes)+inttostr(ano)+'_'+inttostr(hor)+inttostr(min)+inttostr(sec  )+'.txt';

      // Inicializo romp con el valor de la primera linea
      romp := Trim(Copy(s1[0], 35, 15)); // Rompe por AUTORIZACION

      // Recorro todo el archivo
      for i := 0 to (s1.Count-1) do
      begin
         monto := Trim(Copy(s1[i], 71, 14));   // MONTO
         nombre := Trim(Copy(s1[i], 85, 80));  // NOMBRE
         autoriz := Trim(Copy(s1[i], 35, 15)); // AUTORIZACION
         fecha := Trim(Copy(s1[i], 10,  8));   // FECHA AUTORIZACION

         // Datos completos no error de separacion de lineas
         If (monto <> '') and (nombre <> '') and (autoriz <> '') then
         begin
            // Colocar punto al monto
            conv := (StrToFloat(monto)*0.01);
            monto := FloatToStr(conv);

            // Si la autorizacion no es vacia
            If Trim(autoriz) <> '' then
            begin
               // Si cambio el campo autorizacion, creo un registro e inicializo total
               If Trim(autoriz) <> Trim(romp) then
               begin
                  nombre := fecha + #9 + nombre + #9 + '0000000' + #9 + '0000000' + #9 + '0000000' + #9 + autoriz + #9 + FloatToStr(total) + #9 + FloatToStr(total);
                  s2.Add(nombre);

                  total := 0;
                  romp  := Trim(autoriz);
               end;
            end;

            // Acumulo monto
            total := total + StrToFloat(monto);

            // Cuento lineas tratadas
            cant := cant + 1;
            Label2.Caption := IntToStr(cant);
            Application.ProcessMessages;
         end;

         If Detener = 'S' then Break;
      end;

      // Terminé de recorrer pero todavía tengo un ultimo total
      If (total > 0) then
      begin
         nombre := fecha + #9 + nombre + #9 + '0000000' + #9 + '0000000' + #9 + '0000000' + #9 + autoriz + #9 + FloatToStr(total) + #9 + FloatToStr(total);
         s2.Add(nombre);
      end;

      // Guardo las lineas agrupadas
      s2.SaveToFile(ruta);
   finally
      // Libero StringGrids
      s1.Free;
      s2.Free;
   end;

   // Termino aplicacion
   Application.Terminate;
end;

[[duilioisola]]

Con este procedimiento he logrado procesar los 177000 registros
Solo he tenido que controlar que el valor de monto se pudiera convertir mediante

Código Delphi [-]
            try
               conv := (StrToFloat(monto)*0.01);
               monto := FloatToStr(conv);
            except
               monto := '0';
            end;

También he hecho la prueba de copiar y pegar dos veces el text con 354000 lineas.
También lo pude tratar en una máquina virtual con 384 MB de RAM.

[steelha]

Si muchas gracias el codigo funciona de maravillas, con la except que cuando un valor en la linea falta y esta rueda los valores que toma son diferentes. he tratado de controlarlo pero los casos varian a veces son 10 spacios o 5 spacios menos.

[steelha]

tambien me añade la ultima fila mal

[[duilioisola]]

Este es el formato de tu fichero:
La línea de en medio es una que tiene una longitud incorrecta porque falta un dato en medio.

         1         2         3         4         5         6         7         8         9         0
123456789 123456789 123456789 123456789 123456789 123456789 123456789 123456789 123456789 123456789 
         F------F                 A-------------A                     M------------MN------------------------------------------------------------------------------N
0420000033011201203004457  29      12546964       A010010010100001516000000000366700PORTORREAL GIL RODNER FRANCISCO                                                                     MED001  
0420000033011201203004457  29      12546964       A010010010100001516000000000366700PORTORREAL GIL RODNER FRANCISCO                                                                     MED001  
042000003301120120       12607904       A010010010100001516000000000037500PORTORREAL GIL RODNER FRANCISCO                                                                     S20001  
0420000033011201204000000000       12647953       A010010010100001516000000000038900QUEZADA DE CABRERA ORIA ESTHER                                                                      881201  
0420000033011201204000000000       12647953       A010010010100001516000000000038900QUEZADA DE CABRERA ORIA ESTHER                                                                      881340

Aparentemente todas las líneas tienen la misma longitud.
La primera verificación, antes de procesarla deberá ser comprobar la longitud. Si no es correcta, deberas descartarla y enviar un mensaje o advertencia o lo que sea necesario hacer.

Además de esto, veo que estas desfasado 1 caracter a la izquierda con respecto al campo AUTORIZACION.

[steelha]

Muchas gracias duilioisola por la ayuda, el código es perfecto ya he hecho unos arreglos extras y todo marcha de maravillas. Dure mucho para darme cuenta que no era que no estaba acumulando valor sino que me repetia el nombre anterior para eso guardo en variables extras ... Publico codigo para aquellos que lo necesiten.

Código Delphi [-]
unit leeruniversal;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Buttons;

type
  TForm1 = class(TForm)
    ButtonAgrupar: TBitBtn;
    OpenDialog1: TOpenDialog;
    Label1: TLabel;
    Label2: TLabel;
    BitBtn1: TBitBtn;
    procedure ButtonAgruparClick(Sender: TObject);
    procedure BitBtn1Click(Sender: TObject);
  private
    { Private declarations }
    detener : string;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.ButtonAgruparClick(Sender: TObject);
var
   s1, s2 : TStringList;
   archivo: string;
   monto, nombre, autoriz, fecha : string;
   anombre, aautoriz, afecha : string;
   i : Integer;
   cant : Integer;
   conv : Double;
   ruta : string;
   dia  : Word;
   mes  : Word;
   ano  : Word;
   hor  : Word;
   min  : Word;
   sec  : Word;
   mil  : Word;
   romp : string;
   total: Real;
   erro : Integer;
   errl : string;
   linea: string;
   taman: Integer;
   orig : string;
begin
   // inicializo variables
   detener := 'N';
   autoriz :='';
   nombre := '';
   fecha :='';
   aautoriz :='';
   anombre := '';
   afecha :='';
   errl   := '';
   linea:='';
   total := 0;
   cant := 0;
   erro := 0;
   orig := '0402364972811201203003798  118     12424409       A010010010100013402000000000014450PEÑA  PAULA                                                                                         903856  ';
   taman:= Length(orig);

   // Creo StringLists para trabajar con los textos
   s1 := TStringList.Create;
   s2 := TStringList.Create;
   try
      // Pido datos origen
      OpenDialog1.Execute;
      archivo := OpenDialog1.FileName;

      // Cargar archivo de texto
      s1.LoadFromFile(archivo);

      // Obtengo el nombre del fichero destino
      DecodeDate(Now,ano,mes,Dia);
      DecodeTime(Now,hor,min,sec,mil);
      ruta := OpenDialog1.InitialDir +'Universal_'+inttostr(Dia)+inttostr(mes)+inttostr(ano)+'_'+inttostr(hor)+inttostr(min)+inttostr(sec  )+'.txt';

      // Inicializo romp con el valor de la primera linea
      romp := Trim(Copy(s1[0], 36, 8)); // ROMPER POR AUTORIZACION
      anombre := Trim(Copy(s1[i], 85, 60));  // PRIMER NOMBRE
      aautoriz := Trim(Copy(s1[i], 36, 8)); // PRIMERA AUTORIZACION
      afecha := Trim(Copy(s1[i], 10, 8));   // PRIMERA FECHA AUTORIZACION

      // Recorro todo el archivo
      for i := 0 to (s1.Count-1) do
      begin
         if Length(s1.Strings[i]) = taman then
         begin
           monto := Trim(Copy(s1[i], 70, 15));   // MONTO
           nombre := Trim(Copy(s1[i], 85, 60));  // NOMBRE
           autoriz := Trim(Copy(s1[i], 36, 8)); // AUTORIZACION
           fecha := Trim(Copy(s1[i], 10, 8));   // FECHA AUTORIZACION

           // Datos completos no error de separacion de lineas
           If (monto <> '') and (nombre <> '') and (autoriz <> '') then
             begin
                // Colocar punto al monto
                try
                   conv := (StrToFloat(monto)*0.01);
                   monto := FloatToStr(conv);
                except
                   monto := '0.00';
                   erro := erro + 1;
                   Label1.Caption := 'Cantidad de errores encontrados = ' +  IntToStr(erro);
                end;
             end;

            // Si la autorizacion no es vacia
           If Trim(autoriz) <> '' then
            begin
               // Si cambio el campo autorizacion, creo un registro e inicializo total
               If Trim(autoriz) <> Trim(romp) then
               begin
                  linea := '';
                  linea := afecha + #9 + anombre + #9 + '0000000' + #9 + '0000000' + #9 + '0000000' + #9 + aautoriz + #9 + FloatToStr(total) + #9 + FloatToStr(total);
                  s2.Add(linea);
                  total := 0;
                  romp  := Trim(autoriz);
                  anombre := nombre;
                  afecha  := fecha;
                  aautoriz:= autoriz;
               end;
            end;

            // Acumulo monto
            total := total + StrToFloat(monto);

            // Cuento lineas tratadas
            cant := cant + 1;
            Label2.Caption := IntToStr(cant);
            Application.ProcessMessages;

            If Detener = 'S' then
              Break;
          end
         else
            begin
              errl := errl + 'Error en Linea '+IntToStr(i)+' - '+ s1.Strings[i]+ ' (TAMAÑO DE LINEA NO COINCIDEN) '+#13;
            end;
         end;

      // Terminé de recorrer pero todavía tengo un ultimo total
      If (total > 0) then
      begin
         linea := '';
         linea := afecha + #9 + anombre + #9 + '0000000' + #9 + '0000000' + #9 + '0000000' + #9 + aautoriz + #9 + FloatToStr(total) + #9 + FloatToStr(total);
         s2.Add(linea);
      end;


      // Guardo las lineas agrupadas
      s2.SaveToFile(ruta);
      ShowMessage(errl);
   finally
      // Libero StringGrids
      s1.Free;
      s2.Free;
   end;

   // Termino aplicacion
   Application.Terminate;
end;

procedure TForm1.BitBtn1Click(Sender: TObject);
begin
  detener := 'S';
end;

end.

[[duilioisola]]

Ten en cuenta que donde inicializas algunas variables estás utilizando i, que no está inicializada y puede contener basura.

Código Delphi [-]
      // Inicializo romp con el valor de la primera linea
      romp := Trim(Copy(s1[0], 36, 8)); // ROMPER POR AUTORIZACION
      anombre := Trim(Copy(s1[i], 85, 60));  // PRIMER NOMBRE
      aautoriz := Trim(Copy(s1[i], 36, 8)); // PRIMERA AUTORIZACION
      afecha := Trim(Copy(s1[i], 10, 8));   // PRIMERA FECHA AUTORIZACION

Creo que deberías reemplazar la variable i por un 0 en todas estas líneas.