Como Obtener la lista de alias

[ecfisa]

Hola cipce22, bienvenido a Club Delphi .

Como a todos los que ingresan te recomendamos leer nuestra guía de estilo.

Si tenes definidos los alias en aliases.conf, para obtener la lista de alias/rutas desde Delphi, podrías hacer:

Código Delphi [-]
...
uses Registry;

procedure GetFirebirdAliases(Strings: TStrings);
var
  path: string;
  i  : Integer;
begin
 with TRegistry.Create do
  try
   RootKey := HKEY_LOCAL_MACHINE;
   if OpenKeyReadOnly('\SOFTWARE\Firebird Project\Firebird Server\Instances') then
     path := ReadString('DefaultInstance');
     Strings.LoadFromFile(path + 'aliases.conf');
     for i:= Strings.Count-1 downto 0 do
      if Pos('#', Trim(Strings[i])) = 1 then
        Strings.Delete(i);
  finally
   Free;
  end;
end;

Ejemplo de uso:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
begin
  with ListBox1 do
  begin
    Items.Clear;
    GetFirebirdAliases(Items);
  end;
end;

Saludos

[cipce22]

Gracias ecfisa pero por alguna razón el valor que deberia obtener del registro ( que ya revisé y sí contiene la ruta) no es el correcto, me devuelve el valor de donde tengo guardado el proyecto(...Misdocumentos\....) y no el valor que contiene la entrada del registro (C:\Program Files\Firebird\Firebird_2_5\)
¿por qué será?

[ecfisa]

Hola cipe22.

¿ Que versión de Windows estas usando ?, del modo anterior me funciona correctamente en Windows 7.

Saludos

[cipce22]

Empezado por ecfisa

Hola cipe22.

¿ Que versión de Windows estas usando ?, del modo anterior me funciona correctamente en Windows 7.

Saludos

Hola de nuevo ecfisa.
Disculpa que olvide ese detalle tan importante, estoy utilizando Windows 8 x64

Código Delphi [-]
path := ReadString('DefaultInstance');

En esa parte la variable "path" no recibe valor alguno, ¿debo dar algun tipo de privilegio?

[ecfisa]

Hola cipce22.

Podríamos hacer que previemente el procedimiento detecte si estamos en Windows 32 o 64 bits para luego leer la clave correcta:

Código Delphi [-]
uses Registry;

function IsWOW64: Boolean;
type
  LPFN_ISWOW64PROCESS = function(hProcess: THandle; var Wow64Process: BOOL): BOOL; stdcall;
var
  fnIsWow64Process: LPFN_ISWOW64PROCESS;
  bIsWOW64: BOOL;
begin
  Result:= False;
  fnIsWow64Process:= LPFN_ISWOW64PROCESS(
    GetProcAddress( GetModuleHandle('kernel32'), 'IsWow64Process') );
  if Assigned( fnIsWow64Process ) then
  begin
    bIsWow64:= False;
    if fnIsWow64Process(GetCurrentProcess(), bIsWOW64) then
      Result:= bIsWOW64;
  end;
end;

procedure GetFirebirdAliases(Strings: TStrings);
const
  KEY_WOW64_64KEY = $0100;
  RKEYS: array[Boolean] of string = (
    '\Software\Firebird Project\Firebird Server\Instances',   // Windows 32
    '\SOFTWARE\WOW6432node\Firebird Project\Firebird Server\Instances' ); // Windows 64 (*)
   
var
  path: string;
  i  : Integer;
  Reg: TRegistry;
  W64: Boolean;
begin
  W64 := isWOW64;
  with TRegistry.Create(KEY_READ + KEY_WOW64_64KEY * Integer(W64)) do
  try
   RootKey := HKEY_LOCAL_MACHINE;
   if OpenKeyReadOnly(RKEYS[W64]) then
     path := ReadString('DefaultInstance');
     Strings.LoadFromFile(path + 'aliases.conf');
     for i:= Strings.Count-1 downto 0 do
      if Pos('#', Trim(Strings[i])) = 1 then
        Strings.Delete(i);
  finally
   Free;
  end;
end;

