Agregar varios captions de checkbox a bd

[rafaelon]

gracias a todos por responder , ante todo no tengo mucho programando y he estado leyendo libros de delphi hace unos 2 meses porque fue el lenguaje que vi en el instituto por si escribo cosas sin sentido o no muy optimas sepan disculparme, básicamente no he encontrado la manera de hacerlo




por ahora tengo esto en cada checkbox

procedure Tfrm_principal.CheckBox1Click(Sender: TObject);
begin
if CheckBox1.Checked = True then
begin MD.tblproblemas.insert;
MD.tblproblemas.fieldbyname('problema1').AsString:=checkbox1.caption;
end
else
buscarp(label42.Caption, encontrado);
  if encontrado then
  begin
    MD.tblproblemas.delete;

 end;
end;

end.

* tambien intente hacerlo desde el boton guardar pero no se como hacer un conjunto de if anidadados cuando las condiciones son siempre afirmativas (queria enviar una imagen del form pero no me lo permite)

* la tabla tengo como clave principal el "id_orden" (label42) y otros 17 campos donde iria cada problema y un 18 para problemas adicionales , la bd es en access

[ecfisa]

Hola.

Tal vez te resulte mas simple usando un TCheckListBox, v. gr.:

Código Delphi [-]
...
type
  TForm1 = class(TForm)
    CheckListBox1: TCheckListBox;
    btnGuardar: TButton;
    //...
    procedure FormCreate(Sender: TObject);
    procedure btnGuardarClick(Sender: TObject);
  private
    function HaveItemsChecked ( clb: TCheckListBox ): Boolean;
  public
  end;

implementation

// Podes evitar todo el código de FormCreate asignando los 17 ítems en tiempo de diseño 
procedure TForm1.FormCreate(Sender: TObject);
var
  clb: TCheckListBox;
begin  
  clb := CheckListBox1;   
  clb.Items.Add('Problema Wifi');
  clb.Items.Add('Problema Señal');
  clb.Items.Add('Problema Antena');
  clb.Items.Add('Problema Bateria');
  // cbl.Items.Add(...
end;

// devuelve verdadero si existe algún item marcado
function TForm1.HaveItemsChecked ( clb: TCheckListBox ): Boolean;
var
  i: Integer;
begin
  Result := False;
  for i := 0 to clb.Items.Count-1 do
  begin
    Result := clb.Checked[i];
    if Result then Exit;
  end;
end;

procedure TForm1.btnGuardarClick(Sender: TObject);
var
  i  : Integer;
begin
  if HaveItemsChecked( CheckListBox1 ) then
  begin
    MD.tblProblemas.Insert;
    for i := 0 to CheckListBox1.Items.Count-1 do
      if CheckListBox1.Checked[i] then
         MD.tblProblemas.FieldByName(Format('problema%d',[i+1])).AsString :=
          CheckListBox1.Items[i];
    //...
    MD.tblProblemas.Post;
  end
end;

Saludos

[rafaelon]

Empezado por ecfisa

Hola.

Tal vez te resulte mas simple usando un TCheckListBox, v. gr.:

Código Delphi [-]
...
type
  TForm1 = class(TForm)
    CheckListBox1: TCheckListBox;
    btnGuardar: TButton;
    //...
    procedure FormCreate(Sender: TObject);
    procedure btnGuardarClick(Sender: TObject);
  private
    function HaveItemsChecked ( clb: TCheckListBox ): Boolean;
  public
  end;

implementation

// Podes evitar todo el código de FormCreate asignando los 17 ítems en tiempo de diseño 
procedure TForm1.FormCreate(Sender: TObject);
var
  clb: TCheckListBox;
begin  
  clb := CheckListBox1;   
  clb.Items.Add('Problema Wifi');
  clb.Items.Add('Problema Señal');
  clb.Items.Add('Problema Antena');
  clb.Items.Add('Problema Bateria');
  // cbl.Items.Add(...
end;

// devuelve verdadero si existe algún item marcado
function TForm1.HaveItemsChecked ( clb: TCheckListBox ): Boolean;
var
  i: Integer;
begin
  Result := False;
  for i := 0 to clb.Items.Count-1 do
  begin
    Result := clb.Checked[i];
    if Result then Exit;
  end;
end;

procedure TForm1.btnGuardarClick(Sender: TObject);
var
  i  : Integer;
begin
  if HaveItemsChecked( CheckListBox1 ) then
  begin
    MD.tblProblemas.Insert;
    for i := 0 to CheckListBox1.Items.Count-1 do
      if CheckListBox1.Checked[i] then
         MD.tblProblemas.FieldByName(Format('problema%d',[i+1])).AsString :=
          CheckListBox1.Items[i];
    //...
    MD.tblProblemas.Post;
  end
end;

Saludos

Me sirve perfecto gracias , ya tenia otra solución, pero esta es mucho mejor , una ultima pregunta si mas adelante quisiera alimentar los datos de checkboxlist desde una tabla como podría hacer ?

[ecfisa]

Hola.

Empezado por rafaelon

... si mas adelante quisiera alimentar los datos de checkboxlist desde una tabla como podría hacer ?

Código Delphi [-]
// al inicio del formulario del CheckListBox:
procedure TForm1.FormCreate(Sender: TObject);
var
  clb: TCheckListBox;
begin
  clb := CheckListBox1;

  clb.Items.Clear;
  unQuery.Close;
  unQuery.SQL.Text := 'SELECT DESCRIPCION FROM SINTOMAS'; // (*) 
  unQuery.Open;
  while not unQuery.Eof do
  begin
    clb.Items.Add( unQuery.FieldByName('DESCRIPCION').AsString );
    unQuery.Next;
  end;
end;

(*) Donde: DESCRIPCION sería el nombre del campo que detalla el problema y SINTOMAS el nombre de la tabla que los contiene.

Saludos

[rafaelon]

gracias , me funciona bastante bien!