error de CheckBox en DBGrid

[ecfisa]

Hola Miguel.

¿ Ya revisaste este ejemplo ?: CheckBox inside a DBGrid

Saludos

[mRoman]

Empezado por ecfisa

Hola Miguel.

¿ Ya revisaste este ejemplo ?: CheckBox inside a DBGrid

Saludos

Gracias por contestar.

Si ecfisa, ya vi ese ejemplo. Pero al parecer es para campos boleanos....yo trabajo con Firebird 2.0 y ahi no hay campos boleanos. De hecho tengo un campo donde almaceno una "S" para identificar los pedidos que fueron surtidos y una "N" para los que no están en el supuesto.

En realidad no se como aplicarlo a mi codigo....veo q maneja un componente DBCheckBox....yo no lo uso....dejame probarlo.

[ecfisa]

Hola Miguel.

No es necesario que el campo sea booleano, para eso están las propiedades ValueChecked y ValueUnChecked del TDBCheckBox:

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
begin
  with DBCheckBox1 do
  begin
    Caption:= '';
    ValueChecked:= 'S';
    ValueUnchecked:= 'N';
    Visible:= False;
  end;
  IBDataset1.Open;
end;

El resto del código sólo necesita unos cambios menores.

Código Delphi [-]
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
const
  IsChecked: array[Boolean] of Integer = (DFCS_BUTTONCHECK, DFCS_BUTTONCHECK+DFCS_CHECKED);
var
  DrawState: Integer;
  DrawRect: TRect;
begin
  if gdSelected in State then
  begin
    if Column.FieldName = DBCheckBox1.DataField then
    begin
      DBGrid1.Canvas.Brush.Style:= bsSolid;
      DBGrid1.Canvas.Rectangle(Rect.Left, Rect.Top, Rect.Right, Rect. Bottom);
      DBCheckBox1.Left    := Rect.Left + DBGrid1.Left + 2;
      DBCheckBox1.Top     := Rect.Top + DBGrid1.top + 2;
      DBCheckBox1.Width   := (Rect.Right - Rect.Left + 4) div 2;
      DBCheckBox1.Height  := Rect.Bottom - Rect.Top;
      DBCheckBox1.Visible := True;
      DBCheckBox1.SetFocus;
    end
  end
  else if Column.FieldName = DBCheckBox1.DataField then
    begin
      DrawRect := Rect;
      InflateRect(DrawRect,-1,-1);
      DrawState := IsChecked[Column.Field.AsString='S'];
      DBGrid1.Canvas.FillRect(Rect);
      DrawFrameControl(DBGrid1.Canvas.Handle,DrawRect,DFC_BUTTON,DrawState);
    end;
end;

procedure TForm1.DBGrid1ColExit(Sender: TObject);
begin
  with DBCheckBox1 do
    Visible:= not (DBGrid1.SelectedField.FieldName = DataField)
end;

procedure TForm1.DBCheckBox1Exit(Sender: TObject);
begin
  IBDataSet1.Edit;
  IBDataSet1.Post;
end;
...

Saludos

[mRoman]

Agradezco Daniel tu respuesta....en estos momentos estoy probando el codigo. También me guiaré con lo q me comentas....

Nuevamente agradezco tu tiempo. Luego les cuento como fue...y publico el código final.

Saludos.

[mRoman]

oK...Excelente...ya lo probe y funciona al 90%...jajajaja...es que el checkbox se "pinta" tambien afuera del DbGrid1.

Checaré mas a fondo el código para solucionarlo....para mi q va a ser donde esta el codigo del procedimiento
DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
DataCol: Integer; Column: TColumn; State: TGridDrawState);

Lo checo y les comento

[juanlaplata]

Evento DrawColumnCell del DBGrid

Código Delphi [-]
if Column.Field = 'Mover' then
  begin
    Grilla.Canvas.FillRect(Rect);

    ImageList1.Draw(Grilla.Canvas,
                    (Rect.Right - Rect.Left) div 2,
                    Rect.Top+1,
                    0);

    if Base.MovimientosMover.AsBoolean then
      ImageList1.Draw(Grilla.Canvas,Rect.Left+10,Rect.Top+1,2);
  end;

Evento CellClick del DBGrid

Código Delphi [-]
if (Column.FieldName = 'Mover') then
  begin
  Base.Movimientos.Edit;
  Base.MovimientosMover.AsBoolean:= not(Base.MovimientosMover.AsBoolean);
  Base.Movimientos.Post;
  end;

Las imagenes q dibujo ...

[mRoman]

Ok gracias juanlaplata por tu colaboración.

No estoy trabajando con imagenes, pero es otra opción que exploraré y ver que tan efectivo es para mi aplicación....si es lo que se necesita.

Te agradezco tu tiempo.