(*) No tengo Windows 64 bits en este momento como para comprobar el valor de la clave en esa versión.
Aunque si interpreté bién lo escrito en este enlace, Registry Redirector, debería ser ese.

Tendrías que usar el regedit para controlar si el valor de clave "\SOFTWARE\WOW6432node\Firebird Project\Firebird Server\Instances" es el correcto.

Saludos

[[Delphius]]

Empezado por ecfisa

Hola cipce22.

(*) No tengo Windows 64 bits en este momento como para comprobar el valor de la clave en esa versión.
Aunque si interpreté bién lo escrito en este enlace, Registry Redirector, debería ser ese.

Tendrías que usar el regedit para controlar si el valor de clave "\SOFTWARE\WOW6432node\Firebird Project\Firebird Server\Instances" es el correcto.

Saludos

Yo dispongo de Windows 8.1 64bits y la clave del registro no es esa. Es la tradicional:
HKEY_LOCAL_MACHINE\SOFTWARE\Firebird Proyect\Firebird Server\Instances

En la carpeta de instalación, que por defecto, es la misma de siempre (bueno, en caso que se instale la v. 32bits será en "Program Files (x86)"), Hay una carpeta que dice WOW64 que contiene copias de fbclient, instserver, y otros lib. Admito que me falta documentarme más sobre Firebird en entorno 64bits (y sobre todo en la versión 2.5), pero creería que este subdirectorio contiene lo necesario para hacer una conexión desde clientes 32bits a un entorno server 64bits

Si es lo que preocupa al interesado.

Saludos,

[[nlsgarcia]]

cipce22,

Empezado por cipce22

...necesito el nombre de los alias existentes para las bases de datos (Firebird) en mi servidor, se que se almacenan en el aliases.conf...estoy utilizando Windows 8 x64...

Revisa este código:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Registry;

type
  TForm1 = class(TForm)
    Button1: TButton;
    ListBox1: TListBox;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

// Verifica si Windows es de 64 Bits
function CheckWOW64 : Boolean;
type
   TWOW64Process = function(Handle : THandle; var WOW64 : BOOL) : BOOL; Stdcall;

var
   Kernel32 : THandle;
   WOW64Process : TWOW64Process;
   WOW64 : BOOL;

begin

   Kernel32 := LoadLibrary('kernel32.dll');

   if (Kernel32 <> 0) then
   begin
      @WOW64Process := GetProcAddress(Kernel32, 'IsWow64Process');
      if (@WOW64Process <> nil) then
         if (WOW64Process(GetCurrentProcess, WOW64)) then
            Result := WOW64
         else
            Result := False;
   end;

   FreeLibrary(Kernel32);

end;

// Obtiene los Alias de FireBird de 32 y 64 Bits sobre Windows
procedure GetFireBirdAlias(Strings : TStrings);
const
   KEY_WOW64_64KEY = $0100; // Access a 64-bit key from either a 32-bit or 64-bit application
   KEY_WOW64_32KEY = $0200; // Access a 32-bit key from either a 32-bit or 64-bit application
   Instances = '\SOFTWARE\Firebird Project\Firebird Server\Instances';

var
   Path : String;
   i  : Integer;
   SL : TStringList;

begin

   if CheckWOW64 then
   begin

      with TRegistry.Create(KEY_READ or KEY_WOW64_64KEY) do
      try

         RootKey := HKEY_LOCAL_MACHINE;

         if OpenKey(Instances,False) then
         begin

            SL := TStringList.Create;
            Path := ReadString('DefaultInstance') + 'aliases.conf';
            SL.LoadFromFile(Path);

            for i := SL.Count-1 downto 0 do
               if Pos('#', Trim(SL[i])) = 1 then
                  SL.Delete(i);

            Strings.Text := Strings.Text + SL.Text;
            SL.Free;

         end;


      finally

         Free;

      end;

      with TRegistry.Create(KEY_READ or KEY_WOW64_32KEY) do
      try

         RootKey := HKEY_LOCAL_MACHINE;

         if OpenKey(Instances,False) then
         begin

            SL := TStringList.Create;
            Path := ReadString('DefaultInstance') + 'aliases.conf';
            SL.LoadFromFile(Path);

            for i := SL.Count-1 downto 0 do
               if Pos('#', Trim(SL[i])) = 1 then
                  SL.Delete(i);

            Strings.Text := Strings.Text + SL.Text;
            SL.Free;

         end;

      finally

         Free;

      end;

   end
   else
   begin
      with TRegistry.Create do
      try

         RootKey := HKEY_LOCAL_MACHINE;

         if OpenKey(Instances,False) then
         begin
            Path := ReadString('DefaultInstance') + 'aliases.conf';
            Strings.LoadFromFile(Path);
            for i := Strings.Count-1 downto 0 do
               if Pos('#', Trim(Strings[i])) = 1 then
                  Strings.Delete(i);
         end

      finally

         Free;

      end;


   end;

