como exportar una tabla paradox a un archivo plano

[hamer]

Muchas gracias me sirvió mucho el código exporta muy bien a txt pero una ultima cosa es como un poco lento no se si es por la cantidad de datos de la tabla que tengo que pasar, si es posible hacerlo mas rápido o es así en general

[hamer]

aunque ahora que miro no es que este lenta sino que no quiere exportar esa tabla no se si es por el password que tiene que no deja exportar, ya que cree una tabla nueva y esta si me exporto sin ningún problema pero la que necesito no lo realiza.

[hamer]

Muchas gracias de verdad me sirvió mucho el error que tenia era algo sencillo por copiar mal una cosa pero esta exportando perfecto gracias por la colaboración

[bulc]

Se te ha olvidado una opción sencilla. Es colocar un módulo de impresión y seleccionar como salida un archivo. De esta forma te quedará bien colocado. Ah... y con la posibilidad de ordenarlo a tu gusto según el criterio que impongas como índice. Más vale tarde que nunca.
Bulc

[radenf]

Hola amigos:

He adaptado el código de ecfisa para exportar los datos de una tabla de Access a un archivo de texto y funciona a la perfección.
Necesito hacer la operación inversa, es decir exportar los datos del archivo de texto a una tabla de Access, pero no he podido dar con el código. Me quedé pegado asignando los datos a un Stringlist y no he logrado asignar los datos a los campos de la tabla.
¿Puede alguien echarme una mano?
Saludos y muchas gracias

[ecfisa]

Hola randenf.

Fijate si te sirve de este modo:

Código Delphi [-]
procedure ExportToText(const aFileName: TFilename; aDataSet: TDataSet); //(o TADODataSet, etc ...)
var
  F: TextFile;
  i: Integer;
  s: string;
begin
  AssignFile(F, aFileName);
  Rewrite(F);
  aDataSet.Open;
  while (not aDataSet.EOF) do
  begin
    s := '';
    for i := 0 to aDataSet.FieldCount-1 do
      s := s + aDataSet.Fields[i].AsString +',';
      SetLength(s, Length(s)-1);
    Writeln(F, s);
    aDataSet.Next;
  end;
  aDataSet.Close;
  CloseFile(F);
end;

procedure ImportFromText(const aFileName: TFileName; aDataSet: TDataSet); //(o TADODataSet, etc ...)
var
  TS1, TS2: TStrings;
  i, j: Integer;
begin
  aDataSet.Open;
  TS1 := TStringList.Create;
  try
    TS1.LoadFromFile(aFileName);
    for i := 0 to TS1.Count-1 do
    begin
      try
        TS2 := TStringList.Create;
        ExtractStrings([','], [], PChar(TS1[i]), TS2);
        aDataSet.Append;
        for j := 0 to aDataSet.FieldCount-1 do
          aDataSet.Fields[j].AsString := TS2[j];
        aDataSet.Post;
      finally
        TS2.Free;
      end;
    end;
  finally
    TS1.Free;
    aDataSet.Close;
  end;
end;

Ejemplo llamadas:

Código Delphi [-]
 ExportToText('C:\Export.txt', DataSet);
 ...
 ImportFromText('C:\Export.txt', DataSet);

Saludos.

[radenf]

Muchas gracias Daniel.
Lo probaré y te cuento.
Saludos

Iván