como exportar una tabla paradox a un archivo plano

[radenf]

Hola amigos:

He adaptado el código de ecfisa para exportar los datos de una tabla de Access a un archivo de texto y funciona a la perfección.
Necesito hacer la operación inversa, es decir exportar los datos del archivo de texto a una tabla de Access, pero no he podido dar con el código. Me quedé pegado asignando los datos a un Stringlist y no he logrado asignar los datos a los campos de la tabla.
¿Puede alguien echarme una mano?
Saludos y muchas gracias

[ecfisa]

Hola randenf.

Fijate si te sirve de este modo:

Código Delphi [-]
procedure ExportToText(const aFileName: TFilename; aDataSet: TDataSet); //(o TADODataSet, etc ...)
var
  F: TextFile;
  i: Integer;
  s: string;
begin
  AssignFile(F, aFileName);
  Rewrite(F);
  aDataSet.Open;
  while (not aDataSet.EOF) do
  begin
    s := '';
    for i := 0 to aDataSet.FieldCount-1 do
      s := s + aDataSet.Fields[i].AsString +',';
      SetLength(s, Length(s)-1);
    Writeln(F, s);
    aDataSet.Next;
  end;
  aDataSet.Close;
  CloseFile(F);
end;

procedure ImportFromText(const aFileName: TFileName; aDataSet: TDataSet); //(o TADODataSet, etc ...)
var
  TS1, TS2: TStrings;
  i, j: Integer;
begin
  aDataSet.Open;
  TS1 := TStringList.Create;
  try
    TS1.LoadFromFile(aFileName);
    for i := 0 to TS1.Count-1 do
    begin
      try
        TS2 := TStringList.Create;
        ExtractStrings([','], [], PChar(TS1[i]), TS2);
        aDataSet.Append;
        for j := 0 to aDataSet.FieldCount-1 do
          aDataSet.Fields[j].AsString := TS2[j];
        aDataSet.Post;
      finally
        TS2.Free;
      end;
    end;
  finally
    TS1.Free;
    aDataSet.Close;
  end;
end;

Ejemplo llamadas:

Código Delphi [-]
 ExportToText('C:\Export.txt', DataSet);
 ...
 ImportFromText('C:\Export.txt', DataSet);

Saludos.

[radenf]

Muchas gracias Daniel.
Lo probaré y te cuento.
Saludos

Iván

[radenf]

Funcionó perfecto.
Modifiqué las llamadas para poder sobreescribir la tabla y que no me arrojara excepciones por duplicar índices.

Para guardar el archivo:

Código Delphi [-]
procedure TFormConfiguracion.bsSkinButton1Click(Sender: TObject);
var
SpecialFolder: integer;
begin
SpecialFolder := CSIDL_PERSONAL;
Label5.Caption := GetSpecialFolderPath(SpecialFolder) ;
SaveDialog1.InitialDir:= Label5.Caption;
SaveDialog1.FileName:= 'Servidores Dicom';
if SaveDialog1.Execute then
ExportToText(SaveDialog1.FileName, DataSourceServidores.DataSet);
end;

y para cargar el archivo:

Código Delphi [-]
procedure TFormConfiguracion.bsSkinButton3Click(Sender: TObject);
begin
if OpenDialog1.Execute then
try
Data1.TablaServidores.Edit;
ADOQuery3.Close;
ADOQuery3.SQL.Text:= ' Delete * from Servidores ';
ADOQuery3.ExecSQL;
finally
ImportFromText(OpenDialog1.FileName, DataSourceServidores.DataSet);
Data1.TablaServidores.Close;
Data1.TablaServidores.Open;
Data1.TablaServidores.Refresh;
DBAdvGrid3.Update;
end;
end;

Me arroja sin embargo el siguiente warning y no entiendo por qué.
[DCC Warning] Configuracion.pas(674): W1036 Variable 'TS2' might not have been initialized

Saludos Daniel y muchas gracias