end;

// Carga los alias de Firebird de 32 y 64 bits
procedure TForm1.Button1Click(Sender: TObject);
begin
   with ListBox1 do
   begin
      Items.Clear;
      GetFirebirdAlias(Items);
   end;
end;

end.

El código anterior en Delphi 7 sobre Windows 7 Professional x32 y x64, Permite obtener los Alias de Firebird de 32 y 64 bits en Windows x32 y x64, como se muestra en la siguientes imágenes:

Alias de Ejemplo en FireBird en Windows 7 Professional x32:



Alias de Ejemplo en FireBird en Windows 7 Professional x64:



Notas:

1- El código propuesto es una variación del sugerido en el Msg #9.

2- El código propuesto, permite listar los Alias de una instalación de Firebird de 32 o 64 bits en Windows x64, inclusive ambas en caso de que coexistan por alguna razón particular.

3- El código propuesto, permite listar los Alias de una instalación de Firebird de 32 bits en Windows x32.

Revisa esta información:

1- Registry Key Security and Access Rights

2- Accessing an Alternate Registry View

3- IsWow64Process function

Espero sea útil

Nelson.

[ecfisa]

Empezado por Delphius

Yo dispongo de Windows 8.1 64bits y la clave del registro no es esa. Es la tradicional:
HKEY_LOCAL_MACHINE\SOFTWARE\Firebird Proyect\Firebird Server\Instances

En la carpeta de instalación, que por defecto, es la misma de siempre (bueno, en caso que se instale la v. 32bits será en "Program Files (x86)"), Hay una carpeta que dice WOW64 que contiene copias de fbclient, instserver, y otros lib. Admito que me falta documentarme más sobre Firebird en entorno 64bits (y sobre todo en la versión 2.5), pero creería que este subdirectorio contiene lo necesario para hacer una conexión desde clientes 32bits a un entorno server 64bits
...

Hola Delphius.

Gracias por tu comentario ( había olvidado que las aplicaciones 32 bits bajo Windows 64 se instalan en "Program Files (x86)" )

Entonces creo que cipce22 podría intentar así:

Código Delphi [-]
...
uses Registry;

procedure GetFirebirdAliases(Strings: TStrings);
type
 LPFN_ISWOW64PROCESS = function(hProcess: THandle; var Wow64Proc: BOOL): BOOL; stdcall;
var
  fnIsWow64Proc: LPFN_ISWOW64PROCESS;
  IsWow64: BOOL;
  path: string;
  i  : Integer;
begin
  with TRegistry.Create do
  try
    RootKey := HKEY_LOCAL_MACHINE;
    if OpenKeyReadOnly('\Software\Firebird Project\Firebird Server\Instances') then
      path := ReadString('DefaultInstance')
    else
      raise Exception.Create('Firebird no instalado');  
  finally
    Free;
  end;
  fnIsWow64Proc:= LPFN_ISWOW64PROCESS(GetProcAddress(GetModuleHandle('kernel32'),'IsWow64Process'));
  if Assigned(fnIsWow64Proc) then
    fnIsWow64Proc(GetCurrentProcess(), IsWow64);
  if IsWow64 then
    path := StringReplace(path, 'Program Files', 'Program Files (x86)',[rfIgnoreCase]);

  Strings.LoadFromFile(path + 'aliases.conf');
  for i:= Strings.Count-1 downto 0 do
    if Pos('#', Trim(Strings[i])) = 1 then Strings.Delete(i);
end;

Saludos